[tarsisd2]

hi, im looking for a imposter plugin, what happens is when someone kills a enemy with a knife, he steals his skin for that round, being an imposter, say that i am a TR and i kill a CT with a knife, i will look like a CT for the rest of the round, but I`ll still be a TR

i found this plugin in here few years ago, but can`t seem to find it again, maybe someone has it

this plugin is also made for csgo if someone wants to look at the code to have an idea

https://forums.alliedmods.net/showthread.php?p=1873286

thanks

[OciXCrom]

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#if !defined MAX_PLAYERS
const MAX_PLAYERS = 32
#endif

new bool:g_bIsImposter[MAX_PLAYERS + 1]

public plugin_init()
{
    register_plugin("Imposter", "1.0", "OciXCrom")
    register_event("DeathMsg", "OnPlayerKilled", "a", "4=knife")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public client_putinserver(id)
{
    g_bIsImposter[id] = false
}

public OnPlayerSpawn(id)
{
    if(g_bIsImposter[id] && is_user_alive(id))
    {
        cs_reset_user_model(id)
        g_bIsImposter[id] = false
    }
}

public OnPlayerKilled()
{
    new iAttacker = read_data(1), iVictim = read_data(2)

    if(is_user_connected(iAttacker) && iAttacker != iVictim && cs_get_user_team(iAttacker) != cs_get_user_team(iVictim))
    {
        new szModel[32]
        cs_get_user_model(iVictim, szModel, charsmax(szModel))
        cs_set_user_model(iAttacker, szModel)
        g_bIsImposter[iAttacker] = true
    }
}

[tarsisd2]

thanks OciXCrom, will test it