[Yonny]

Hola creo que es algo complicado lo que voy a pedir pero aver si algien sabe..
Bueno lo que hace mi code es poner una pieda y usa como vector la mira... bueno yo quiero que antes de poner la piedra me aparesca una pieda igual a la que se tendria que poner pero:
1 que la vea yo solo
2 que siga a la mira
Lo que quiero hacer es que antes de poner la roca sepa bien donde se va a poner...

PHP Code:

#include <amxmodx>
#include <fakemeta_util>
 
#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"
 
enum _:Box { Mins, Maxs };
enum _:Axis { X, Y, Z };
 
new g_classname[] = "block"
new g_model[] = "models/big_rock.mdl"
 
public plugin_precache() precache_model(g_model)
 
public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say rock", "RockOn")
}
public RockOn(id)
{
    new Float:origin[3]
    fm_get_aim_origin(id, origin)
    
    entidad_solida(origin)
    
    return PLUGIN_HANDLED;
}
stock entidad_solida(Float:origin[3])
{
    new Float:size[Box][Axis], Float:abssize[Box][Axis], entity
    
    entity = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))
    
    set_pev(entity, pev_classname, g_classname)
    set_pev(entity, pev_movetype, MOVETYPE_FLY)
    
    engfunc(EngFunc_SetOrigin, entity, origin)
    
    engfunc(EngFunc_SetModel, entity, g_model)
    set_pev(entity, pev_solid, SOLID_BBOX)
    
    size[Mins] = Float:{ -20.0, -20.0, -20.0 }
    size[Maxs] = Float:{ 20.0, 20.0, 20.0 }
    
    engfunc(EngFunc_SetSize, entity, size[Mins], size[Maxs])
    
    xs_vec_add(origin, size[Mins], abssize[Mins])
    xs_vec_add(origin, size[Maxs], abssize[Maxs])
    
    set_pev(entity, pev_absmin, abssize[Mins])
    set_pev(entity, pev_absmax, abssize[Maxs])
} 


[joropito]

Podes hacerlo con esto

PHP Code:

#define TE_MODEL                    106      // Create a moving model that bounces and makes a sound when it hits
// write_byte(TE_MODEL)
// write_coord(position.x)
// write_coord(position.y)
// write_coord(position.z)
// write_coord(velocity.x)
// write_coord(velocity.y)
// write_coord(velocity.z)
// write_angle(initial yaw)
// write_short(model index)
// write_byte(bounce sound type)
// write_byte(life in 0.1's) 


Te sugiero que veas el codigo de algun grab para ver como actualizar la posicion.

[Yonny]

Originally Posted by joropito Podes hacerlo con esto PHP Code: #define TE_MODEL                    106      // Create a moving model that bounces and makes a sound when it hits // write_byte(TE_MODEL) // write_coord(position.x) // write_coord(position.y) // write_coord(position.z) // write_coord(velocity.x) // write_coord(velocity.y) // write_coord(velocity.z) // write_angle(initial yaw) // write_short(model index) // write_byte(bounce sound type) // write_byte(life in 0.1's)  Te sugiero que veas el codigo de algun grab para ver como actualizar la posicion.

Perdona mi ignorancia pero no entiendo como sirve y ni que deberia hace

[L//]

Te lo dejo semi-resuelto, vos verás como hacer para dejarlo estatico (Con mi anterior post )

PHP Code:

#include <amxmodx>
#include <engine>
#include <fakemeta_util>

#define PLUGIN "Test"
#define VERSION "1.0"
#define AUTHOR "L//"

new g_model[] = "models/big_rock.mdl"

new g_owner, g_model_index

public plugin_precache() g_model_index = precache_model(g_model)

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say aim", "crear_ilusion")
    
    register_forward(FM_AddToFullPack, "addToFullPackPost", 1)
    
    g_owner = create_entity("info_target")
}

public crear_ilusion(id)
{
    new entity = create_entity("info_target")
    
    assert is_valid_ent(entity);
    
    entity_set_edict(entity, EV_ENT_aiment, id)    
    set_pev(entity, pev_movetype, MOVETYPE_FOLLOW)
    
    entity_set_model(entity, g_model)
    
    set_pev(entity, pev_owner, g_owner)

    set_pev(entity, pev_solid, SOLID_NOT)

    return PLUGIN_HANDLED;
}

public addToFullPackPost(es, e, ent, host, hostflags, player, pSet)
{
    if ((1 <= host <= 32) && is_valid_ent(ent))
    {
        if (pev(ent, pev_owner) == g_owner)
        {
            if (engfunc(EngFunc_CheckVisibility, ent, pSet))
            {
                new id = pev(ent, pev_aiment)
                
                if (host != id) return;
                    
                static Float:origin[3]
                
                fm_get_aim_origin(id, origin)
                
                set_es(es, ES_AimEnt, 0)
                set_es(es, ES_MoveType, MOVETYPE_NONE)
                set_es(es, ES_ModelIndex, g_model_index)
                set_es(es, ES_Scale, 1.0)
                set_es(es, ES_Origin, origin)
                set_es(es, ES_RenderMode, kRenderNormal)
            }
        }
    }
} 


[Yonny]

Originally Posted by L// Te lo dejo semi-resuelto, vos verás como hacer para dejarlo estatico (Con mi anterior post ) PHP Code: #include <amxmodx> #include <engine> #include <fakemeta_util>   #define PLUGIN "Test" #define VERSION "1.0" #define AUTHOR "L//"   new g_model[] = "models/big_rock.mdl"   new g_owner, g_model_index   public plugin_precache() g_model_index = precache_model(g_model)   public plugin_init()  {     register_plugin(PLUGIN, VERSION, AUTHOR)       register_clcmd("say aim", "crear_ilusion")       register_forward(FM_AddToFullPack, "addToFullPackPost", 1)       g_owner = create_entity("info_target") }   public crear_ilusion(id) {     new entity = create_entity("info_target")       assert is_valid_ent(entity);       entity_set_edict(entity, EV_ENT_aiment, id)         set_pev(entity, pev_movetype, MOVETYPE_FOLLOW)       entity_set_model(entity, g_model)       set_pev(entity, pev_owner, g_owner)       set_pev(entity, pev_solid, SOLID_NOT)       return PLUGIN_HANDLED; }   public addToFullPackPost(es, e, ent, host, hostflags, player, pSet) {     if ((1 <= host <= 32) && is_valid_ent(ent))     {         if (pev(ent, pev_owner) == g_owner)         {             if (engfunc(EngFunc_CheckVisibility, ent, pSet))             {                 new id = pev(ent, pev_aiment)                   if (host != id) return;                   static Float:origin[3]                   fm_get_aim_origin(id, origin)                   set_es(es, ES_AimEnt, 0)                 set_es(es, ES_MoveType, MOVETYPE_NONE)                 set_es(es, ES_ModelIndex, g_model_index)                 set_es(es, ES_Scale, 1.0)                 set_es(es, ES_Origin, origin)                 set_es(es, ES_RenderMode, kRenderNormal)             }         }     } }

Gracias L por segunda ves... estoy aprendiendo mucho de entidades ya que no hay ningun tutoria avanzado es dificil aprender..
Igual con lo de abajo me mataste si me podrias explicar un toque lo de abajo te agradeseria aun mas...