[Scherzo]

Server Queries

Library to asynchronous request fetching information about other server of HL game. Server queries - Valve Developer Community


Available requests:

Ping. Online state check.

stock ServerPing(const szServer[], const szCallback[]);

new const SERVER_ADDRESS[] = "192.168.0.14:27015";

public ping()
{
        ServerPing(SERVER_ADDRESS, "cbPing");
        return PLUGIN_HANDLED;
}

public cbPing(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(success)
        {
                client_print(0, print_chat, "Server %s is Online latency = %d", szServer, latency);
        }
        else
        {
                client_print(0, print_chat, "Server %s is Offline", szServer);
        }
}

Info. Server name, map name, current number of players, max number of players, name of game.

stock ServerInfo(const szServer[], const szCallback[]);

new const SERVER_ADDRESS[] = "192.168.0.14:27015";

public info()
{       
        ServerInfo(SERVER_ADDRESS, "cbInfo");
        return PLUGIN_HANDLED;
}

public cbInfo(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{               
        if(!success)
                return;
                        
        new szName[64], szMap[64], szDirectory[64], szDescription[64];
        new iPlayers = 0;
        new iMaxPlayers = 0;
        
        ServerResponseParseInfo(Response, szName, 63, szMap, 63, szDirectory, 63, szDescription, 63, iPlayers, iMaxPlayers);
        
        client_print(0, print_chat, "Server name: %s", szName);
        client_print(0, print_chat, "Map: %s", szMap);
        client_print(0, print_chat, "Folder: %s", szDirectory);
        client_print(0, print_chat, "Description: %s", szDescription);
        client_print(0, print_chat, "Players: %d / %d", iPlayers, iMaxPlayers);
}

Rules. List of spoonable cvars.
! Response can be in few packes, so callback can be called few times per one use.

stock ServerRules(const szServer[], const szCallback[]);

new const SERVER_ADDRESS[] = "192.168.0.14:27015";

public rules()
{       
        if(ServerGetChallenge(SERVER_ADDRESS))
        {       
                ServerRules(SERVER_ADDRESS, "cbRules");
        }
        else
        {
                ServerChallenge(SERVER_ADDRESS, "cbChallengeRules");
        }
        return PLUGIN_HANDLED;
}

public cbChallengeRules(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(!success)
                return;
                
        //Get and cche challenge        
        new challenge_value = ServerResponseParseChallenge(Response);
        ServerSetChallenge(szServer, challenge_value);
        
        //Now can get Rules
        ServerRules(SERVER_ADDRESS, "cbRules");
}

public cbRules(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(!success)
                return;
        
        new szValue[32];
        if(ServerResponseParseRules(Response, len, "sv_alltalk", szValue, 31))
        {
                client_print(0, print_chat, "Rule: sv_alltalk ^"%s^"", szValue);
        }
}

Player. List players on server.

stock ServerPlayer(const szServer[], const szCallback[]);

new const SERVER_ADDRESS[] = "192.168.0.14:27015";

public player()
{       
        if(ServerGetChallenge(SERVER_ADDRESS))
        {       
                ServerPlayer(SERVER_ADDRESS, "cbPlayer");
        }
        else
        {
                ServerChallenge(SERVER_ADDRESS, "cbChallengePlayer");
        }
        return PLUGIN_HANDLED;
}

public cbChallengePlayer(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(!success)
                return;
                
        //Get and cache challenge       
        new challenge_value = ServerResponseParseChallenge(Response);
        ServerSetChallenge(szServer, challenge_value);
        
        //Now can get Player
        ServerPlayer(SERVER_ADDRESS, "cbPlayer");
}


public cbPlayer(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(!success)
                return;
                
        new iPlayers = ServerResponseParsePlayerNum(Response);
        
        client_print(0, print_chat, "Players: %d", iPlayers);
        
        new szNick[32], id, kills, Float:uptime;
        for(new i=0;i<iPlayers; i++)
        {
                if(ServerResponseParsePlayer(Response, i, id, szNick, 31, kills, uptime))
                {
                        client_print(0, print_chat, "%d %s |  kills:%d, uptime = %f", id, szNick, kills, uptime);
                }
        }
        
        ServerResponseSave("Player", Response, len);
}

Challenge. Required code for Player i Rules

stock ServerChallenge(const szServer[], const szCallback[]);

new const SERVER_ADDRESS[] = "192.168.0.14:27015";

public challenge()
{       
        ServerChallenge(SERVER_ADDRESS, "cbChallenge");
        return PLUGIN_HANDLED;
}

public cbChallenge(const szServer[], _A2A_TYPE, const Response[], len, success, latency)
{
        if(!success)
                return;
                
        new challenge_value = ServerResponseParseChallenge(Response);
        client_print(0, print_chat, "Challenge: %X", challenge_value);
}

[Arkshine]

Is not already made ? https://forums.alliedmods.net/showthread.php?t=142858

EDIT: Ah, well, guess more complete.

[Scherzo]

Maybe, didn`t see that. Having few solutions for same problem is nice whenever.

[xakintosh]

Thanks very usefful.

[K.K.Lv]

the Rules reply type has been changed.
will be better to catch packet to re-check it .
also I have post the info at this post.
http://forums.alliedmods.net/showpos...66&postcount=3

[xPaw]

Originally Posted by K.K.Lv the Rules reply type has been changed. will be better to catch packet to re-check it . also I have post the info at this post. http://forums.alliedmods.net/showpos...66&postcount=3

It didn't change. 0x56 is correct. On your screenshot you have "E" character, which is 0x45, that stands for answer. Everything is correct.

PHP Code:

    /**
     * Packets sent
     */
    const A2S_PING      = 0x69;
    const A2S_INFO      = 0x54;
    const A2S_PLAYER    = 0x55;
    const A2S_RULES     = 0x56;
    
    /**
     * Packets received
     */
    const S2A_PING      = 0x6A;
    const S2A_CHALLENGE = 0x41;
    const S2A_INFO      = 0x49;
    const S2A_INFO_OLD  = 0x6D; // Old GoldSource, HLTV uses it
    const S2A_PLAYER    = 0x44;
    const S2A_RULES     = 0x45;
    const S2A_RCON      = 0x6C; 


[K.K.Lv]

Originally Posted by xPaw It didn't change. 0x56 is correct. On your screenshot you have "E" character, which is 0x45, that stands for answer. Everything is correct. PHP Code:     /**      * Packets sent      */     const A2S_PING      = 0x69;     const A2S_INFO      = 0x54;     const A2S_PLAYER    = 0x55;     const A2S_RULES     = 0x56;       /**      * Packets received      */     const S2A_PING      = 0x6A;     const S2A_CHALLENGE = 0x41;     const S2A_INFO      = 0x49;     const S2A_INFO_OLD  = 0x6D; // Old GoldSource, HLTV uses it     const S2A_PLAYER    = 0x44;     const S2A_RULES     = 0x45;     const S2A_RCON      = 0x6C;

in pass, we usually use this

if (buffer[4] == 0x45)

but now
I use this

if (buffer[13] == 0x45)

you can use this inc file to check it .
you will find the first var was wrong .
all I have test .

[xPaw]

Originally Posted by K.K.Lv if (buffer[13] == 0x45)

This is incorrect. You have to properly read split packets to receive correct answer.
https://developer.valvesoftware.com/...eries#Protocol

[K.K.Lv]

I have test my own steam server, you can use WPE Pro to cacth packet.

[xPaw]

Originally Posted by K.K.Lv I have test my own steam server, you can use WPE Pro to cacth packet.

What are you trying to say?

Changing [5] to [13] is a work around, and won't lead to proper result. It's shifted because when packets are split, there is information prepended about split packets. You really should read wiki article.