[Jawad Salvad0r]

Hi Everyone ! every body know that this plugin help us to send a private message to other player in the server

I need someone to help me to let the owner of the server see all privates messages in the server ! and thanks

#include <amxmodx>
#include <colorchat>

new g_iTarget[33]

public plugin_init() 
{
    register_plugin("PM - Private Message", "1.0", "EaGle/Flicker-rewriten")
    
    register_clcmd("say /pm", "cmdPMMenu")
    register_clcmd("say_team /pm", "cmdPMMenu")
    
    register_clcmd("PrivateMessage", "cmd_player");
}

public cmdPMMenu(id)
{
    new menu = menu_create("\yPrivate Message \wMenu", "handlePMMEnu")
    
    new players[32], num
    new szName[32], szTempid[32]
    
    get_players(players, num, "ach")
    
    for(new i; i < num; i++)
    {
        get_user_name(players[i], szName, charsmax(szName))
        
        num_to_str(get_user_userid(players[i]), szTempid, charsmax(szTempid))
        
        menu_additem(menu, szName, szTempid, 0)
    }
    
    menu_display(id, menu)
}

public handlePMMEnu(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    
    new szData[6], szName[64], iAccess, iCallback
    menu_item_getinfo(menu, item, iAccess, szData, charsmax(szData), szName, charsmax(szName), iCallback)
    
    g_iTarget[id] = find_player("k", str_to_num(szData))
    
    client_cmd(id, "messagemode PrivateMessage")
    
    menu_destroy(menu)
    return PLUGIN_HANDLED
}

public cmd_player(id)
{
    new say[300]
    read_args(say, charsmax(say))
    remove_quotes(say)
    
    if(!strlen(say))
        return PLUGIN_HANDLED
    
    new szSenderName[32], szReceiverName[32]
    get_user_name(id, szSenderName, charsmax(szSenderName))
    get_user_name(g_iTarget[id], szReceiverName, charsmax(szReceiverName))
    
    ColorChat(id, GREY, "[AMXX]^4 Private Message To^3 %s^1: %s", szReceiverName, say)
    ColorChat(g_iTarget[id], GREY, "[AMXX]^4 Private Message From^3 %s^1: %s", szSenderName, say)
    
    return PLUGIN_CONTINUE
}  

[OciXCrom]

Define "owner", i.e. how isl the plugin going to check if a player is the owner?

[Jawad Salvad0r]

Didn't undrstood ? I Said That The Owner Of Server Can See All Private messages between players !!!

[SomewhereLost]

Originally Posted by Jawad Salvad0r Didn't undrstood ? I Said That The Owner Of Server Can See All Private messages between players !!!

He understood, but he means How the plugin will know about that somebody who sees the messages is the owner of the server and not an ordinary admin.

[Freezo Begin]

Originally Posted by SomewhereLost He understood, but he means How the plugin will know about that somebody who sees the messages is the owner of the server and not an ordinary admin.

get_user_flags(index) & ADMIN_IMMUNITY

[siriusmd99]

Originally Posted by Freezo Begin get_user_flags(index) & ADMIN_IMMUNITY

There are different flags on different servers which owners have. But the most logic way is to CHECK ADMIN_RCON , because owner must be a dumb to give rcon access to other admins.
But let him say the flag maybe it's different.

[OciXCrom]

There's nothing dumb about giving rcon access. Please choose one of the following:

- Detect the owner by:

• his SteamID;
• a specific admin flag he uses;
• save the message in a log file.

[Jawad Salvad0r]

A a specific admin flag he uses;

[siriusmd99]

Change OWNER_FLAG define to what flag you want.

PHP Code:

#include <amxmodx>
#include <colorchat>

#define OWNER_FLAG ADMIN_RCON

new g_iTarget[33]

public plugin_init() 
{
    register_plugin("PM - Private Message", "1.0", "EaGle/Flicker-rewriten")
    
    register_clcmd("say /pm", "cmdPMMenu")
    register_clcmd("say_team /pm", "cmdPMMenu")
    
    register_clcmd("PrivateMessage", "cmd_player");
}

public cmdPMMenu(id)
{
    new menu = menu_create("\yPrivate Message \wMenu", "handlePMMEnu")
    
    new players[32], num
    new szName[32], szTempid[32]
    
    get_players(players, num, "ach")
    
    for(new i; i < num; i++)
    {
        get_user_name(players[i], szName, charsmax(szName))
        
        num_to_str(get_user_userid(players[i]), szTempid, charsmax(szTempid))
        
        menu_additem(menu, szName, szTempid, 0)
    }
    
    menu_display(id, menu)
}

public handlePMMEnu(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    
    new szData[6], szName[64], iAccess, iCallback
    menu_item_getinfo(menu, item, iAccess, szData, charsmax(szData), szName, charsmax(szName), iCallback)
    
    g_iTarget[id] = find_player("k", str_to_num(szData))
    
    client_cmd(id, "messagemode PrivateMessage")
    
    menu_destroy(menu)
    return PLUGIN_HANDLED
}

public cmd_player(id)
{
    new say[300]
    read_args(say, charsmax(say))
    remove_quotes(say)
    
    if(!strlen(say))
        return PLUGIN_HANDLED
    
    new szSenderName[32], szReceiverName[32]
    get_user_name(id, szSenderName, charsmax(szSenderName))
    get_user_name(g_iTarget[id], szReceiverName, charsmax(szReceiverName))
    
    ColorChat(id, GREY, "[AMXX]^4 Private Message To^3 %s^1: %s", szReceiverName, say)
    ColorChat(g_iTarget[id], GREY, "[AMXX]^4 Private Message From^3 %s^1: %s", szSenderName, say)
    
    for(new i = 1; i < get_maxplayers(); i++ )
        if(is_user_connected(i) && (get_user_flags(i) & OWNER_FLAG))
        {
           ColorChat(i, GREY, "[AMXX]^4 Private Message from ^3%s ^1To ^3%s:", szSenderName, szReceiverName)
           ColorChat(i, GREEN, "%s", say)
        }         
    
    return PLUGIN_CONTINUE
} 


[Jawad Salvad0r]

Worked Man . Thanks A Lot !!