[akcaliberg]

Plugin Name: Sprint
Plugin Version: 1.2
Plugin Author: akcaliberg

Description

This plugin allows you to sprint by simply double-tapping the forward (W) key. So you can easily run faster.

Once you reached the specified maximum sprint duration limit, you will be slowed down to the normal speed. You can sprint again when the cooldown time has passed.

If you don't complete your sprint time, you can use it later without waiting for cooldown. For example sprint_timemax is set to 5 seconds. And you used only 2 seconds. You can use your remaining 3 seconds instantly whenever you want.

Any advice and suggestions will be appreciated



Cvars:

sprint_cooldown             "5.0"         // How many seconds do players need to wait to sprint again.
sprint_timemax              "2.5"         // How many seconds can players sprint at once.
sprint_speed                "400.0"       // Sprint speed.
sprint_keylisten_interval   "0.2"         // Maximum double-tap delay time. Maximum seconds between two taps. ( Recommended value is 0.2 No need to change )
sprint_blockjump            "0"           // It blocks sprinting when you jump, so players can't jump onto unreachable places using sprint.
sprint_breathsound          "2"           // Exhausted breathing sound effect. 2: Use emit_sound | 1: Use client_cmd("spk") | 0: No sound effect.
sprint_screenfade_enabled   "1"           // 1: ScreenFade effects for sprinting and exhaustion | 0: No effects.
sprint_screenfade_rgba      "0 20 200 50" // ScreenFade color options for sprinting.
sprint_screenfade_rgba2     "255 0 0 50"  // ScreenFade color options for exhaustion.
1. parameter: Red
2. parameter: Green
3. parameter: Blue
4. parameter: Alpha (Opacity)

sprint_showusage            "1"           // 1: Sends an introduction text about plugin to everyone every 5 minutes | 0: No introduction.

Commands:

sprint_reloadcvars // Reloads the new cvar values instantly. So you won't need to wait for a new round.

Change Log:

v1.0  
*Plugin released.
v1.1  
+Added exhausted breathing sound.
+Added ScreenFade effects.
v1.2 
*Changed cvar caching system. You had to change the map to update new cvar values before. Now, cvars are updating every round start. So you just need to wait for a new round.
+Added sprint_reloadcvars command.
+Added this feature.
+Added sprint_blockjump cvar.
>Fixed spectator sprint bug.

Modules:

Amxmodx
Hamsandwich
Fakemeta

NOTE: Old versions can be found in the Files.zip

[oxygen935]

This idea is damn good! It's like minecraft!
Keep up the good work!

[Phant]

Strange, but it does not work for me . I am run normally after double-tapping "W".
I tried up sprint_speed, like 800.0, same.

[akcaliberg]

Originally Posted by Phant Strange, but it does not work for me . I am run normally after double-tapping "W". I tried up sprint_speed, like 800.0, same.

It works for me. Maybe you are tapping not fast enough. Try raising up the sprint_keylisten_interval. I will try it again when I get home.

[ironskillz1]

A plugin like this already exist.
But good job anyways

/* Plugin generated by AMXX-Studio */

#include < amxmodx >
#include < amxmisc >
#include < hamsandwich >
#include < fakemeta >
#include < engine >

#define PLUGIN "Sprint Minecraft"
#define VERSION "1.0"
#define AUTHOR "DarkGL"

#define MAX 32

new const Float:fWeaponsSpeed[ ]	=	{
	000.0,
	250.0, 000.0, 260.0, 250.0, 240.0, 
	250.0, 250.0, 240.0, 250.0, 250.0,                
	250.0, 250.0, 210.0, 240.0, 240.0,    
	250.0, 250.0, 210.0, 250.0, 220.0,              
	230.0, 230.0, 250.0, 210.0, 250.0,            
	250.0, 235.0, 221.0, 250.0, 245.0 
};

enum sprintState {
	SPRINT_OFF ,
	SPRINT_FIRST_FORWARD ,
	SPRINT_NOT_FORWARD ,
	SPRINT_ON
}

new sprintState:	ePlayerState[ MAX + 1 ];	
new Float:			fTimePlayer[ MAX + 1 ];
new Float:			fToFov[ MAX + 1 ];
new Float: 			fTimeFov[ MAX + 1 ];
new Float:			fFovLastUpdate[ MAX + 1 ];
new Float:			fCurrentFov[ MAX + 1 ];

new 	pCvarTimeDelay		=	0 ,
		pCvarSprintSpeed	=	0 ,
		pCvarChance			=	0 ,
		pCvarTimeFov		=	0;

new msgFOV;

public plugin_init() {
	register_plugin( PLUGIN , VERSION , AUTHOR );
	
	RegisterHam( Ham_Killed , "player" , "fwKilled" , 1 );
	RegisterHam( Ham_Player_PreThink , "player" , "fwPreThink" );
	
	register_event( "CurWeapon" , "CurWeapon" , "be" , "1=1" );
	
	pCvarTimeDelay		=	register_cvar( "sprintMinecraft_delay" , "0.5" );
	pCvarSprintSpeed	=	register_cvar( "sprintMinecraft_speed" , "310.0" );
	pCvarChance			=	register_cvar( "sprintMinecraft_change" , "1" );
	pCvarTimeFov		=	register_cvar( "sprintMinecraft_fovtime" , "0.2" );
	
	msgFOV 				= 	get_user_msgid( "SetFOV" );
}

public client_connect( id ){
	cleanInformation( id );
	fTimeFov[ id ]		=	0.0;
}

public client_disconnect( id ){
	cleanInformation( id );
	fTimeFov[ id ]		=	0.0;
}

public fwPreThink( id ){
	if( !is_user_alive( id ) || pev( id , pev_maxspeed ) == 1.0 ){ //in freezetime player have 1.0 maxspeed
		return PLUGIN_CONTINUE;
	}
	
	if( fTimeFov[ id ] != 0.0 ){
		if( fTimeFov[ id ] < get_gametime( ) ){
			fTimeFov[ id ]	=	0.0;
		}
		else{		
			fCurrentFov[ id ]	+=	( get_gametime( ) - fFovLastUpdate[ id ] ) * fToFov[ id ];
			
			set_pev( id , pev_fov , fCurrentFov[ id ] );
			
			message_begin( MSG_ONE , msgFOV, { 0 , 0 , 0 }, id );
			write_byte( floatround( fCurrentFov[ id ] ) );
			message_end( );
			
			fFovLastUpdate[ id ]	=	get_gametime( );
		}
	}
	
	new iButton		=	pev( id , pev_button );
	new iOldButton	=	pev( id , pev_oldbuttons );
	
	switch( ePlayerState[ id ] ){
		case SPRINT_ON : {
			if( !( iButton & IN_FORWARD ) ){
				sprintOff( id );
			}
		}
		case SPRINT_OFF : {
			if( iButton & IN_FORWARD && !( iOldButton & IN_FORWARD ) ){
				fTimePlayer[ id ]	=	get_gametime();
				ePlayerState[ id ]	=	SPRINT_FIRST_FORWARD;
			}
		}
		case SPRINT_FIRST_FORWARD : {
			if( !checkTime( id ) ){
				cleanInformation( id );
				
				return PLUGIN_CONTINUE;
			}
			
			if( !( iButton & IN_FORWARD ) ){
				ePlayerState[ id ]	=	SPRINT_NOT_FORWARD;
			}
		}
		case SPRINT_NOT_FORWARD : {
			if( !checkTime( id ) ){
				cleanInformation( id );
				
				return PLUGIN_CONTINUE;
			}
			
			if( iButton & IN_FORWARD ){
				if( random_num( 0 , get_pcvar_num( pCvarChance ) ) != 0 ){
					cleanInformation( id ) ;
				}
				else{
					sprintOn( id );
				}
			}
		}
	}
	
	return PLUGIN_CONTINUE;
}

moveTo( id , Float: fFov , Float: fTime ){
	fCurrentFov[ id ]		=	float( pev( id , pev_fov ) );
	
	fTimeFov[ id ]			=	get_gametime( ) + fTime;
	fToFov[ id ]			=	( fFov - fCurrentFov[ id ] ) / fTime;
	
	fFovLastUpdate[ id ]	=	get_gametime( );
}

cleanInformation( id ){
	fTimePlayer[ id ]	=	0.0;
	ePlayerState[ id ]	=	SPRINT_OFF;
}

bool: checkTime( id ){
	return ( get_gametime() - fTimePlayer[ id ] <= get_pcvar_float( pCvarTimeDelay ) );
}

sprintOn( id ){
	ePlayerState[ id ]	=	SPRINT_ON;
	fTimePlayer[ id ]	=	0.0;
	
	set_pev( id , pev_maxspeed , get_pcvar_float( pCvarSprintSpeed ) );
	
	engfunc( EngFunc_SetClientMaxspeed , id , get_pcvar_float( pCvarSprintSpeed ) );
	
	moveTo( id , 100.0 , get_pcvar_float( pCvarTimeFov ) );
}

sprintOff( id ){
	ePlayerState[ id ]	=	SPRINT_OFF;
	fTimePlayer[ id ]	=	0.0;
	
	set_pev( id , pev_maxspeed , fWeaponsSpeed[ get_user_weapon( id ) ] );
	
	if( is_user_alive( id ) ){
		engfunc( EngFunc_SetClientMaxspeed , id , fWeaponsSpeed[ get_user_weapon( id ) ] );
	}
	
	moveTo( id , 90.0 , get_pcvar_float( pCvarTimeFov ) );
}

public fwKilled( id ){
	if( is_user_alive( id ) ){
		return HAM_IGNORED;
	}
	
	sprintOff( id )
	
	return HAM_IGNORED;
}

public CurWeapon( id ){
	if( !is_user_alive( id ) || ePlayerState[ id ] != SPRINT_ON ){
		return PLUGIN_CONTINUE;
	}
	
	set_pev( id , pev_maxspeed , get_pcvar_float( pCvarSprintSpeed ) );
	
	return PLUGIN_CONTINUE;
}

[Kia]

Isn't working for me too.

[jingojang]

Me neither.

[akcaliberg]

Sorry guys. I attached the wrong sma accidentally.

Now, it works.

Originally Posted by ironskillz1 A plugin like this already exist. But good job anyways

I searched, but I couldn't find any sprint plugin like mine until you posted it here.

I searched your plugins name, still can't find


Thanks for your replies. I will add a video tonight. I have to go now.

[norbi1952]

Originally Posted by akcaliberg I searched your plugins name, still can't find

This plugin was made more than year ago ;)

http://amxx.pl/topic/87715-sprint-minecraft/

[Kia]

Working fine now, but should it make more clear if someone is sprinting, a colored screen for example.
Made a quick video :