[SpartanK]

I've been searching for days and I can't find any clear simple example of how to do this.

I just want to gather a location(s) around the map, perhaps grabbing the clients current location.

Using that location, I want to spawn a weapon there on the floor.

I'm making the assumption that if a player can stand in a location, then a weapon can spawn there without problems.

[FuZ!on]

You might be able to take a look at some code from this plugin: https://forums.alliedmods.net/showthread.php?t=193359

It gathers the a player's location on death and spawns an entity at that location.

[Kolapsicle]

I wrote a quick example which spawns an AK47 at a players position.

Spoiler

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

#pragma newdecls required

public void OnPluginStart()
{
    RegConsoleCmd("sm_spawn", Command_Spawn);
}

public Action Command_Spawn(int client, int args)
{
    if (!IsValidClient(client))
    {
        return Plugin_Handled;
    }
    
    float origin[3];
    GetClientAbsOrigin(client, origin);
    SpawnWeapon("weapon_ak47", origin);
    return Plugin_Handled;
}

void SpawnWeapon(char[] weapon, float origin[3], float rotation[3] =  { 0.0, 0.0, 90.0 } )
{
    int ent = CreateEntityByName(weapon);
    if (!IsValidEntity(ent))
    {
        ThrowError("Invalid Entity.");
    }
    
    if (!DispatchSpawn(ent))
    {
        ThrowError("Invalid entity index, or no mod support.");
    }
    
    TeleportEntity(ent, origin, rotation, NULL_VECTOR);
}

bool IsValidClient(int client)
{
    return 0 < client <= MaxClients && IsClientInGame(client);
} 


[SpartanK]

Originally Posted by Kolapsicle I wrote a quick example which spawns an AK47 at a players position

Thanks for this, I'm going to try and implement it. I've not tested it but I've seen a lot of posts saying that spawned weapons, don't actually have the weapon properties.

Should this actually spawn an AK47 that is the same as an AK47 you'd get from the buy menu?

Hijacking my own thread but something else I'm stuck on is, how do you prevent people from spawning after the round has started. In my mod, new players should spawn at the start of the next round, just like in casual for instance?

[SpartanK]

Originally Posted by FuZ!on You might be able to take a look at some code from this plugin: https://forums.alliedmods.net/showthread.php?t=193359 It gathers the a player's location on death and spawns an entity at that location.

Thanks, yes I already had this downloaded as an example to work from

[SpartanK]

Originally Posted by Kolapsicle I wrote a quick example which spawns an AK47 at a players position

This actually worked as intended, I then modified it to spawn a weapon at a players aim.