[dataviruset]

Hello!

I am trying to set the ammo of the active weapons of two players.
It seems that is doesn't work sometimes and for certain players...

PHP Code:

StripAllWeapons(LRprogressplayer1);
StripAllWeapons(LRprogressplayer2);

// set HP
SetEntData(LRprogressplayer1, FindSendPropOffs("CBasePlayer", "m_iHealth"), 100);
SetEntData(LRprogressplayer2, FindSendPropOffs("CBasePlayer", "m_iHealth"), 100);

CreateTimer(GetConVarFloat(sm_hosties_lr_ns_delay), NSstart, _, TIMER_FLAG_NO_MAPCHANGE); 


PHP Code:

public Action:NSstart(Handle:timer)
{
    if ( (IsClientInGame(LRprogressplayer1)) && (IsPlayerAlive(LRprogressplayer1))
    && (IsClientInGame(LRprogressplayer2)) && (IsPlayerAlive(LRprogressplayer2))
    && (LRtype == 6) )
    {
        // play no scope start sound
        if (!StrEqual(noscope_sound, "-1"))
            EmitSoundToAll(noscope_sound);


        GivePlayerItem(LRprogressplayer1, "weapon_knife");
        GivePlayerItem(LRprogressplayer2, "weapon_knife");

        decl NSw1, NSw2;
        if (GetConVarInt(sm_hosties_lr_ns_weapon) == 1)
        {
            NSw1 = CreateEntityByName("weapon_scout");
            NSw2 = CreateEntityByName("weapon_scout");
        }
        else
        {
            NSw1 = CreateEntityByName("weapon_awp");
            NSw2 = CreateEntityByName("weapon_awp");
        }

        DispatchSpawn(NSw1);
        DispatchSpawn(NSw2);
        EquipPlayerWeapon(LRprogressplayer1, NSw1);
        EquipPlayerWeapon(LRprogressplayer2, NSw2);
        

        // set ammo
        new iWeapon = GetEntDataEnt2(LRprogressplayer1, FindSendPropInfo("CCSPlayer", "m_hActiveWeapon"));
        SetEntData(iWeapon, FindSendPropInfo("CBaseCombatWeapon", "m_iClip1"), 99);
        new iWeapon2 = GetEntDataEnt2(LRprogressplayer2, FindSendPropInfo("CCSPlayer", "m_hActiveWeapon"));
        SetEntData(iWeapon2, FindSendPropInfo("CBaseCombatWeapon", "m_iClip1"), 99);
    }

    return Plugin_Continue;
} 


[rhelgeby]

Tried m_iAmmo? Clip 1 and clip 2 is the clip reserve for primary and secondary weapons I think.

[dataviruset]

I don't think that's the problem because it always works for me, but for other players it doesn't, some times...

[rhelgeby]

If it's "random" it might depend on when you set the ammo. You already have a timer so it might be ok.

Also check the conditions for setting it. What is LRtype? Did you remember to make sure it has a valid/updated value before creating the timer? Any chance that it might be changed before the timer is triggered, like a new event before the other one is done?

And I assume LRprogressplayer1 and 2 are caches for global client indexes? Do they get updated properly too.

Since you actually got it working on one or more players, you should check the conditions when applying it. What if a player change to secondary/primary weapon? What if a player drop it and pick up another one.

I've also done mistakes where I've used the wrong variable in a feature, where it some how still worked for some players.

[dataviruset]

It seems that I always get 99 ammo and some others as well, but it's always the same persons... O_o

[dataviruset]

I got it to work, I had to do it this way instead... It isn't what I was looking for, but a more optimized solution to the problem:

PHP Code:

        decl NSw1, NSw2;
        if (GetConVarInt(sm_hosties_lr_ns_weapon) == 1)
        {
            NSw1 = CreateEntityByName("weapon_scout");
            NSw2 = CreateEntityByName("weapon_scout");
        }
        else
        {
            NSw1 = CreateEntityByName("weapon_awp");
            NSw2 = CreateEntityByName("weapon_awp");
        }

        DispatchSpawn(NSw1);
        DispatchSpawn(NSw2);
        EquipPlayerWeapon(LRprogressplayer1, NSw1);
        EquipPlayerWeapon(LRprogressplayer2, NSw2);

        SetEntData(NSw1, FindSendPropInfo("CBaseCombatWeapon", "m_iClip1"), 99);
        SetEntData(NSw2, FindSendPropInfo("CBaseCombatWeapon", "m_iClip1"), 99); 


[meng]

Just stash the offsets globally, especially if it helps with stability issues.