[Cuttlas]

is there any plugin which player can choose name for playing on each team?

for example when he is playing on CT, his name is RoboCop and when He transfer to T, then his name changed to Jackal

[mlibre]

of course, what about the duplicates, will they all have the same name?

[Cuttlas]

it will be used only for admins. while duplicates it should add numbers.

If it can read names from an ini files, it would be perfect.

[Bugsy]

So each admin does this?

set_name "Bugsy_T" (while on T team)
set_name "Bugsy_CT" (while on CT team)

Then the next time I connect, it automatically sets my name based on the team I join?

[Cuttlas]

for example I store names on an ini files like this:

CTName=RoboCop
TName=Jackal

then the plugin will read that ini file and in each round will check the player team, if he is on CT, then the CT name should be set, if he is on T, the T name.

also it is very good, if we can enable/disable team checking, if the plugin is disabled then it should not change the names, also it would be perfect if the enable/disable be a amx cvar.

[Bugsy]

So if 2 CT admins connect, you would expect:

Robocop 1
Robocop 2

?

[Cuttlas]

Originally Posted by Bugsy So if 2 CT admins connect, you would expect: Robocop 1 Robocop 2 ?

yeah, it would be nice

[Cuttlas]

or we can think more publicly, that every player (admin or none-admin) can set CTName and TName in an ini file (in a specific folder with a specific name) on their client systems.

whenever any player wants to active this functionally he can call /teamnames.

[fysiks]

The server can't read a file like that. You would need to give them the ability to set the setting and store it on the server. However, this wouldn't really be much different than just them changing their own name.

[Bugsy]

Here's most of it, I just need to hook team change CT <-> T to set the name accordingly when /teamnames is enabled for the player.

Edit: Updated with team change hook to apply name change when going CT <-> T. Not tested much.

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <nvault>

new const Version[] = "0.1";

new g_Vault;

enum TeamNameData
{
    tnAuthID,
    tnCurTeam,
    bool:tnEnabled
}

new g_tnData[ MAX_PLAYERS + 1 ][ TeamNameData ];

public plugin_init() 
{
    register_plugin( "Team Names" , Version , "bugsy" );
    
    register_clcmd( "tname" , "SetTeamName" );
    register_clcmd( "ctname" , "SetTeamName" );
    register_clcmd( "say /teamnames" , "EnableTeamName" );
    
    register_event( "TeamInfo" , "EventTeamInfo" , "a" );
    
    if ( ( g_Vault = nvault_open( "TeamNames" ) ) == INVALID_HANDLE )
        set_fail_state( "Error opening vault" );
}

public plugin_end()
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    get_user_authid( id , g_tnData[ id ][ tnAuthID ] , charsmax( g_tnData[][ tnAuthID ] ) );
    g_tnData[ id ][ tnCurTeam ] = 'U';
    g_tnData[ id ][ tnEnabled ] = false;
}

public EnableTeamName( id )
{
    g_tnData[ id ][ tnEnabled ] = !g_tnData[ id ][ tnEnabled ];
    client_print( id , print_chat , "* Team Names was %s" , g_tnData[ id ][ tnEnabled ]  ? "enabled" : "disabled" );
    
    if ( g_tnData[ id ][ tnEnabled ]  )
        ChangePlayerName( id , g_tnData[ id ][ tnCurTeam ] == 'T' ? CS_TEAM_T : CS_TEAM_CT );
    
    return PLUGIN_HANDLED;
}

public SetTeamName( id )
{
    new szCmd[ 7 ] ,  szName[ 33 ] ,  szKey[ 36 ];
    
    read_argv( 0 , szCmd , charsmax( szCmd ) );
    read_argv( 1 , szName , charsmax( szName ) );
    
    formatex( szKey , charsmax( szKey ) , "%s_%s" , szCmd[ 0 ] == 'c' ? "C" : "T" , g_tnData[ id ][ tnAuthID ] );
    nvault_set( g_Vault , szKey , szName );
    
    console_print( id , "%s name successfully set to '%s'" , szCmd[ 0 ] == 'c' ? "CT" : "T" , szName );
    UpdateName( id );
    
    return PLUGIN_HANDLED;
}

public UpdateName( id )
{

    if ( g_tnData[ id ][ tnEnabled ] )
    {

        switch ( g_tnData[ id ][ tnCurTeam ] )
        {
            case 'T': ChangePlayerName( id , CS_TEAM_T );
            case 'C': ChangePlayerName( id , CS_TEAM_CT  );
        }
    }
}

public ChangePlayerName( id , CsTeams:csTeam )
{
    new szName[ 35 ] ,  szKey[ 36 ] ,  iNameLen , iTS ,  iCounter = 1 , szCurName[ 33 ];
    
    formatex( szKey , charsmax( szKey ) , "%s_%s" , ( csTeam == CS_TEAM_CT ) ? "C" : "T" , g_tnData[ id ][ tnAuthID ] );
    
    if ( nvault_lookup( g_Vault , szKey , szName , charsmax( szName ) , iTS ) )
    {
        iNameLen = strlen( szName );
        while ( cmd_target( id , szName ) )
        {
            if ( szName[ iNameLen ] == EOS )
                szName[ iNameLen ] = '_';
            
            szName[ iNameLen + 1 ] = '0' +  iCounter;
        }
        
        get_user_name( id , szCurName , charsmax( szCurName ) );
        
        if ( !equali( szName , szCurName )  )
        {
            console_cmd( id , "name ^"%s^"" , szName );
        }
    }
    else
    {
        client_print( id , print_chat , "* You do not have a %s team name defined. Use the 'tname' & 'ctname' console commands to do so." , ( csTeam == CS_TEAM_CT ) ? "CT" : "T" );
    }    
}

public EventTeamInfo( )
{
    static id; id = read_data( 1 );
    static szTeam[ 2 ]; read_data( 2 , szTeam , charsmax( szTeam ) );
    
    if ( g_tnData[ id ][ tnCurTeam ] != szTeam[ 0 ] )
    {
        g_tnData[ id ][ tnCurTeam ] = szTeam[ 0 ];
        UpdateName( id );
    }
}