[Chdata]

PHP Code:

new Handle:SandvichTimers[TF_MAX_PLAYERS] = {INVALID_HANDLE,...};

public OnMapStart()
{
    for (new i = 1; i <= MaxClients; i++)
    {
        SandvichTimers[i]       = INVALID_HANDLE;
    }
}

public OnEventRoundStart(Handle:hEvent, const String:szStr, bool:bBool)
{
    for (new ionplay = 1; ionplay <= MaxClients; ionplay++)
    {
        ClearTimer(SandvichTimers[ionplay]);
    }
}

public OnClientDisconnect(client)
{
    ClearTimer(SandvichTimers[client]);
}

OnHeavyEatSandVich(iClient)
{
    SandvichTimers[iClient] = CreateTimer(1.0, tSandvichHeal, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
}

public Action:tSandvichHeal(Handle:hTimer, any:ref)
{
    new iClient = GetClientOfUserId(ref);

    if (!iClient || !IsClientInGame(iClient) || TF2_GetPlayerClass(iClient) != TFClass_Heavy)
    {
        SandvichTimers[iClient] = INVALID_HANDLE;
        return Plugin_Stop;
    }

    static timer[TF_MAX_PLAYERS] = 0;

    AddPlayerHealth(iClient, 1000, 0.0, true);

    // Perform healing 4 times (+1 because we did before this timer was made)
    if (++timer[iClient] >= 4) // Note: 3 would be the normal duration of eating
    {
        timer[iClient] = 0;
        SandvichTimers[iClient] = INVALID_HANDLE;
        return Plugin_Stop;
    }

    return Plugin_Continue;
}


stock ClearTimer(&Handle:hTimer)
{
    if (hTimer != INVALID_HANDLE)
    {
        KillTimer(hTimer);
        hTimer = INVALID_HANDLE;
    }
} 


My problem starts with

public Action:tSandvichHeal(

GetClientOfUserId returns 0 if the client is "no longer in the server".

If it returns 0, that means I cannot clear SandvichTimers[iClient] and can only clear SandvichTimers[0]. If I were to use CreateDataTimer so I can remember the iClient, it's possible for another player to connect to the server as the old player disconnects, thus fire the timer on someone when I don't want it to. [Same problem would happen if I pass the client index instead of the userid].

If I don't try to clear SandvichTimers during tSandvichHeal, then ClearTimer will try to close an invalid handle. If I do clear it, there's no guarantee that I will clear it properly.

I'm not sure if OnClientDisconnect really solves the issue either.

I'm not sure how to set this up.

[Miu]

your question is sort of confusing, but I'm guessing you want to clear the correct SandvichTimer index in the timer if the userid is not valid? just pass the client id along with the userid?

[Peace-Maker]

When closing and clearing the handle in OnClientDisconnect, the timer won't fire with an invalid userid. So you should never get a clientindex of 0.

[ici]

PHP Code:

new Handle:gH_SandvichTimers[TF_MAX_PLAYERS] = {INVALID_HANDLE, ...};
new g_Timers[TF_MAX_PLAYERS];

public OnMapStart()
{
    ClearAllTimers();
}

public OnClientDisconnect(client)
{
    ClearClientTimer(client);
}

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    ClearAllTimers();
}

public Action:Timer_SandvichHeal(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    
    if (!client || !IsClientInGame(client) || !IsPlayerAlive(client) || TF2_GetPlayerClass(client) != TFClass_Heavy) {
        g_Timers[client] = 0;
        gH_SandvichTimers[client] = INVALID_HANDLE;
        return Plugin_Stop;
    }
    
    AddPlayerHealth(client, 1000, 0.0, true);
    
    if (++g_Timers[client] >= 4) {
        g_Timers[client] = 0;
        gH_SandvichTimers[client] = INVALID_HANDLE;
        return Plugin_Stop;
    }
    
    return Plugin_Continue;
}

OnHeavyEatSandVich(client)
{
    gH_SandvichTimers[client] = CreateTimer(1.0, Timer_SandvichHeal, GetClientUserId(client), TIMER_REPEAT);
}

ClearClientTimer(client)
{
    if (gH_SandvichTimers[client] != INVALID_HANDLE) {
        KillTimer(gH_SandvichTimers[client]);
        gH_SandvichTimers[client] = INVALID_HANDLE;
        g_Timers[client] = 0;
    }
}

ClearAllTimers()
{
    for (new i = 1; i <= MaxClients; i++) {
        if (gH_SandvichTimers[i] != INVALID_HANDLE) {
            KillTimer(gH_SandvichTimers[i]);
            gH_SandvichTimers[i] = INVALID_HANDLE;
            g_Timers[i] = 0;
        }
    }
} 


[KyleS]

PHP Code:

new Handle:SandvichTimers[MAX_PLAYERS+1] = {INVALID_HANDLE,...};

public OnEventRoundStart(Handle:hEvent, const String:szStr[], bool:bBool)
{
    for (new i = MaxClients; i > 0; --i)
    {
        OnClientDisconnect(i);
    }
}

public OnClientDisconnect(client)
{
    tSandvichHeal(INVALID_HANDLE, client);
    ReplaceHandle(SandvichTimers[client], INVALID_HANDLE);
}

OnHeavyEatSandVich(iClient)
{
    ReplaceHandle(SandvichTimers[iClient], CreateTimer(1.0, tSandvichHeal, iClient, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT));
}

public Action:tSandvichHeal(Handle:hTimer, any:iClient)
{
    static timer[MAXPLAYERS+1];
    if (!IsClientInGame(iClient) || TF2_GetPlayerClass(iClient) != TFClass_Heavy || ++timer[iClient] >= 4)
    {
        timer[iClient] = 0;
        ReplaceHandle(SandvichTimers[iClient], INVALID_HANDLE);
        return Plugin_Stop;
    }

    AddPlayerHealth(iClient, 1000, 0.0, true);
    return Plugin_Continue;
}

static stock ReplaceHandle(Handle:&hNew, Handle:hSource) /* Probably Illegal on newer compilers from an array. */
{
    if (hNew != INVALID_HANDLE)
    {
        CloseHandle(hNew);
    }

    hNew = hSource;
} 


[Chdata]

That's an interesting one, KyleS.

Sometimes, for OnClientDisconnect, IsClientInGame() can still return true.

Should I check IsClientConnected in the timer?

I'm not sure what calling the timer func is for OnClientDisconnected otherwise. It'll either try to heal someone as they're disconnecting (which should always be the case if they just ate a sandvich - they're only not InGame if they're still connecting to the server) or fire ReplaceHandle twice which does the same thing. In some cases it'll reset the static timer there if you disconnect near the last iteration. Maybe I should check if hTimer == INVALID_HANDLE?

I didn't know it was safe to closehandle a timer from within the timer ;O

Thanks for the help, this might solve issues I've been having with lots of other timers.

Edit: Nope, you can't close timers from within the same timer. I changed the replacehandles in the timer to just set the global handle to INVALID_HANDLE.

It seems like it's good now though.