[diorfo]

Hello,

I'm trying to develop a plugin to auto kill spitter after spit_burst event to avoid players hold spitter for long time in game.

Tried the below code but didn't work and i don't know why:

PHP Code:

#include <sourcemod> 
#include <sdktools> 

#define PLUGIN_VERSION "1.0" 

public Plugin:myinfo = 
{ 
    name = "Spitter Auto Kill", 
    author = "diorfo", 
    description = "Spitter Auto Kill after Spit", 
    version = PLUGIN_VERSION, 
    url = "" 
} 

public OnPluginStart() 
{ 
    CreateConVar("sm_l4d2_spitter_auto_kill", PLUGIN_VERSION, "Spitter Auto Kill", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY); 
     
    HookEvent("spit_burst", Event_SpitBurst); 

} 

public Event_SpitBurst (Handle:event, const String:name[], bool:dontBroadcast) 
{ 
    new client = GetClientOfUserId(GetEventInt(event,"userid")); 
    new Handle:idfix = CreateDataPack();   
    WritePackCell(idfix, GetClientUserId(client)); 
    PrintToChat(client, "\x04[SM] \x05Voce spitou e morrera em 10s"); 
    CreateTimer(10.0, kill_spitter); 
} 

public Action:kill_spitter(Handle:timer, any:idfix) 
{ 
    GetClientOfUserId(ReadPackCell(idfix)); 
    ForcePlayerSuicide(idfix); 
} 


looks like the id of spitter is losing in public Action:kill_spitter because if i change the CreateTimer(10.0, kill_spitter) for ForcePlayerSuicide(client) the spitter is killed instantly after spit and i'd like to set a time before she get auto killed.

Any ideas what is it wrong in code?

[xines]

If i understand this correctly then this would do the trick.

PHP Code:

#include <sourcemod>  
#include <sdktools>  

#define PLUGIN_VERSION "1.0"  

public Plugin myinfo =  
{  
    name = "Spitter Auto Kill",  
    author = "diorfo",  
    description = "Spitter Auto Kill after Spit",  
    version = PLUGIN_VERSION,  
    url = ""  
}  

public void OnPluginStart()  
{  
    CreateConVar("sm_l4d2_spitter_auto_kill", PLUGIN_VERSION, "Spitter Auto Kill", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);  
    HookEvent("spit_burst", Event_SpitBurst);  
}  

public Action Event_SpitBurst(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if(IsValidClient(client)
    {
        PrintToChat(client, "\x04[SM] \x05Voce spitou e morrera em 10s");  
        CreateTimer(10.0, kill_spitter, GetClientUserId(client));
    }
    return Plugin_Continue;
} 

public Action kill_spitter(Handle timer, any userid)  
{  
    int client = GetClientOfUserId(userid);  
    if(IsValidClient(client) && IsPlayerAlive(client))
    {
        ForcePlayerSuicide(client);
    }
    return Plugin_Stop;
}

stock bool IsValidClient(int client)
{
    return (1 <= client <= MaxClients && IsClientInGame(client));
} 


[diorfo]

worked.

thank you

[xerox8521]

The issue in your first code was that you never send the datapack handle to the timer function. So it would try to access an unknown datapack which the error log should show.

[diorfo]

Originally Posted by xerox8521 The issue in your first code was that you never send the datapack handle to the timer function. So it would try to access an unknown datapack which the error log should show.

Probably that's why i was receiving some lose identification warning.

[Marttt]

Edit (20-January-2019)

There is a new version released here.
_____________________________________________ ___________________________________________

Here is the working code.

PHP Code:

#include <sourcemod>
#include <sdktools>

#define PLUGIN_VERSION "1.0"

public Plugin myinfo =
{
    name = "Spitter Auto Kill",
    author = "diorfo",
    description = "Spitter Auto Kill after Spit",
    version = PLUGIN_VERSION,
    url = ""
}

public void OnPluginStart()
{
    CreateConVar("sm_l4d2_spitter_auto_kill", PLUGIN_VERSION, "Spitter Auto Kill", FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);
    HookEvent("spit_burst", Event_SpitBurst);
}

public Action Event_SpitBurst(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if(IsValidClient(client))
    {
        PrintToChat(client, "\x04[SM] \x05Voce spitou e morrera em 10s");
        CreateTimer(10.0, kill_spitter, GetClientUserId(client));
    }
    return Plugin_Continue;
}

public Action kill_spitter(Handle timer, any userid)
{
    int client = GetClientOfUserId(userid);
    if(IsValidClient(client) && IsPlayerAlive(client))
    {
        ForcePlayerSuicide(client);
    }
    return Plugin_Stop;
}

stock bool IsValidClient(int client)
{
    return (1 <= client <= MaxClients && IsClientInGame(client));
}