[Cuttlas]

it seems the codes provided by Bugsy and 101 have a bug with my goal.

whenever the admin drops a gun with G and picks up another one, the event won't call. so does it mean I should change weapons on a pick-up event? Or can I edit the current event?


and how to disable weapon changing for others? just admin can change his weapon, and others' weapons will be the same as the admin and they are not allowed to change or drop their weapons.

[Bugsy]

Another option is to use CurWeapon with logic to make it apply only when needed.

[Cuttlas]

Originally Posted by Bugsy Another option is to use CurWeapon with logic to make it apply only when needed.

could you please help me on that?

[Bugsy]

Can you clarify requirements?

Should it only happen when a true weapon switch happens, and not upon weapon pickup?
Do all weapons apply, excluding nades and c4?
Which admins flags do you care about?
Should the player be given the weapon if he doesn’t have it?
Does it apply to only players on the same team as the admin?

[Bugsy]

This should cover all. I left chat prints in there so you can see what's happening in real-time. I tested it with bots and I see the switch happening. Granted, the player can switch to something else after force-switching their weapon, did you want to block that?

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <fun>

new const Version[] = "0.2";

const ADMIN_WEAPON_FLAGS = ADMIN_BAN | ADMIN_KICK;
const IGNORE_ITEMS = ( ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_C4 ) );
new const TeamNames[ CsTeams ][] = { "" , "TERRORIST" , "CT" , "" };

enum WeaponInfo
{
    CurrentWeapon,
    AllWeaponsBits
}
new g_wiData[ MAX_PLAYERS + 1 ][ WeaponInfo ];


public plugin_init() 
{
    register_plugin( "Admin Weapon Switch" , Version , "bugsy" );
    
    register_event("CurWeapon" , "WeaponChange" , "be" , "1=1" );
}

public WeaponChange( id )
{
    if ( ( get_user_flags( id ) & ADMIN_WEAPON_FLAGS ) == ADMIN_WEAPON_FLAGS )
    {
        new iWeaponID = read_data( 2 );
    
        if ( g_wiData[ id ][ AllWeaponsBits ] & ( 1 << iWeaponID ) )
        {
            if ( ( iWeaponID != g_wiData[ id ][ CurrentWeapon ] ) && !( IGNORE_ITEMS & ( 1 << iWeaponID ) ) )
            {
                client_print( id , print_chat , "Changed to weapon id %d" , iWeaponID );
                SetPlayerWeapons( id , iWeaponID , true );
            }
        }
        else
        {
            client_print( id , print_chat , "Picked up weapon id %d" , iWeaponID );
        }
            
        g_wiData[ id ][ CurrentWeapon ] = iWeaponID;
        g_wiData[ id ][ AllWeaponsBits ] = pev( id , pev_weapons );
    }
} 

SetPlayerWeapons( id , iWeaponID , bool:bSameTeamOnly=true )
{
    new iPlayers[ MAX_PLAYERS ] , iNum , iPlayer , szWeaponName[ 20 ] , CsTeams:csCurTeam = cs_get_user_team( id );
    
    get_players( iPlayers , iNum , bSameTeamOnly ? "ae" : "a" , bSameTeamOnly ? TeamNames[ csCurTeam ] : "" );
    get_weaponname( iWeaponID , szWeaponName , charsmax( szWeaponName ) );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        if ( iPlayer != id )
        {
            if ( !user_has_weapon( iPlayer , iWeaponID ) )
            {
                client_print( id , print_chat , "Giving id %d weapon %s" , iPlayer , szWeaponName );
                give_item( iPlayer , szWeaponName );
                engclient_cmd( iPlayer , szWeaponName );
            }
            else
            {
                client_print( id , print_chat , "Setting id %d weapon to %s" , iPlayer , szWeaponName );
                engclient_cmd( iPlayer , szWeaponName );
            }
        }
    }
} 


[Cuttlas]

I'm trying to do it on weapon pick up, but no success:

PHP Code:

public weapon_pickup( iEntity )
{
        new wid = read_data(2)
          new id = pev( wid , pev_owner );
    
        if ( iEntity == admin)
        {
            client_print( 0 , print_chat , "Admin picked up a weapon");
            new szWeaponName[ 23 ];
            new iWeaponID = cs_get_weapon_id( wid );
            get_weaponname( iWeaponID , szWeaponName , charsmax( szWeaponName ) );
            
            client_print( 0 , print_chat , "Admin picked up %s weapon" , szWeaponName);
        }
} 


it will print ""Admin picked up a weapon""

but it can not print the weapon name. how to fix it?

[Bugsy]

What event is triggering weapon_pickup?
Why are you checking if the weapon entity (iEntity) is equal to admin? This may just be bad variable naming.
What does admin hold?

If you are using CurWeapon to trigger weapon_pickup, this does not give you the entity ID, only the CSW_ weapon id. You cannot use pev_owner to get the owner of this. The owner is passed directly into the CurWeapon event.

This may be what you are trying to do:

PHP Code:

public weapon_pickup( iPlayer )
{
    if ( iPlayer == admin )
    {
        //client_print( 0 , print_chat , "Admin picked up a weapon");
        new szWeaponName[ 23 ];
        get_weaponname( read_data( 2 ), szWeaponName , charsmax( szWeaponName ) );
        
        client_print( 0 , print_chat , "Admin picked up %s weapon" , szWeaponName[ 7 ] );
    }
} 


[Cuttlas]

I have used this:

register_event("WeapPickup", "weapon_pickup", "b");

with yours and the WeapPickup, again it can not find the weapon name!

the admin is just an example, it will store the admin id in terror Team for example.

also beside the weapon name, I need the weapon id.

[Bugsy]

Change read_data( 2 ) to read_data( 1 ). What do you need the entity ID for?

Name:	WeapPickup
Structure:	
byte	WeaponID

[Cuttlas]

worked well Bugsy.

I'm trying to give the admin's weapon to other players on a team. so the Entity ID (which here is the player id who picks up the weapon) can help me to decide whether the player is admin or not.