[ssphreak]

Hello - i am requesting a pluggin.

For CSGO

It will automatically slay a person that bunnyhops, either by script or 'skill.'

Is this something that could be done/made?

Willing to pay for the time created.

Please contact me...thank you!

[fiction]

You can do a simple implementation using shavit's Bunnyhop Statistics by simply checking how many times a player is jumping per jump.
This will almost definitely have false positives though, a better approach would be to analyse a player's jumps per jump over a period of 10 to 30 jumps so a player isn't slayed for an anomalous jump.

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>
#include <bhopstats>

ConVar g_cvMaxJumpsPerJump;
int g_iJumps[MAXPLAYERS + 1];

public void OnPluginStart()
{
    g_cvMaxJumpsPerJump = CreateConVar("sm_max_jumps_per_jump", "4", "Maximum jumps per jump before being slayed.", _, true, 1.0);
}

public void Bunnyhop_OnJumpPressed(int client, bool onground)
{
    g_iJumps[client]++;
}

public void Bunnyhop_OnTouchGround(int client)
{
    if(g_iJumps[client] > g_cvMaxJumpsPerJump.IntValue)
        ForcePlayerSuicide(client);

    g_iJumps[client] = 0;
} 


Remember you'll need to install Bunnyhop Statistics itself on your server too.

[ssphreak]

Thank you for the reply. Is there a pluggin that could be built without having to do any implementaion? I am not too handy with coding. I am willing to pay someone for their time for a pluggin.

THank you - sl4ysl3d

[fiction]

Originally Posted by ssphreak Thank you for the reply. Is there a pluggin that could be built without having to do any implementaion? I am not too handy with coding. I am willing to pay someone for their time for a pluggin. THank you - sl4ysl3d

The plugin I put in my last post is the simple implementation, you can compile it yourself or click get plugin. As I said though make sure to install Bunnyhop Statistics too.

[ssphreak]

Fiction - thank you - i thought there was something i needed to do. I tried clicking get plugin, but i got a failed to compile message. i try to figure it out - thank you!

[ssphreak]

Hello Fiction - It does slay people mashing the jump button or rolling their wheel. But you are still able to bunnyhop - is there a way to add a function that slays when they accelerate from the bunnyhopw as well?

Thank You

[fiction]

Originally Posted by ssphreak Hello Fiction - It does slay people mashing the jump button or rolling their wheel. But you are still able to bunnyhop - is there a way to add a function that slays when they accelerate from the bunnyhopw as well? Thank You

Hmm you'll need to explain what you're trying to accomplish a bit more... if you just want to stop anyone from bhopping then set sv_enablebunnyhopping 0 and player's will be reset to ~285.96 u/s speed when they land, no matter what.

[ssphreak]

Thank you for being helping me out. I do have sv_enablebunnyhopping 0 in my server.cfg but that does not seem to work.

How about forcing the player to be on the ground after a jump a certain amount of time so that they cannot immediately jump as they land?

[fiction]

Originally Posted by ssphreak Thank you for being helping me out. I do have sv_enablebunnyhopping 0 in my server.cfg but that does not seem to work. How about forcing the player to be on the ground after a jump a certain amount of time so that they cannot immediately jump as they land?

Sure try this, I've only briefly tested it. 1 should be enough but if you find players are still able to bhop turn sm_jump_blocked_ticks up until you're happy with it.
Note: Bunnyhop Statistics is no longer used and you can remove it from your server.

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

ConVar g_cvJumpBlockedTicks;

public void OnPluginStart()
{
    g_cvJumpBlockedTicks = CreateConVar("sm_jump_blocked_ticks", "1", "Ticks/frames after landing before you are able to jump.", _, true, 0.0);
}

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3])
{
    Action iReturn = Plugin_Continue;
    static bool bOnGround[MAXPLAYERS + 1] = {true, ...};
    static bool bReleasedJump[MAXPLAYERS + 1] = {true, ...};
    static int iPassedTicks[MAXPLAYERS + 1] = {-1, ...};

    if(!IsPlayerAlive(client) || IsFakeClient(client))
        return iReturn;

    if(g_cvJumpBlockedTicks.IntValue > iPassedTicks[client] > -1)
    {
        iPassedTicks[client]++;

        if(buttons & IN_JUMP)
        {
            buttons &= ~IN_JUMP;
            iReturn = Plugin_Changed;
        }
    }
    else if(iPassedTicks[client] == g_cvJumpBlockedTicks.IntValue)
    {
        iPassedTicks[client] = -1;
        bReleasedJump[client] = false;
    }

    if(iPassedTicks[client] == -1 && !bReleasedJump[client])
    {

        if(!(buttons & IN_JUMP))
            bReleasedJump[client] = true;

        if(!bReleasedJump[client])
        {
            buttons &= ~IN_JUMP;
            iReturn = Plugin_Changed;
        }
    }

    bool bPreviouslyOnGround = bOnGround[client];

    if(GetEntPropEnt(client, Prop_Send, "m_hGroundEntity") == -1)
        bOnGround[client] = false;
    else
        bOnGround[client] = true;

    if(bOnGround[client] && !bPreviouslyOnGround)
        iPassedTicks[client] = 0;

    return iReturn;
} 


[ssphreak]

Hello fiction - i have tested this last version, and it is super close. It makes it a lot harder, but players are still able to bunnyhop as the timing for the bunnyhop is before the hitting the ground. I presume almost instantly, if hit is not pressed at the precise moment this plugin stops them for the tic inputed (i tested 1,3,5,10,50) all intervals they were able to bhop.

How about after a player presses jump, each jump pressed afterwards does nothing for a set amount of tics? almost a combo of the two?

Thank you so much for your time!