[Triniayo]

Hello,

I wanted to ask, if someone could tell me how I could code how to prevent damage for X seconds, after weapon_x can deal damage again?

So, basically I hit someone with an AK, and after X seconds I can deal damage again. Hope you understand what I mean haha.
Would be nice if the function would work per target, and not an overall count.

[Bacardi]

css, csgo or insurgency ?
There are many game mods.

Use sdkhook OnTakeDamge on players.
check attacker is valid client index, attacker index is equal to inflictor index.
Attacker is in game, then look attacker m_hActiveWeapon entity, get entity classname to look is it weapon_ak47.

use adt or trie array to store entity index with timestamp.
or any other method.


(I'm using phone)

[Triniayo]

It's for CSS/CSGO.

And thanks for the reply, gonna give it a try

[SM9]

You could create a global variable, then hook when the player deals damage, set the variable to false, then after a timer for x seconds set it to true again.

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

bool g_bCanDealDamage[MAXPLAYERS + 1] = true;
Handle g_hDamageTimer[MAXPLAYERS + 1] = null;

#define LoopValidClients(%1) for(int %1 = 1; %1 < MaxClients; %1++) if(IsValidClient(%1))

public Plugin myinfo = 
{
    name = "", 
    author = "", 
    description = "", 
    version = "0.1", 
    url = ""
};

public void OnPluginStart() {
    HookEvent("player_hurt", Event_PlayerHurt, EventHookMode_Post);
    
    LoopValidClients(iClient) {
        OnClientPutInServer(iClient);
    }
}

public void OnClientPutInServer(int iClient) {
    SDKHook(iClient, SDKHook_OnTakeDamage, Hook_TakeDamage);
    g_bCanDealDamage[iClient] = true;
    g_hDamageTimer[iClient] = null;
}

public void OnClientDisconnect(int iClient) {
    g_bCanDealDamage[iClient] = true;
    g_hDamageTimer[iClient] = null;
}

public void Event_PlayerHurt(Handle hEvent, char[] chName, bool bDontBroadcast)
{
    int iAttacker = GetClientOfUserId(GetEventInt(hEvent, "attacker"));
    int iVictim = GetClientOfUserId(GetEventInt(hEvent, "userid"));
    
    if (IsValidClient(iAttacker) && IsValidClient(iVictim) && iVictim != iAttacker && g_bCanDealDamage[iAttacker]) {
        char chWeapon[48]; GetEventString(hEvent, "weapon", chWeapon, 48); Format(chWeapon, 48, "weapon_%s", chWeapon);
        
        if (StrEqual(chWeapon, "weapon_ak47", false)) {
            g_bCanDealDamage[iAttacker] = false;
            
            if (g_hDamageTimer[iAttacker] == null) {
                g_hDamageTimer[iAttacker] = CreateTimer(5.0, Timer_AllowDamage, GetClientUserId(iAttacker), TIMER_FLAG_NO_MAPCHANGE);
            }
        }
    }
}

public Action Hook_TakeDamage(int iVictim, int &iAttacker, int &iInflictor, float &fDamage, int &iDamageType, int &iWeapon, float fDamageForce[3], float fDamagePosition[3])
{
    if (!g_bCanDealDamage[iAttacker] && iAttacker != iVictim) {
        float fNull[3]; fNull[0] = 0.0; fNull[1] = 0.0; fNull[2] = 0.0;
        
        // Block the aimpunch.
        SetEntPropVector(iVictim, Prop_Send, "m_aimPunchAngle", fNull);
        SetEntPropVector(iVictim, Prop_Send, "m_aimPunchAngleVel", fNull);
        SetEntPropVector(iVictim, Prop_Send, "m_viewPunchAngle", fNull);
        
        return Plugin_Handled; // Block Damage.
    }
    
    return Plugin_Continue;
}

public Action Timer_AllowDamage(Handle hTimer, int iUserId)
{
    int iClient = GetClientOfUserId(iUserId);
    
    if (!IsValidClient(iClient)) {
        return Plugin_Stop;
    }
    
    g_bCanDealDamage[iClient] = true;
    g_hDamageTimer[iClient] = null;
    
    return Plugin_Stop;
}

stock bool IsValidClient(int iClient) {
    return iClient > 0 && iClient <= MaxClients && IsClientInGame(iClient);
} 


So to block the player dealing damage then just set g_bCanDealDamage[iClient] = false; then set it to true to allow him to deal damage again.

[Bacardi]

...but did OP want to block one certain "ak47" in between that time or all "ak47's" sametime ?

[Triniayo]

I want to block the damage per player.

Example: Player 1 attacks Player 2 with an AK. After X seconds can Player 1 deal damage again on Player 2. Player 2 didn't shoot when Player 1 shot, and can still hurt Player 1 with his bullet.

So, this means that I want a cooldown per player and not a global cooldown for all players at the same time.

[SM9]

Originally Posted by FreakyLike I want to block the damage per player. Example: Player 1 attacks Player 2 with an AK. After X seconds can Player 1 deal damage again on Player 2. Player 2 didn't shoot when Player 1 shot, and can still hurt Player 1 with his bullet. So, this means that I want a cooldown per player and not a global cooldown for all players at the same time.

Oh ok, try this one then:

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

bool g_bCanDealDamage[MAXPLAYERS + 1][MAXPLAYERS + 1];
Handle g_hDamageTimer[MAXPLAYERS + 1][MAXPLAYERS + 1];

#define LoopValidClients(%1) for(int %1 = 1; %1 < MaxClients; %1++) if(IsValidClient(%1))

public Plugin myinfo = 
{
    name = "", 
    author = "", 
    description = "", 
    version = "0.1", 
    url = ""
};

public void OnPluginStart() {
    HookEvent("player_hurt", Event_PlayerHurt, EventHookMode_Post);
    
    LoopValidClients(iClient) {
        OnClientPutInServer(iClient);
    }
}

public void OnClientPutInServer(int iClient) {
    SDKHook(iClient, SDKHook_OnTakeDamage, Hook_TakeDamage);
    
    LoopValidClients(i) {
        g_bCanDealDamage[iClient][i] = true;
        g_hDamageTimer[iClient][i] = null;
    }
}

public void OnClientDisconnect(int iClient) {
    LoopValidClients(i) {
        g_bCanDealDamage[iClient][i] = true;
        g_hDamageTimer[iClient][i] = null;
    }
}

public void Event_PlayerHurt(Handle hEvent, char[] chName, bool bDontBroadcast)
{
    int iAttacker = GetClientOfUserId(GetEventInt(hEvent, "attacker"));
    int iVictim = GetClientOfUserId(GetEventInt(hEvent, "userid"));
    
    if (IsValidClient(iAttacker) && IsValidClient(iVictim) && iVictim != iAttacker && g_bCanDealDamage[iAttacker][iVictim]) {
        char chWeapon[48]; GetEventString(hEvent, "weapon", chWeapon, 48); Format(chWeapon, 48, "weapon_%s", chWeapon);
        
        if (StrEqual(chWeapon, "weapon_ak47", false)) {
            g_bCanDealDamage[iAttacker][iVictim] = false;
            
            if (g_hDamageTimer[iAttacker][iVictim] == null) {
                DataPack dPack; g_hDamageTimer[iAttacker][iVictim] = CreateDataTimer(5.0, Timer_AllowDamage, dPack, TIMER_FLAG_NO_MAPCHANGE | TIMER_DATA_HNDL_CLOSE);
                WritePackCell(dPack, GetClientUserId(iAttacker)); WritePackCell(dPack, GetClientUserId(iVictim)); ResetPack(dPack);
            }
        }
    }
}

public Action Hook_TakeDamage(int iVictim, int &iAttacker, int &iInflictor, float &fDamage, int &iDamageType, int &iWeapon, float fDamageForce[3], float fDamagePosition[3])
{
    if (!g_bCanDealDamage[iAttacker][iVictim] && iAttacker != iVictim) {
        float fNull[3]; fNull[0] = 0.0; fNull[1] = 0.0; fNull[2] = 0.0;
        
        // Block the aimpunch.
        SetEntPropVector(iVictim, Prop_Send, "m_aimPunchAngle", fNull);
        SetEntPropVector(iVictim, Prop_Send, "m_aimPunchAngleVel", fNull);
        SetEntPropVector(iVictim, Prop_Send, "m_viewPunchAngle", fNull);
        
        return Plugin_Handled; // Block Damage.
    }
    
    return Plugin_Continue;
}

public Action Timer_AllowDamage(Handle hTimer, DataPack dPack)
{
    int iAttacker = GetClientOfUserId(ReadPackCell(dPack));
    int iVictim = GetClientOfUserId(ReadPackCell(dPack));
    
    if (!IsValidClient(iAttacker) || !IsValidClient(iVictim)) {
        return Plugin_Stop;
    }
    
    g_bCanDealDamage[iAttacker][iVictim] = true;
    g_hDamageTimer[iAttacker][iVictim] = null;
    
    return Plugin_Stop;
}

stock bool IsValidClient(int iClient) {
    return iClient > 0 && iClient <= MaxClients && IsClientInGame(iClient);
} 


PHP Code:

g_bCanDealDamage[iAttacker][iVictim] = true; 


Would mean the attacker index can damage the victim index.

Let me know how it works!

[Neuro Toxin]

I would personally avoid timers per client and store a time instead.