[MAUGHOLD]

This plugin works, but once the player get's their kills reset, and then goes on to get 256 deaths, the server still crashes.

Also, the say to the player about their score being reset, doesn't seem to stay on the screen long enough.

Can someone fix this so that it resets a players deaths ?

Thanks.

[ConnorMcLeod]

Have you tried dod_maxkds 254 instead of 255 ?

[MAUGHOLD]

Originally Posted by ConnorMcLeod Have you tried dod_maxkds 254 instead of 255 ?

yes, it doesn't seem to matter, what you set it to. it just wasn't counting deaths.

I just crashed a server running the version that I posted here. I noticed that my deaths were at 259 and the server crashed.

Thanks connor, I will try you're version

[ConnorMcLeod]

If it works, i'll look in dodx module, maybe i can remove those messages hooks and use client_score + client_death + 1 msg hook left.

[MAUGHOLD]

Originally Posted by ConnorMcLeod If it works, i'll look in dodx module, maybe i can remove those messages hooks and use client_score + client_death + 1 msg hook left.

Can you add a way to quickly test this by adding kills to an admins deaths with the amxmodx menu ?

I can set the dod_maxkds to 10 and upload the amxx.cfg. buts it's easier doing it in game with the cvar menu.

It resets both kills and deaths, but it doesn't notify the player about either.

[ConnorMcLeod]

Better to stay with register_message.

PHP Code:

/*    Formatright © 2011, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#define TEST_PLUGIN

#include <amxmodx>
#include <dodfun>

#if defined TEST_PLUGIN
    #include <amxmisc>
#endif

#define VERSION "0.0.3"
#define PLUGIN "Dod Max Score"

new dod_maxkds

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    dod_maxkds = register_cvar("dod_maxkds", "255")
    register_message(get_user_msgid("ScoreShort"), "Message_ScoreShort") // dod_set_pl_deaths
    register_message(get_user_msgid("ObjScore"), "Message_ObjScore") // dod_set_user_score
    register_message(get_user_msgid("Frags"), "Message_Frags") // dod_set_user_kills

    #if defined TEST_PLUGIN
        register_concmd("dod_set_user_score", "ClCmd_SetUserScore", _ , "<name/steam/#userid> <frags> <deaths> <score>")
    #endif
}

public Message_Frags(iMsgId, iMsgDest, iMsgEnt)
{
    if( get_msg_arg_int(2) >= get_pcvar_num( dod_maxkds ) )
    {
        set_msg_arg_int(2, ARG_SHORT, 0)
        new id = get_msg_arg_int(1)
        if( dod_set_user_stats(id, 0, 0, 0, .updatefrags=0) )
        {
            NotifyReset(id)
        }
    }
}

public Message_ObjScore(iMsgId, iMsgDest, iMsgEnt)
{
    if( get_msg_arg_int(2) >= get_pcvar_num( dod_maxkds ) )
    {
        set_msg_arg_int(2, ARG_SHORT, 0)
        new id = get_msg_arg_int(1)
        if( dod_set_user_stats(id, 0, 0, 0, .updatescore=0) )
        {
            NotifyReset(id)
        }
    }
}

public Message_ScoreShort(iMsgId, iMsgDest, iMsgEnt)
{
    new iMaxKds = get_pcvar_num( dod_maxkds )
    if(    get_msg_arg_int(2) >= iMaxKds
    ||        get_msg_arg_int(3) >= iMaxKds
    ||        get_msg_arg_int(4) >= iMaxKds        )
    {
        set_msg_arg_int(2, ARG_SHORT, 0)
        set_msg_arg_int(3, ARG_SHORT, 0)
        set_msg_arg_int(4, ARG_SHORT, 0)

        new id = get_msg_arg_int(1)
        if( dod_set_user_stats(id, 0, 0, 0, .updatedeaths=0) )
        {
            NotifyReset(id)
        }
    }
}

dod_set_user_stats(id, frags, deaths, score, updatefrags=1, updatedeaths=1, updatescore=1)
{
    if( is_user_connected(id) )
    {
        dod_set_user_kills(id, frags, updatefrags)
        dod_set_pl_deaths(id, deaths, updatedeaths)
        dod_set_user_score(id, score, updatescore)
        return 1
    }
    return 0
}

NotifyReset( id )
{
    static szName[32]
    get_user_name(id, szName, charsmax(szName))
    client_print(id, print_chat, " ** %s, Your score has been reset to prevent the server from crashing.", szName)
}

#if defined TEST_PLUGIN
public ClCmd_SetUserScore(id, lvl, cid)
{
    if( !cmd_access(id, lvl, cid, 5) )
    {
        return PLUGIN_HANDLED
    }

    new szTarget[32]
    read_argv(1, szTarget, charsmax(szTarget))
    new plr = cmd_target(id, szTarget, CMDTARGET_ALLOW_SELF|CMDTARGET_OBEY_IMMUNITY)
    if( plr > 0 )
    {
        new szFrags[4], szDeaths[4], szScore[4]
        read_argv(2, szFrags, charsmax(szFrags))
        read_argv(3, szDeaths, charsmax(szDeaths))
        read_argv(4, szScore, charsmax(szScore))
        dod_set_user_stats
        (
            plr,
            str_to_num( szFrags ),
            str_to_num( szDeaths ),
            str_to_num( szScore )
        )
    }
    return PLUGIN_HANDLED
}
#endif 


[MAUGHOLD]

Since many admins run 24/7 servers with very long map rotations, many players will get their scores reset, is there a way to still show all of those players true amount of kills at the end of the map, so the player with the most kills will still show as the number one killer when the map ends ?

Testing it right now. thanks.

[ConnorMcLeod]

First, we should figure out what makes server crash and why.

[MAUGHOLD]

Originally Posted by ConnorMcLeod First, we should figure out what makes server crash and why.

HLDS has always crashed when any player gets 256 kills, but when the original plugin was made, I'm not sure if the author new that HLDS would also crash when any player gets 256 deaths.

[ConnorMcLeod]

And what is "score" ? And does it has the same problem ?
But why does HLDS crashed ? It doesn't happen when you launch a listenserver ?