[icequeenzz]

i tried creating a plugin that would return me the players that are on the server. pretty easy i tought cuz im a noob @ coding. but it was harder then i tought.

i hoped someone here could say what i did wrong that it doesnt return a couple of things

my code:

PHP Code:

#define PLUGIN_NAME "TF2 Online Players"
#define PLUGIN_VERSION "1.0"

new string: cName[10000];
new cId[10000];
new string: cIp[10000];
new nrClients = 0; 


public Plugin:myinfo = 
{
    name = PLUGIN_NAME,
    author = "Icequeenzz",
    description = "Prints connected players @ console",
    version = PLUGIN_VERSION,
    url = "http://TFO2.webs.com"
};

public  OnClientConnected(client)
{
    GetClientName(client, cName[nrClients], 20);
    GetClientIP(client, cIp[nrClients], 25);
    GetClientAuthString(client, cId[nrClients] , 50);
    nrClients++;
}

public OnPluginStart()
{
    CreateConVar("sm_PlayerPrint", PLUGIN_VERSION, PLUGIN_NAME, FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);
    RegConsoleCmd("OnPlayers", Command_Players);
}

public Action:Command_Players(client, args)
{
        PrintToServer("Players On Server: %s", nrClients);
        for(new i = 0; nrClients > i; i++)
        {
            if(IsClientConnected(cId))
            {
            PrintToServer("Player: %s, %d, %f", cName[i], cId[i], cIp[i]);
            }
        }
} 


What happens:

it return "players on server: " and then it gives a kinda wingding things O_o.. 1 = smily 2 = coloured smily 3= heart etc..

it then returns the name of the first player well.
but when another player joins it adds the first 4 letters of his name onto the previous player.
it doesnt show the steamid and also not the id.

some help on telling me what i did wrong is appreciated

soz for my bad english

Icequeenzz

[noodleboy347]

Use %N instead of converting their name to a string. Dunno how to help you with the others though.

[almcaeobtac]

status does this well

[Bigbuck]

Originally Posted by almcaeobtac status does this well

Either that or HLSW if you want a "neater" look.

[exvel]

1. Getting SteamID OnClientConnected is a bad idea. Player SteamID validated only some time after connection. Do it on OnClientAuthorized or in the command's callback.
2. Use sm_PlayerPrint_version as version cvar
3. You are using %d and %f for strings instead of %s (ip and SteamID are strings)

%d for integers (also %i)
%f for floats
%s for strings
%N player's name

4. You can loop directly through clients without adding them in array in OnClientConnected. Loop from 1 to MaxClients, and check if IsClientInGame.
5. There is a default function GetClientCount

[exvel]

All you need... OnClientConnected is not needed.

PHP Code:

public OnPluginStart()
{
    CreateConVar("sm_PlayerPrint_version", PLUGIN_VERSION, PLUGIN_NAME, FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);
    RegConsoleCmd("OnPlayers", Command_Players);
}

public Action:Command_Players(client, args)
{
    // Simple buffer strings
    new String:szIP[20];
    new String:szSteam[32];
    
    PrintToServer("Players On Server: %d", GetClientCount());
    
    // Looping through all clients
    for (new i = 1; i <= MaxClients; i++)
    {
        // If client is not in game then skip him
        if (!IsClientInGame(i))
            continue;

        // Checking client's authorization string (SteamID)    
        if (IsClientAuthorized(i))
        {
            GetClientAuthString(i, szSteam, sizeof(szSteam));
        }
        // Client is not authorized
        else
        {
            Format(szSteam, sizeof(szSteam), "Not authorized");
        }
        
        GetClientIP(i, szIP, sizeof(szIP));
        
        // Printing name, ip, SteamID
        PrintToServer("Player: %N, %s, %s", i, szSteam, szIP);
    }
}