[puttsmobiles]

Ok, So I have been searching for about 2 hours now for a plugin that I can not find.

I'm not sure how hard this is to code or even if it is possible.

I want to have a plugin that when the first user connects to the server he is marked with a flag "b" or something. (CVAR control on the flags would be nice, if not thats fine) And it remains until the player is gone, then the flag is deleted. Also, can it display a message to the user (you are the first user connected, please use .example to start)?

Thank you so much in advance.

[Exolent[jNr]]

#include < amxmodx >

new g_iFirstPlayer;

new pCvarFlags;

public plugin_init( )
{
    register_plugin( "First Player Flags", "0.0.1", "Exolent" );
    
    pCvarFlags = register_cvar( "first_player_flags", "b" );
}

public client_putinserver( iPlayer )
{
    if( !g_iFirstPlayer )
    {
        g_iFirstPlayer = iPlayer;
        set_user_flags( iPlayer, read_pcvar_flags( pCvarFlags ) );
        
        client_print( iPlayer, print_chat, "please use .example to start" );
    }
}

public client_disconnect( iPlayer )
{
    if( g_iFirstPlayer == iPlayer )
    {
        g_iFirstPlayer = 0;
    }
}

read_pcvar_flags( const pCvar )
{
    new szFlags[ 27 ];
    get_pcvar_string( pCvar, szFlags, charsmax( szFlags ) );
    return read_flags( szFlags );
}

[puttsmobiles]

I felt bad making you do more work. So I just deleted my post.

This will work perfectly Thank you for your help

[puttsmobiles]

It sets the admin but doesnt display the message.

[Exolent[jNr]]

client_putinserver() may be too soon for the player to actually notice it.
Try delaying the message with a task.

[ConnorMcLeod]

Also you would need to set access each time client_infochanged is triggered, because admin.amxx will reset flags, don't bother to make checks on names, just set flags again.

[puttsmobiles]

I think this might work. Not 100% sure.

Not too sound like every other user on the forum but. I'm not quite sure how to do it. :s

[ConnorMcLeod]

This is not the way tasks work, try to find an example somewhere.

[puttsmobiles]

			set_task( 15.0, "CheckTerrorists", _, _, _, "b" );
			
			// Lets make restart after 20 seconds from map start.
			set_task( 20.0, "RestartRound" );

Pulled from Deatrun Manager.

I know it's not the same thing but you guys said to look for a task right?

[ConnorMcLeod]

Try this :

PHP Code:

#include < amxmodx >

#define TASK_PRINT_TEXT 135784 // random num

new g_iFirstPlayer;

new pCvarFlags;

public plugin_init( )
{
    register_plugin( "First Player Flags", "0.0.1", "Exolent" );
    
    pCvarFlags = register_cvar( "first_player_flags", "b" );
}

public client_putinserver( iPlayer )
{
    if( !g_iFirstPlayer )
    {
        g_iFirstPlayer = iPlayer;
        SetUserFlags( iPlayer );
      
        remove_task(TASK_PRINT_TEXT);
        set_task(15.0, "PrintText", TASK_PRINT_TEXT);
    }
}

public PrintText()
{
    if( g_iFirstPlayer && is_user_connected(g_iFirstPlayer) )
    {
        client_print( g_iFirstPlayer, print_chat, "[Practice Mod] Please use .menu to configure the server" )
    }
}

public client_infochanged( id )
{
    if( id == g_iFirstPlayer )
    {
        SetUserFlags( id );
    }
}

public client_disconnect( iPlayer )
{
    if( g_iFirstPlayer == iPlayer )
    {
        g_iFirstPlayer = 0;
        remove_task(TASK_PRINT_TEXT);
    }
}

SetUserFlags( id )
{
    new szFlags[ 27 ];
    get_pcvar_string( pCvarFlags, szFlags, charsmax( szFlags ) );
    set_user_flags( id, read_flags( szFlags ) )
}