[OFFBEAT]

Don't really get why this isn't working, it's suppose too, I've read around alot about the events of round start, round end, player spawn etc.

I'm trying to set the player maxspeed on round start, though it doesn't set it... Even if the id is correct and everything is a match.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <fakemeta_util>

#define PLUGIN "Test Plugin"
#define VERSION "0.0.1"
#define AUTHOR "OFFBEAT"

new g_iDecals;
new g_cvarCount;
new g_iDecFreq;

new bool:g_bMaySpray = true;

public plugin_init( )
{
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    register_logevent( "fnRoundStart", 2, "1=Round_Start" )  
    
    g_cvarCount = register_cvar( "mod_countspray", "1" );
    
    g_iDecFreq = get_cvar_num( "decalfrequency" );
}

public fnRoundStart( )
{
    new players[32], Max;
    get_players( players, Max );
    
    for( new i = 0; i < Max; i++ )
    {
        if( is_user_alive( players[i] ) )
            fm_set_user_maxspeed( players[i], fm_get_user_maxspeed( players[i] ) + 50.0 );
    }
    
    return PLUGIN_HANDLED;
}

public client_impulse( id, impulse )
{
    if( get_pcvar_num( g_cvarCount ) && impulse == 201 && g_bMaySpray )
    {
        g_iDecals++;
        
        switch( g_iDecals )
        {
            case 5:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have sprayed %d decals, spray 5 more to increase in speed!", g_iDecals );
            }
                
            case 10:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have sprayed %d decals, increasing 50 units in speed", g_iDecals );
                
                fm_set_user_maxspeed( id, fm_get_user_maxspeed( id ) + 50.0 );
            }
            
            default:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have now sprayed %d decal(s)", g_iDecals );
            }
        }
        
        g_bMaySpray = false;
        set_task( float( g_iDecFreq ), "fnMaySpray" );
        
        return PLUGIN_CONTINUE;
    } else if( get_pcvar_num( g_cvarCount ) && impulse == 201 && !g_bMaySpray )
    {
        // return handled
    }
    
    return PLUGIN_HANDLED;
}

public fnMaySpray( )
{
    g_bMaySpray = true;
} 


Don't worry about the other parts of the code, it's just the round start code i want to work, the other was just a test.

EDIT: Fixed it, thanks guys! Fixed code in my latest post.

[fysiks]

You need to search around for setting max speed now. Also, don't use fm_ functions if there is an identical function already created to do the same thing.

[ConnorMcLeod]

It deosn't work because right after this event, players maxspeed are reset because it's the end of freezetime.
As fysiks said, use set_user_maxspeed and get_user_maxspeed natives instead of fm_*
Instead of client_impulse, you can use register_impulse( 201 , "client_impulse_201" )

[OFFBEAT]

Oh okey, so fun's set_user_maxspeed and register impulse instead of client_impulse, got it, thank you I will try that out.

Solved:

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <fun>

#define PLUGIN "Test Plugin"
#define VERSION "0.0.1"
#define AUTHOR "OFFBEAT"

new g_iDecals;
new g_cvarCount;
new g_iDecFreq;

new bool:g_bMaySpray = true;

public plugin_init( )
{
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    register_event( "HLTV", "fnFreeze", "a", "1=0", "2=0" );
    register_impulse( 201, "fnClientImpulse" );
    
    g_cvarCount = register_cvar( "mod_countspray", "1" );
    
    g_iDecFreq = get_cvar_num( "decalfrequency" );
}

public fnFreeze( )
{
    new Float:flFreeze = get_cvar_float( "mp_freezetime" );
    
    set_task( flFreeze, "fnSetSpeed" );
    
    return PLUGIN_HANDLED;
}

public fnSetSpeed( )
{
    new iPlayers[32], iMax;
    get_players( iPlayers, iMax );
    
    for( new i = 0; i < iMax; i++ )
    {
        if( is_user_alive( iPlayers[i] ) )
            set_user_maxspeed( iPlayers[i], get_user_maxspeed( iPlayers[i] ) + 50.0 );
    }
    
    return PLUGIN_HANDLED;
}

public fnClientImpulse( id, impulse )
{
    if( get_pcvar_num( g_cvarCount ) && g_bMaySpray )
    {
        g_iDecals++;
        
        switch( g_iDecals )
        {
            case 5:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have sprayed %d decals, spray 5 more to increase in speed!", g_iDecals );
            }
                
            case 10:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have sprayed %d decals, increasing 50 units in speed", g_iDecals );
                
                set_user_maxspeed( id, get_user_maxspeed( id ) + 50.0 );
            }
            
            default:
            {
                client_print( id, print_chat, "[DECAL COUNTER] You have now sprayed %d decal(s)", g_iDecals );
            }
        }
        
        g_bMaySpray = false;
        set_task( float( g_iDecFreq ), "fnMaySpray" );
        
        return PLUGIN_CONTINUE;
    } else if( get_pcvar_num( g_cvarCount ) && !g_bMaySpray )
    {
        // return handled
    }
    
    return PLUGIN_HANDLED;
}

public fnMaySpray( )
{
    g_bMaySpray = true;
}