[LouLouBizou]

how detect that an entity is visible from another entity ????

like: player can seen player b from this position

any idea ?



i using something like that

new j;
for(j = 1; j <= GetMaxClients(); j++){

if ( IsClientInGame(j) && (client != j) && IsPlayerAlive(j) && (GetClientTeam(client) != GetClientTeam(j)) ){

GetClientAbsOrigin(j, VictimPos);
Distance = GetVectorDistance(MyPos, VictimPos, false);

new Handle:trace = TR_TraceRayFilterEx(MyPos, VictimPos, MASK_ALL, RayType_Infinite, TraceRayDontHitSelf, j);
PrintToChat(client, "ret: %d", TR_GetEntityIndex(trace));
if (TR_GetEntityIndex(trace) == j){
...
}
CloseHandle(trace);
}

}

any help ?

[LouLouBizou]

help

[blodia]

for mypos use GetClientEyePosition instead of GetClientAbsOrigin as this is where you see from.

for the victim you will need to do 2 or more traces for different parts of the body, GetClientAbsOrigin will only work if you can see their feet, GetClientEyePosition will only work if you can see their head, those 2 might be enough or you may need one in the middle of those 2 coords.

you don't need a handle for the trace if you use the results immediately, i think you use a handle if you want to save the results for use later. this also means you don't need the ex version. also since you're not using a handle use TR_GetEntityIndex() without the handle to get the results.

for the data to send to the filter (last parameter in the raytrace call) don't send j send your index

you also need your filter function "TraceRayDontHitSelf". something like this should work.

PHP Code:

public bool:TraceRayDontHitSelf(entity, contentsMask, any:data)
{
    return (entity != data);
} 


[AtomicStryker]

Example from srsmod

PHP Code:

static bool:IsVisibleTo(client, entity) // check an entity for being visible to a client
{
    decl Float:vAngles[3], Float:vOrigin[3], Float:vEnt[3], Float:vLookAt[3];
    
    GetClientEyePosition(client,vOrigin); // get both player and zombie position
    GetEntityAbsOrigin(entity, vEnt);
    
    MakeVectorFromPoints(vOrigin, vEnt, vLookAt); // compute vector from player to zombie
    
    GetVectorAngles(vLookAt, vAngles); // get angles from vector for trace
    
    // execute Trace
    new Handle:trace = TR_TraceRayFilterEx(vOrigin, vAngles, MASK_SHOT, RayType_Infinite, _DI_TraceFilter);
    
    new bool:isVisible = false;
    if (TR_DidHit(trace))
    {
        decl Float:vStart[3];
        TR_GetEndPosition(vStart, trace); // retrieve our trace endpoint
        
        if ((GetVectorDistance(vOrigin, vStart, false) + TRACE_TOLERANCE) >= GetVectorDistance(vOrigin, vEnt))
        {
            isVisible = true; // if trace ray lenght plus tolerance equal or bigger absolute distance, you hit the targeted zombie
        }
    }
    else
    {
        Debug_Print("Zombie Despawner Bug: Player-Zombie Trace did not hit anything, WTF");
        isVisible = true;
    }
    CloseHandle(trace);
    return isVisible;
}

public bool:_DI_TraceFilter(entity, contentsMask)
{
    if (entity <= CLIENT_VALID_LAST || !IsValidEntity(entity)) // dont let WORLD, players, or invalid entities be hit
    {
        return false;
    }
    
    decl String:class[128];
    GetEdictClassname(entity, class, sizeof(class)); // also not zombies or witches, as unlikely that may be, or physobjects (= windows)
    if (StrEqual(class, CLASSNAME_INFECTED, .caseSensitive = false)
    || StrEqual(class, CLASSNAME_WITCH, .caseSensitive = false)
    || StrEqual(class, CLASSNAME_PHYSPROPS, .caseSensitive = false))
    {
        return false;
    }
    
    return true;
} 


[LouLouBizou]

Thanks to all, it works