[headmaster]

Hello there, if someone could make me a mini plugin.
When player press button "E", he will teleport where he is aiming, + teleport is avab. on four(4) seconds. If he try to press E before timer, it will show in chat, you need to wait (left seconds).
Thank you very much.

[headmaster]

Anyone?!

[siriusmd99]

Why you don't look to Warcraft teleport function and try to make it by yourself?

It's not needed much rocket science , just copy paste and some modifications..

[zmd94]

Just edit below:

https://forums.alliedmods.net/showthread.php?p=821615

[HamletEagle]

#include <amxmodx>
#include <fakemeta>
#include <xs>

new const neededSound[] = "common/wpn_denyselect.wav"

new maxPlayers
new Float:nextGameTime[33]

public plugin_init()
{
    maxPlayers = get_maxplayers()
    register_forward(FM_EmitSound, "pfnEmitSound")
}

public pfnEmitSound(id, channel, const sound[], Float:volume, Float:attenuation, flags, pitch)
{
    if(1 <= id <= maxPlayers)
    {
        if(equal(sound, neededSound) && (pev(id, pev_button) & IN_USE))
        {
            new Float:currentGameTime = get_gametime()
            if(currentGameTime >= nextGameTime[id])
            {
                teleportPlayer(id)
                nextGameTime[id] = currentGameTime + 4.0
                return FMRES_SUPERCEDE
            }
            else 
            {
                client_print(id, print_chat, "You have to wait %.1f seconds", nextGameTime[id] - currentGameTime)
            }
        }
    }
    
    return FMRES_IGNORED
}

teleportPlayer(id)
{
    new Float:playerOrigin[3], Float:playerViewOffset[3]
    pev(id, pev_origin, playerOrigin)
    pev(id, pev_view_ofs, playerViewOffset)
    xs_vec_add(playerOrigin, playerViewOffset, playerOrigin)
    
    new Float:playerViewAngle[3]
    pev(id, pev_v_angle, playerViewAngle)
    engfunc(EngFunc_MakeVectors, playerViewAngle)
    global_get(glb_v_forward, playerViewAngle)
    
    xs_vec_mul_scalar(playerViewAngle, 9999.0, playerViewAngle)
    xs_vec_add(playerOrigin, playerViewAngle, playerViewAngle)

    new handleTraceLine, Float:traceLineEndPos[3], Float:traceFraction
    engfunc(EngFunc_TraceLine, playerOrigin, playerViewAngle, DONT_IGNORE_MONSTERS, id, handleTraceLine)
    get_tr2(0, TR_vecEndPos, traceLineEndPos)
    
    new startDistance = 5
    if(validSpotFound(id, traceLineEndPos)) 
    {
        set_pev(id, pev_origin, traceLineEndPos)
    }
    else
    {
        new restrictMaxSearches = 150, i, Float:foundOrigin[3]
        while(--restrictMaxSearches > 0)
        {
            for(i = 0; i < 3; i++)
            {
                foundOrigin[i] = random_float(traceLineEndPos[i] - startDistance , traceLineEndPos[i] + startDistance)
            }
            
            engfunc(EngFunc_TraceLine, playerOrigin, foundOrigin, DONT_IGNORE_MONSTERS, id, handleTraceLine)
            get_tr2(handleTraceLine, TR_flFraction, traceFraction)
            free_tr2(handleTraceLine)
            
            if(traceFraction == 1.0)
            {
                if(validSpotFound(id, foundOrigin))
                {
                    set_pev(id, pev_origin, foundOrigin)
                    break
                }
            } 
            
            startDistance = startDistance + 1
        }
    }
}

bool:validSpotFound(id, Float:Origin[3])
{
    new handleTraceHull 
    engfunc(EngFunc_TraceHull, Origin, Origin, DONT_IGNORE_MONSTERS, pev(id, pev_flags) & FL_DUCKING ? HULL_HEAD : HULL_HUMAN, id, handleTraceHull)    
    if(get_tr2(handleTraceHull, TR_InOpen) && !(get_tr2(handleTraceHull, TR_StartSolid) || get_tr2(handleTraceHull, TR_AllSolid))) 
    {
        return true
    }    
    
    return false
}

Here it is.

Originally Posted by zmd94 Just edit below: https://forums.alliedmods.net/showthread.php?p=821615

Originally Posted by siriusmd99 Why you don't look to Warcraft teleport function and try to make it by yourself? It's not needed much rocket science , just copy paste and some modifications..

:facepalm:


You forget that this section is for request, not scripting help. Most server admins can't change some defines inside source code. Just do what OP wants or ignore the post.

[zmd94]

HamletEagle, will use your method for the teleport feature. ;)

[headmaster]

HamletEagle, thank you very much for plugin, i really appreciacte your help man! .