[XenTerSiO]

Is it possible to completely turn off the MOTD window on the server?
Game: Counter-Strike: Source

[NinjaSK]

I wonder what happens if you just delete motd.txt on your server

[XenTerSiO]

Still displays the standard Windows

[Bacardi]

Originally Posted by XenTerSiO Is it possible to completely turn off the MOTD window on the server? Game: Counter-Strike: Source

This block motd window whenever server try send it to players.
*edit
to clarify, not show motd when player join to server and type motd in chat.
But if player type in they own console spec_help, then it shows up.

Spoiler

PHP Code:

public OnPluginStart()
{
    HookUserMessage(GetUserMessageId("VGUIMenu"), VGUIMenu, true);
}

public Action:VGUIMenu(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
    new String:buffer[5];
    BfReadString(bf, buffer, sizeof(buffer));
    if(StrEqual(buffer, "info"))
    {
        return Plugin_Handled;
    }
    return Plugin_Continue;
} 


[XenTerSiO]

Thank you very much, it works!

[BLITZR]

PHP Code:

public OnPluginStart()
{
    HookUserMessage(GetUserMessageId("VGUIMenu"), VGUIMenu, true);
}
 
public Action:VGUIMenu(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
    new String:buffer[5];
    BfReadString(bf, buffer, sizeof(buffer));
    if(StrEqual(buffer, "info"))
    {
        return Plugin_Handled;
    }
    return Plugin_Continue;
} 


Hi all.

Hopefully you guys don't mind me hijacking this thread

This plugin works like a charm Bacardi, thank you. However I was hoping someone could help me make this pop up the team select menu, ontop of blocking the motd as it does now.

Cheers.

ps. The game is Counter-strike: Source.

[Bacardi]

untested

public OnPluginStart()
{
	HookUserMessage(GetUserMessageId("VGUIMenu"), VGUIMenu, true);
}

public Action:VGUIMenu(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
	new String:buffer[5];
	BfReadString(bf, buffer, sizeof(buffer));
	if(StrEqual(buffer, "info"))
	{
		return Plugin_Handled;
	}
	return Plugin_Continue;
}

public OnClientPutInServer(client)
{
	CreateTimer(3.0, timer_menu, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
}

public Action:timer_menu(Handle:timer, any:userid)
{
	new client = GetClientOfUserId(userid);
	if(client != 0 && !IsFakeClient(client))
	{
		ShowVGUIPanel(client, "team", INVALID_HANDLE, true);
	}
}

[BLITZR]

Thank you Bacardi. That worked perfectly, much appreciated.

[Bacardi]

...csgo
*block motd when player enter on level

PHP Code:

#include <cstrike>

new Handle:g_hTimers[MAXPLAYERS+1];

public OnPluginStart()
{
    //HookUserMessage(GetUserMessageId("VGUIMenu"), VGUIMenu, true);
    HookEventEx("player_connect_full", player_activate);
    AddCommandListener(joingame, "joingame");
}

public Action:joingame(client, const String:command[], argc)
{
    //PrintToServer("%s", command);
    if(g_hTimers[client] != INVALID_HANDLE)
    {
        KillTimer(g_hTimers[client]);
        g_hTimers[client] = INVALID_HANDLE;
    }
}

public player_activate(Handle:event, const String:name[], bool:dontBroadcast)
{
    //PrintToServer("player_activate = %s", name);
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    g_hTimers[client] = CreateTimer(0.1, clearmotd, client, TIMER_REPEAT);
}

public Action:clearmotd(Handle:timer, any:client)
{
    //PrintToServer("clearmotd %i", client);

    if(client == 0 || !IsClientInGame(client) || IsFakeClient(client))
    {
        g_hTimers[client] = INVALID_HANDLE;
        return Plugin_Stop;
    }

    new Handle:pb = StartMessageOne("VGUIMenu", client);
    PbSetString(pb, "name", "info");
    PbSetBool(pb, "show", false);

    new Handle:subkey;

    subkey = PbAddMessage(pb, "subkeys");
    PbSetString(subkey, "name", "title");
    PbSetString(subkey, "str", "");

    subkey = PbAddMessage(pb, "subkeys");
    PbSetString(subkey, "name", "type");
    PbSetString(subkey, "str", "0");

    subkey = PbAddMessage(pb, "subkeys");
    PbSetString(subkey, "name", "msg");
    PbSetString(subkey, "str", "");

    subkey = PbAddMessage(pb, "subkeys");
    PbSetString(subkey, "name", "cmd");
    PbSetString(subkey, "str", "1");
    EndMessage();

    return Plugin_Continue;

}

/*
public Action:VGUIMenu(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
    new String:buffer[5];

    if(GetUserMessageType() == UM_Protobuf) // CSGO
    {
        PbReadString(bf, "name", buffer, sizeof(buffer));
        if(StrEqual(buffer, "info") && reliable)
        {
            return Plugin_Handled;
        }
    }
    return Plugin_Continue;
}
*/