[HSFighter]

Hi all,

i want to read all values from a config file via "KeyValues".
But the Key's are unknow.

It's no problem when i know the name of the "key" but i didn't.

Example:

"MyFile"
{
    "de_dust"
    {
        "Key_fvj"           "Value_arhu"
        "Key_fgaz"          "Value_mpai"
        "Key_sae"          "Value_uusj"
        "Key_diugx"         "Value_yjko"

    }
    "de_dust2"
    {
        "Key_abc"           "Value_afdu"
        "Key_fguz"          "Value_msai"
        "Key_sqae"          "Value_ddsj"
        "Key_diegx"         "Value_ejko"
    }
}

PHP Code:

public bool:ReadFile(const String:value[], maxlength) 
{    
    decl String:map[64];
    GetCurrentMap(map, sizeof(map));

    kv = CreateKeyValues("Myfile");
    FileToKeyValues(kv, path);
    
    if (!KvGotoFirstSubKey(kv)) 
    {
        LogMessage("CFG File not found");
        
        CloseHandle(kv);
        return false;
    }
    do 
    {
        KvGetSectionName(kv, buffer, sizeof(buffer));
        if (StrEqual(buffer, map))
        {            
            // Here i dount know the "Key"
            KvGetString(kv, "Key_???", Value, maxlength);
            CloseHandle(kv);
            return true;            
        }
    }while (KvGotoNextKey(kv));
    CloseHandle(kv);
    return true;  
} 


I want to save all key's and values to an Array.

E.x. de_dust:

Array[0][0] = Key_fvj
Array[0][1] = Value_arhu

Array[1][0] = Key_fgaz
Array[1][1] = Value_mpai

...

Can someone tell me how i can realize it?

Thanks for the effort.

[friagram]

You may have to parse keys yourself manually, using readfileline

[Powerlord]

Originally Posted by friagram You may have to parse keys yourself manually, using readfileline

That's just silly.

HSFighter:

It is possible to iterate through those. Valve refers to KV items that have values (and thus no children) as Values, which is what might have thrown you off from finding the solution on your own.

Both KvGotoFirstSubKey and KvGotoNextKey have an optional second value named keysOnly. When this is set to true (the default), it will only go through the Key items. When this is set to false, it will only go through the Value items.

One more important thing: To retrieve the value of the current Value item, you have to pass NULL_STRING as the key name. This is mentioned as a valid argument for the key name, but the documentation doesn't mention what it does.

So, to fetch them all is something like this:

PHP Code:

        if (StrEqual(buffer, map))
        {
            if (KvGotoFirstSubKey(kv, false))
            {
                new counter = 0;
                do
                {
                    KvGetSectionName(kv, Array[counter][0], sizeof(Array[])); // This is the current key name
                    KvGetString(kv, NULL_STRING, Array[counter][1], sizeof(Array[])); // and this is its value
                    counter++;
                }while (KvGotoNextKey(kv, false));
            }
        } 


Incidentally, if you want to know if this works, MapChooser Extended Sounds uses it.

[HSFighter]

Thank You Powerlord , very interesting.

I get only the first Char back.
Then i set the Size of Array for the time being to 128.
After this i get some funny Results.

Result from the First Key / Value:

Debug: ArrayKey: KValKValue_mpai
Debug: ArrayValue: ValKValue_mpai

Here My Code:

PHP Code:

public bool:ReadHelpFile(const String:Array[9][2]) 
{

    decl String:buffer[PLATFORM_MAX_PATH];
    decl String:map[64];
    
    GetCurrentMap(map, sizeof(map));
    
    new Handle: kv = CreateKeyValues("Myfile");
    FileToKeyValues(kv, path);
    
    if (!KvGotoFirstSubKey(kv)) 
    {
        LogMessage("CFG File not found");
        
        CloseHandle(kv);
        return false;
    }
    do
    {
        KvGetSectionName(kv, buffer, sizeof(buffer));
        if (StrEqual(buffer, map))
        {                        
            if (KvGotoFirstSubKey(kv, false))
            {
                new counter = 0;
                do
                {
                    KvGetSectionName(kv, Array[counter][0], 128); // This is the current key name
                    KvGetString(kv, NULL_STRING, Array[counter][1], 128); // and this is its value
                    counter++;
                }while (KvGotoNextKey(kv, false));
            }
        }
    }while (KvGotoNextKey(kv));
    CloseHandle(kv);
    
    return true;  
} 


PHP Code:

public Action:Test(client, args )
{
    decl String: g_adtArray[9][2];
    if (ReadHelpFile(g_adtArray))
    {
        PrintToChatAll("Debug: ArrayKey: %s", g_adtArray[0][0]);            
        PrintToChatAll("Debug: ArrayValue: %s", g_adtArray[0][1]);            
    }
    return Plugin_Handled;
    
} 


Any idea what i doing wrong?


-

[Powerlord]

Whoops. Since you're storing Strings, your array needs a third dimension with the string length.

[HSFighter]

That's it!

Thank you very much.