[Miggy]

Hi folks,

I'm trying to add a function into my plugin that will grab a text file and take items in the text file and turn them into an array of strings(I believe this can be done with ExplodeString?). Then I would be grabbing info from the server and comparing them to said strings to see if there's a match.

For starters:
1) Is it possible to grab the contents of a text file and use ExplodeString to make it more manageable?
Or is there a better way?

2) I don't know diddly squat about arrays, the api doesn't really show me much and I can't find comprehensive guide. The SourceMod wiki explains it but the explanation really goes from A to Z really quick and I just get lost trying to figure out how to tie that into what I'm trying to do.

What I'm trying to do is have my plugin pull a text file of SteamID and IPs and look for a match between the txt list and players in the server. I know I could accomplish with a database but I'm wanting to keep it super simple until there is a need to have a database.

[Benoist3012]

can you show for us a example of what you want to do.

[Miggy]

Nothing I have coded is functioning anywhere near what I want it to do so I scrapped it all, mainly because I honestly don't understand how to work with arrays.
So currently I don't have code for that particle feature of my plugin.

I already have code that grabs the IPs and SteamIDs of the players in the server. Now I just need to grab that information and compare it to a txt file list of IPs and SteamIDs to see if there's a match.

Currently this is all I have working for the feature. I was even able to test it out so it would print the IPs and IDs to a txt file just to make sure it was pulling the information correctly:

PHP Code:

public Action:WhoAreYou(Handle:event, const String:name[], bool:dontBroadcast)
{
new client = GetClientOfUserId(GetEventInt(event, "userid"));

decl String:PlayerName[64], String:Authid[64], String:IPAddress[64];
GetClientName(client, PlayerName, 64);
GetClientIP(client, IPAddress, 64);
GetClientAuthId(client, AuthId_Steam2,Authid, 64);
//Do Stuff - Once figured out, Code to Compare IPs and IDs to list will go here
/**Testing out logging information just to see how it outputs so I'll know the formats I will use to compare
new Handle:FileHandle = OpenFile("cfg/player_address_log.txt", "a+");
WriteFileLine(FileHandle, "Alias: %s SteamID: %s  IP: %s", PlayerName, Authid, IPAddress);
CloseHandle(FileHandle);
**/
} 


[KissLick]

You can use KeyValues format

PHP Code:

"root"
{
    "steamid_1" "ip_1"
    "steamid_2" "ip_2"
    "steamid_2" "ip_2"
    .
    .
    .
    "steamid_n" "ip_n"
} 


Read it and store in adt_trie - use steamid as a key and ip as string value.

eg like this

PHP Code:

new g_hTrie = CreateTrie();

// ---

if (!FileExists(sPath)) {
    LogError("Cannot load from file '%s' - file doesn't exist!", sPath);
    return;
}

new Handle:hKV = CreateKeyValues("root");

if (!FileToKeyValues(hKV, sPath)) {
    CloseHandle(hKV);
    LogError("Cannot load data from file '%s' !", sPath);
    return;
}

if (!KvGotoFirstSubKey(hKV, false)) {
    CloseHandle(hKV);
    return;
}

new String:sSteamID[64], String:sIP[64];

do
{
    KvGetSectionName(hKV, sSteamID, sizeof(sSteamID));
    KvGetString(hKV, NULL_STRING, sIP, sizeof(sIP));
    
    SetTrieString(g_hTrie, sSteamID, sIP);
} while (KvGotoNextKey(hKV, false));

CloseHandle(hKV);

// ---

if (GetTrieArray(g_hTrie, sPlayersSteamID, sIP, sIP)) {
    // now we know that steamid is in the config file
    
    if (StrEqual(sPlayersIP, sIP)) {
        // player's ip and ip in config are same
        return true;
    }
} 


NOT tested...

[Miggy]

Cool, I tried compiling it as is and got a bunch of errors so I'm gonna have to sit down and really go through it.
Looks like I'll also have to read up on some adt though cause I'm not really 100% sure of what's going on in the script.
I get the idea of what each part does but I don't understand the "how" x.x

[KissLick]

Didn't test it, but try this

PHP Code:

#include <sourcemod>

#define CONFIG_PATH "configs/myconfig.cfg"

public Plugin:myinfo =
{
    name = "test",
    author = "Raska",
    description = "",
    version = "0.1",
    url = ""
}

new Handle:g_hTrie;

public OnMapStart()
{
    new String:sPath[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, sPath, sizeof(sPath), CONFIG_PATH);
    
    // create config file if doesn't exist
    if (!FileExists(sPath)) {
        new Handle:hFile = OpenFile(sPath, "w");
        WriteFileLine(hFile, "\"root\"");
        WriteFileLine(hFile, "{");
        WriteFileLine(hFile, "\t// \"steamid\" \"ip\"");
        WriteFileLine(hFile, "}");
        CloseHandle(hFile);
    }
    
    // create hashmap (adt_trie) structure
    if (g_hTrie != INVALID_HANDLE) {
        CloseHandle(g_hTrie);
    }
    g_hTrie = CreateTrie();
    
    // open config
    new Handle:hKV = CreateKeyValues("root");
    if (!FileToKeyValues(hKV, sPath)) {
        CloseHandle(hKV);
        LogError("Cannot load data from file '%s' !", sPath);
        return;
    }
    
    // read fondig
    if (!KvGotoFirstSubKey(hKV, false)) {
        CloseHandle(hKV);
        return;
    }
    
    new String:sSteamID[64], String:sIP[64];
    do
    {
        KvGetSectionName(hKV, sSteamID, sizeof(sSteamID));
        KvGetString(hKV, NULL_STRING, sIP, sizeof(sIP));
        
        SetTrieString(g_hTrie, sSteamID, sIP);
    } while (KvGotoNextKey(hKV, false));

    CloseHandle(hKV);
}

public OnClientAuthorized(iClient, const String:sAuth[])
{
    new String:sIP[64];
    
    if (GetTrieString(g_hTrie, sAuth, sIP, sizeof(sIP))) {
        // connected player is in config - let's check ip
        
        new String:sPlayersIP[64];
        GetClientIP(iClient, sPlayersIP, sizeof(sPlayersIP));
        
        if (StrEqual(sIP, sPlayersIP, false)) {
            // connected player is in config and IPs are same
        }
    }
} 


[Miggy]

Neat!
I'm trying to tweak it so it detects SteamID or IP rather than SteamID AND IP

[KissLick]

Originally Posted by Miggy Neat! I'm trying to tweak it so it detects SteamID or IP rather than SteamID AND IP

Something like this?

PHP Code:

#include <sourcemod>

#define CONFIG_PATH "configs/myconfig.cfg"

public Plugin:myinfo =
{
    name = "test",
    author = "Raska",
    description = "",
    version = "0.1",
    url = ""
}

new Handle:g_hPlayerList;

public OnMapStart()
{
    new String:sPath[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, sPath, sizeof(sPath), CONFIG_PATH);

    // create config file if doesn't exist
    if (!FileExists(sPath)) {
        new Handle:hFile = OpenFile(sPath, "w");
        WriteFileLine(hFile, "\"root\"");
        WriteFileLine(hFile, "{");
        WriteFileLine(hFile, "\t// \"steamid\" \"ip\"");
        WriteFileLine(hFile, "}");
        CloseHandle(hFile);
    }

    // create dynamic array (adt_array) structure
    if (g_hPlayerList != INVALID_HANDLE) {
        CloseHandle(g_hPlayerList);
    }
    g_hPlayerList = CreateArray(64);

    // open config
    new Handle:hKV = CreateKeyValues("root");
    if (!FileToKeyValues(hKV, sPath)) {
        CloseHandle(hKV);
        LogError("Cannot load data from file '%s' !", sPath);
        return;
    }

    // read condig
    if (!KvGotoFirstSubKey(hKV, false)) {
        CloseHandle(hKV);
        return;
    }

    new String:sSteamID[64], String:sIP[64];
    do
    {
        KvGetSectionName(hKV, sSteamID, sizeof(sSteamID));
        KvGetString(hKV, NULL_STRING, sIP, sizeof(sIP));

        PushArrayString(g_hPlayerList, sSteamID);
        PushArrayString(g_hPlayerList, sIP);
    } while (KvGotoNextKey(hKV, false));

    CloseHandle(hKV);
}

public OnClientAuthorized(iClient, const String:sAuth[])
{
    new String:sIP[64];
    GetClientIP(iClient, sIP, sizeof(sIP));

    if (FindStringInArray(g_hPlayerList, sAuth) != -1 || FindStringInArray(g_hPlayerList, sIP) != -1 ) {
        // connected player's ip or steamid is in config
    }
} 


[Miggy]

Something more like

PHP Code:

public OnClientAuthorized(iClient, const String:sAuth[])
{
decl String:PlayerName[64], String:sIP[64];
GetClientIP(iClient, sIP, sizeof(sIP));
GetClientName(iClient, PlayerName, 64);



if (FindStringInArray(g_hPlayerList, sAuth) != -1) {
        // connected player's steamid is in config
PrintToChatAll("%s is currently Banned in UGC", PlayerName);
PrintToConsole("Banned Player SteamID Connected"
}
    
if (FindStringInArray(g_hPlayerList, sIP) != -1 ) {
        // connected player's ip is in config
PrintToChatAll("%s is using IP Address which is associated with a Banned UGC Player", PlayerName);
PrintToConsole("Banned Player IP Connected")
} 


But my printtchatall/printtoconsole doesn't seem to be working.
It's always one thing after another, lol

[KissLick]

You don't need to use GetClientName, just use PrintToChatAll("%N is currently Banned in UGC", iClient);

Try add some debug print before these ifs, like PrintToChatAll("TESTING: %N:%s:%s", iClient, sAuth, sIP);