[REQ] CS1.6 plugins based on Orpheu Module.

yokomo · **Author**

Hi, i'm requesting 3 CS1.6 plugins using Orpheu module.

Plugins list:
1. Remove buyzone.
2. Unlimited buyzone (everywhere is buyzone).
3. Remove slowdown after landing (like cs1.3).

That's all, ok thanks.

kotinha · 02-05-2012 , 10:10 Re: [REQ] CS1.6 plugins based on Orpheu Module.

You don't need orpheu for that...
Buyzone Range
Bunny Hop Abilities

Devil259 · 02-05-2012 , 10:14 Re: [REQ] CS1.6 plugins based on Orpheu Module.

1.

Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >

new const info_map_parameters[ ] = "info_map_parameters";

new g_hSpawn;

public plugin_precache( ) 
{
    new iEntity = create_entity( info_map_parameters );
    DispatchKeyValue( iEntity, "buying", "3" );
    DispatchSpawn( iEntity );
    
    g_hSpawn = register_forward( FM_Spawn, "FwdSpawn" );
}

public FwdSpawn( iEnt ) 
{
    static szClassname[ 32 ];
    entity_get_string( iEnt, EV_SZ_classname, szClassname, 31 );
    
    if( equal( szClassname, info_map_parameters ) ) {
        remove_entity( iEnt );
        
        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
}

public plugin_init( ) 
{
    if( g_hSpawn > 0 ) 
    {
        unregister_forward( FM_Spawn, g_hSpawn );
    }
}

3.

Code:

#include < amxmodx >
#include < fakemeta >

public plugin_init( )
{
    register_forward( FM_PlayerPreThink , "fwdPlayerPreThink" , 0 )
}

public fwdPlayerPreThink( id )
{
    if( is_user_alive( id ) )
    {
        set_pev( id, pev_fuser2 , 0.0 )
    }
}

ConnorMcLeod · *Last edited by ConnorMcLeod; 02-05-2012 at 13:40.*

2. Better to use fakemeta or engine.

PHP Code:


			
#include <amxmodx>
#include <fakemeta_stocks>

#define VERSION "0.0.1"
#define PLUGIN "Buy EveryWhere"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
}

public plugin_precache()
{
    new ent = EF_CreateNamedEntity(EF_AllocString("func_buyzone"))
    DF_Spawn(ent)
    EF_SetSize(ent, Float:{-8192.0, -8192.0, -8192.0}, Float:{8192.0, 8192.0, 8192.0})
}

3.

PHP Code:


			
/*    Formatright © 2010, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

//#define AUTO_ENABLE_AXN

#include <amxmodx>
#include <amxmisc>
#include <orpheu>
#include <orpheu_memory>

#define VERSION "0.0.1"
#define PLUGIN ""

const OrpheuHook:OrpheuInvalidHook = OrpheuHook:0

new g_flJumpSlowDown, g_flBunnyJumpMaxSpeedFactor
new OrpheuStruct:pmove
new Float:g_flUseReduceSpeed

new bool:g_bIsCz

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    new szModName[7]
    get_modname(szModName, charsmax(szModName))
    g_bIsCz = !!equal(szModName, "czero")
#if defined AUTO_ENABLE_AXN
    SetJumpSlowDown( 0x00000000 ) // 0.0
    SetBunnyJumpMaxSpeedFactor( 0x00000000 ) // 0.0
    SetUseReduceSpeedFactor( 0.3 )
#endif

    register_concmd("amx_set_jump_slowdown", "ConCmd_SetJumpSlowDown", ADMIN_CFG)
    register_concmd("amx_reset_jump_slowdown", "ConCmd_ResetJumpSlowDown", ADMIN_CFG)

    register_concmd("amx_set_bj_maxspeed_factor", "ConCmd_SetBjMsFact", ADMIN_CFG)
    register_concmd("amx_reset_bj_maxspeed_factor", "ConCmd_ResetBjMsFact", ADMIN_CFG)

    register_concmd("amx_set_use_reducespeed_factor", "ConCmd_SetUseRecuceFact", ADMIN_CFG)
    register_concmd("amx_reset_use_reducespeed_factor", "ConCmd_ResetUseRecuceFact", ADMIN_CFG)
}

public ConCmd_SetJumpSlowDown(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 2) )
    {
        new szValue[32]
        read_argv(1, szValue, charsmax(szValue))
        SetJumpSlowDown( floatmax(0.0, str_to_float(szValue)) )
    }
    return PLUGIN_HANDLED
}

public ConCmd_ResetJumpSlowDown(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 0) )
    {
        SetJumpSlowDown( 0x44A47943 )
    }
    return PLUGIN_HANDLED
}

public ConCmd_SetBjMsFact(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 2) )
    {
        new szValue[32]
        read_argv(1, szValue, charsmax(szValue))
        SetBunnyJumpMaxSpeedFactor( floatmax(0.0, str_to_float(szValue)) )
    }
    return PLUGIN_HANDLED
}

public ConCmd_ResetBjMsFact(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 0) )
    {
        SetBunnyJumpMaxSpeedFactor( 0x3F99999A )
    }
    return PLUGIN_HANDLED
}

public ConCmd_SetUseRecuceFact(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 2) )
    {
        new szValue[32]
        read_argv(1, szValue, charsmax(szValue))
        SetUseReduceSpeedFactor( floatclamp(str_to_float(szValue), 0.0, 1.0) )
    }
    return PLUGIN_HANDLED
}

public ConCmd_ResetUseRecuceFact(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 0) )
    {
        SetUseReduceSpeedFactor( 0.0 )
    }
    return PLUGIN_HANDLED
}

SetJumpSlowDown( {_,Float}:Value )
{
    server_print("Jump_SlowDown changed from %f to %f", OrpheuMemoryGet(g_bIsCz ? "Jump_SlowDown_CZ" : "Jump_SlowDown"), Value)
    OrpheuMemorySet(g_bIsCz ? "Jump_SlowDown_CZ" : "Jump_SlowDown", 1, Value)
    g_flJumpSlowDown = Value
}

SetBunnyJumpMaxSpeedFactor( {_,Float}:Value )
{
    server_print("BUNNYJUMP_MAX_SPEED_FACTOR from %f to %f", OrpheuMemoryGet(g_bIsCz ? "BUNNYJUMP_MAX_SPEED_FACTOR_CZ" : "BUNNYJUMP_MAX_SPEED_FACTOR"), Value)
    OrpheuMemorySet(g_bIsCz ? "BUNNYJUMP_MAX_SPEED_FACTOR_CZ" : "BUNNYJUMP_MAX_SPEED_FACTOR", 1, Value)
    g_flBunnyJumpMaxSpeedFactor = Value
}

SetUseReduceSpeedFactor( Float:flValue )
{
    static OrpheuFunction:oFnPM_Move = OrpheuInvalidFunction, OrpheuFunction:oFnPM_Duck = OrpheuInvalidFunction
    if( !oFnPM_Move || !oFnPM_Duck )
    {
        oFnPM_Move = OrpheuGetFunction("PM_Move")
        oFnPM_Duck = OrpheuGetFunction("PM_Duck")
    }

    static OrpheuHook:iOhPM_Move = OrpheuInvalidHook, OrpheuHook:iOhPM_Duck = OrpheuInvalidHook
    if( 0.0 < flValue < 1.0 )
    {
        if( !iOhPM_Move )
        {
            iOhPM_Move = OrpheuRegisterHook(oFnPM_Move, "OnPM_Move", OrpheuHookPre)
        }
        if( !iOhPM_Duck )
        {
            iOhPM_Duck = OrpheuRegisterHook(OrpheuGetFunction("PM_Duck"), "OnPM_Duck_Post", OrpheuHookPost)
        }
        g_flUseReduceSpeed = flValue
    }
    else
    {
        if( iOhPM_Move )
        {
            OrpheuUnregisterHook( iOhPM_Move )
            iOhPM_Move = OrpheuInvalidHook
        }
        if( iOhPM_Duck )
        {
            OrpheuUnregisterHook( iOhPM_Duck )
            iOhPM_Duck = OrpheuInvalidHook
        }
        g_flUseReduceSpeed = 0.0
    }
}

public OnPM_Duck_Post()
{
    const IN_USE = (1<<5)

    if(    OrpheuGetStructMember(OrpheuStruct:OrpheuGetStructMember( pmove, "cmd" ), "buttons" ) & IN_USE
    &&    OrpheuGetStructMember(pmove, "onground") != -1    )
    {
        new Float:fVecVelocity[3]
        OrpheuGetStructMember(pmove, "velocity", fVecVelocity)
        fVecVelocity[0] *= g_flUseReduceSpeed
        fVecVelocity[1] *= g_flUseReduceSpeed
        fVecVelocity[2] *= g_flUseReduceSpeed
        OrpheuSetStructMember(pmove, "velocity", fVecVelocity)
    }
}

public OnPM_Move( OrpheuStruct:ppmove /* , server */ )
{
    pmove = ppmove
}

public plugin_unpause()
{
    SetBunnyJumpMaxSpeedFactor( g_flJumpSlowDown ) // 0.0
    SetJumpSlowDown( g_flBunnyJumpMaxSpeedFactor ) // 0.0
    SetUseReduceSpeedFactor( g_flUseReduceSpeed )
}

public plugin_pause()
{
    SetBunnyJumpMaxSpeedFactor( 0x3F99999A ) // 1.2        9A 99 99 3F
    SetJumpSlowDown( 0x44A47943 ) // 1315.7894287109375
    SetUseReduceSpeedFactor( 0.0 )
}

public plugin_end()
{
    SetBunnyJumpMaxSpeedFactor( 0x3F99999A ) // 1.2
    SetJumpSlowDown( 0x44A47943 ) // 1315.7894287109375
}

yokomo · 02-05-2012 , 13:45 Re: [REQ] CS1.6 plugins based on Orpheu Module.

Oh no need to use Orpheu? which 1 is efficient? using fakemeta or orpheu. Ok nevermind all 3 plugins has been done. Thanks all.

ConnorMcLeod · 02-05-2012 , 13:49 Re: [REQ] CS1.6 plugins based on Orpheu Module.

I can't find 1.6 files, sorry.

Code:

{
	"name" : "BUNNYJUMP_MAX_SPEED_FACTOR_CZ",
    "library"     : "mod",
    "type"        : "float",
    "memoryType"  : "rodata",
	"identifiers" : 
	[
		{
			"os"    : "linux",
			"mod"   : "cstrike",
			"value" : 0x1BF168
		}
	]
}

Code:

{
	"name" : "Jump_SlowDown_CZ",
    "library"     : "mod",
    "type"        : "float",
    "memoryType"  : "rodata",
	"identifiers" : 
	[
		{
			"os"    : "windows",
			"mod"   : "cstrike",
			"value" : [0x51,0x8B,0x0D,"*","*","*","*",0x53,0x8B,0x81,0xD0,0x00,0x00,0x00,0x85,0xC0,0x74,0x11,0x8B,0x81,0xC8],
			"displacement" : 0x32B
		},
		{
			"os"    : "linux",
			"mod"   : "cstrike",
			"value" : 0x1BF1B8
		}
	]
}

yokomo · 04-16-2012 , 05:11 Re: [REQ] CS1.6 plugins based on Orpheu Module.

ConnorMcLeod
How to install plugin no 3? i got error:

Code:

L 04/16/2012 - 16:52:57: Start of error session.
L 04/16/2012 - 16:52:57: Info (map "de_inferno") (file "addons/amxmodx/logs/error_20120416.log")
L 04/16/2012 - 16:52:57: [ORPHEU] Invalid memory structure "BUNNYJUMP_MAX_SPEED_FACTOR_CZ"
L 04/16/2012 - 16:52:57: [AMXX] Displaying debug trace (plugin "NoSlowDown.amxx")
L 04/16/2012 - 16:52:57: [AMXX] Run time error 10: native error (native "OrpheuMemoryGet")
L 04/16/2012 - 16:52:57: [AMXX]    [0] NoSlowDown.sma::SetBunnyJumpMaxSpeedFactor (line 130)
L 04/16/2012 - 16:52:57: [AMXX]    [1] NoSlowDown.sma::plugin_init (line 47)
L 04/16/2012 - 16:57:03: [ORPHEU] Invalid memory structure "BUNNYJUMP_MAX_SPEED_FACTOR_CZ"
L 04/16/2012 - 16:57:03: [AMXX] Displaying debug trace (plugin "NoSlowDown.amxx")
L 04/16/2012 - 16:57:03: [AMXX] Run time error 10: native error (native "OrpheuMemoryGet")
L 04/16/2012 - 16:57:03: [AMXX]    [0] NoSlowDown.sma::SetBunnyJumpMaxSpeedFactor (line 130)
L 04/16/2012 - 16:57:03: [AMXX]    [1] NoSlowDown.sma::plugin_end (line 210)

Meta version:

Code:

   Metamod version 1.19p32 Copyright (c) 2001-2006 Will Day
     Patch: Metamod-P (mm-p) v32 Copyright (c) 2004-2007 Jussi Kivilinna
   Metamod comes with ABSOLUTELY NO WARRANTY; for details type `meta gpl'.
   This is free software, and you are welcome to redistribute it
   under certain conditions; type `meta gpl' for details.
   

   AMX Mod X version 1.8.2-dev Copyright (c) 2004-2006 AMX Mod X Development Team 
   AMX Mod X comes with ABSOLUTELY NO WARRANTY; for details type `amxx gpl'.
   This is free software and you are welcome to redistribute it under 
   certain conditions; type 'amxx gpl' f

Meta list:

Code:

Currently loaded plugins:
      description      stat pend  file              vers      src   load  unlod
 [ 1] AMX Mod X        RUN   -    amxmodx_mm.dll    v1.8.2-d  ini   Start ANY  
 [ 2] Orpheu           RUN   -    orpheu_amxx.dll   v2.3a     pl1   ANY   ANY  
 [ 3] CS Team Changer  RUN   -    cs_team_changer_  v1.0b     pl1   ANY   ANY  
 [ 4] Cvar Utilities   RUN   -    cvar_util_amxx.d  v1.3.1    pl1   ANY   ANY  
 [ 5] Fun              RUN   -    fun_amxx.dll      v1.8.2-d  pl1   ANY   ANY  
 [ 6] Engine           RUN   -    engine_amxx.dll   v1.8.2-d  pl1   ANY   ANY  
 [ 7] FakeMeta         RUN   -    fakemeta_amxx.dl  v1.8.2-d  pl1   ANY   ANY  
 [ 8] CStrike          RUN   -    cstrike_amxx.dll  v1.8.2-d  pl1   ANY   ANY  
 [ 9] CSX              RUN   -    csx_amxx.dll      v1.8.2-d  pl1   ANY   ANY  
 [10] Ham Sandwich     RUN   -    hamsandwich_amxx  v1.8.2-d  pl1   ANY   ANY  
10 plugins, 10 running

Plugin list:

Code:

----- Currently loaded plugins -----
name               version     author            file             status   
Admin Base         1.8.2       AMXX Dev Team     admin.amxx       running  
CU: amx_cvar Fix   1.0         Arkshine          cu_amx_cvar_fix  running  
Admin Commands     1.8.2       AMXX Dev Team     admincmd.amxx    running  
Admin Help         1.8.2       AMXX Dev Team     adminhelp.amxx   running  
Menus Front-End    1.8.2       AMXX Dev Team     menufront.amxx   running  
Commands Menu      1.8.2       AMXX Dev Team     cmdmenu.amxx     running  
Players Menu       1.8.2       AMXX Dev Team     plmenu.amxx      running  
Teleport Menu      1.8.2       AMXX Dev Team     telemenu.amxx    running  
Maps Menu          1.8.2       AMXX Dev Team     mapsmenu.amxx    running  
Plugin Menu        1.8.2       AMXX Dev Team     pluginmenu.amxx running
Admin Chat         1.8.2       AMXX Dev Team     adminchat.amxx   running  
Admin Votes        1.8.2       AMXX Dev Team     adminvote.amxx   running  
NextMap            1.8.2       AMXX Dev Team     nextmap.amxx     running  
Nextmap Chooser    1.8.2       AMXX Dev Team     mapchooser.amxx  running  
TimeLeft           1.8.2       AMXX Dev Team     timeleft.amxx    running  
Stats Configurati  1.8.2       AMXX Dev Team     statscfg.amxx    running  
StatsX             1.8.2       AMXX Dev Team     statsx.amxx      running  
get_user_team fix  0.0.1       ConnorMcLeod      get_user_team_f  running  
No Shield          0.2.0       ConnorMcLeod      noshield.amxx    running  
[CS] Ham Hooks fo  1.0         WiLS              cs_ham_bots_api  running  
[CS] Weapon Model  1.1         WiLS              cs_weap_models_  running  
Server Cvars Unlo  1.0.1       Arkshine          server_cvars_un  running  
CSDM NightVision   0.0.1       wbyokomo          CsdmNvg.amxx     running  
Loading Sound      1.0         Amxx User         loadingsound.am  running  
Connect Messages   0.0.1       GHW_Chronic       ConnectInfo.amx  running  
HE Damage Multipl  0.0.1       wbyokomo          CsdmHeMultiplie  running  
CSDM Kill Vox      0.0.1       wbyokomo          CsdmKillVox.amx  running  
Custom Knife Dist  1.0.1       Arkshine          custom_knife_di  running  
Strong Knife       0.0.1       wbyokomo          StrongKnife.amx  running  
Dark Sky           0.0.1       wbyokomo          RandomDarkSky.a running
No Slow Down       0.0.1       ConnorMcLeod      NoSlowDown.amxx  debug

I'm using listenserver

Code:

] status
hostname:  Condition Zero
version :  48/1.0.0.3/2.0.1333.551 4554 insecure  (80)
tcp/ip  :  192.168.1.254:27015
map     :  de_inferno at: -1711 x, 432 y, -10 z
players :  10 active (32 max)

Devil259 · 04-16-2012 , 05:27 Re: [REQ] CS1.6 plugins based on Orpheu Module.

Install Orpheu. http://forums.alliedmods.net/showthread.php?t=116393

yokomo · 04-16-2012 , 06:32 Re: [REQ] CS1.6 plugins based on Orpheu Module.

Quote:

Originally Posted by Devil259

Install Orpheu. http://forums.alliedmods.net/showthread.php?t=116393

Code:

 [ 2] Orpheu           RUN   -    orpheu_amxx.dll   v2.3a     pl1   ANY   ANY

Installed already.

Devil259 · 04-16-2012 , 06:40 Re: [REQ] CS1.6 plugins based on Orpheu Module.

Yes, misread sorry.
Have you installed signature ?