[_GamerX]

This: HookEvent("round_start", OnRoundStart, EventHookMode_Pre);
change to this HookEvent("round_prestart", OnRoundStart);

[Obyboby]

Originally Posted by _GamerX This: HookEvent("round_start", OnRoundStart, EventHookMode_Pre); change to this HookEvent("round_prestart", OnRoundStart);

Thanks dude, I replaced that in the latest source of the plugin as posted in the previous page, let's see if it works

[WatchDogs]

Oh Thank you so much _GamerX.

Here is fixed-working version:

PHP Code:

#pragma semicolon 1

#define PLUGIN_AUTHOR "[W]atch [D]ogs"
#define PLUGIN_VERSION "1.0.6"

#include <sourcemod>
#include <cstrike>
#include <sdktools_functions>

#pragma newdecls required

Handle h_bEnable;

public Plugin myinfo = 
{
    name = "Fast Team Balancer",
    author = PLUGIN_AUTHOR,
    description = "Balances teams at start of every rounds",
    version = PLUGIN_VERSION,
    url = "https://forums.alliedmods.net/showthread.php?t=298717"
};

public void OnPluginStart()
{
    h_bEnable = CreateConVar("sm_ftb_enable", "1", "Enable / Disable fast team balancing", _, true, 0.0, true, 1.0);
    if(GetEngineVersion() == Engine_CSGO)
        HookEvent("round_prestart", Event_PreRoundStart);
    else
        HookEvent("round_end", Event_PreRoundStart);
}

public Action Event_PreRoundStart(Handle event, const char[] name, bool dontBroadcast)
{
    int T_Count = GetTeamClientCount(CS_TEAM_T);
    int CT_Count = GetTeamClientCount(CS_TEAM_CT);
    
    if(!GetConVarBool(h_bEnable) || T_Count == CT_Count || T_Count + 1 == CT_Count || CT_Count + 1 == T_Count)
        return Plugin_Continue;
        
    while(T_Count > CT_Count && T_Count != CT_Count + 1)
    {
        int client = GetRandomPlayer(CS_TEAM_T);
        CS_SwitchTeam(client, CS_TEAM_CT);
        T_Count--;
        CT_Count++;
    }
    while(T_Count < CT_Count && CT_Count != T_Count + 1)
    {
        int client = GetRandomPlayer(CS_TEAM_CT);
        CS_SwitchTeam(client, CS_TEAM_T);
        CT_Count--;
        T_Count++;
    }
    return Plugin_Continue;
}

stock int GetRandomPlayer(int team) 
{ 
    int[] clients = new int[MaxClients]; 
    int clientCount; 
    for (int i = 1; i <= MaxClients; i++) 
    { 
        if (IsClientInGame(i) && GetClientTeam(i) == team)
        { 
            clients[clientCount++] = i; 
        } 
    } 
    return (clientCount == 0) ? -1 : clients[GetRandomInt(0, clientCount - 1)]; 
} 


EDIT: 1.0.6 | Fixed a bug for non-CSGO games.

[Obyboby]

This is nearly perfect but sometimes players are slayed at the end of a round in order to be moved. It doesn't always happen though.
Could you look into that?

[WatchDogs]

Are you using the last version ?

CS_SwitchTeam shouldn't slay them.

Check the version if problem continues I'll give you another thing to test.

[Obyboby]

Originally Posted by WatchDogs Are you using the last version ? CS_SwitchTeam shouldn't slay them. Check the version if problem continues I'll give you another thing to test.

Oops, I had 1.0.2 installed
Wil update to 1.0.6 and test.

[Obyboby]

Hey man, can you please check the plugin?
Some players reported that it resets their money upon moving to the other team.
It would be cool if the money was saved
I'm still not sure if this is related to this plugin itself or it's an incompatibility with another one... just trying to trouble shoot.
Thanks!

[vortex.]

I do not think it has anything to do with the plugin. But if you want, money can save before team transfer. When team transfer done, give money again. I can do that, if you want.

[Obyboby]

Originally Posted by vortex. I do not think it has anything to do with the plugin. But if you want, money can save before team transfer. When team transfer done, give money again. I can do that, if you want.

Yes please! So that I can add it to this plugin and see if the issue gets fixed.
Another "suspect" is the teambets plugin that I have recently installed but..one thing at a time :p

[vortex.]

I know this is very strange. But we must try. It will work.
This idea is ridiculous xD

EDIT: Test and report please, if dont working, we can add timers.

PHP Code:

#pragma semicolon 1 

#define PLUGIN_AUTHOR "[W]atch [D]ogs" // Respect ;)
#define PLUGIN_VERSION "1.0.6" 

#include <sourcemod> 
#include <cstrike> 
#include <sdktools_functions> 
#include <smlib>

#pragma newdecls required 

Handle h_bEnable; 

public Plugin myinfo =  
{ 
    name = "Fast Team Balancer", 
    author = PLUGIN_AUTHOR, 
    description = "Balances teams at start of every rounds", 
    version = PLUGIN_VERSION, 
    url = "https://forums.alliedmods.net/showthread.php?t=298717" 
}; 

public void OnPluginStart() 
{ 
    h_bEnable = CreateConVar("sm_ftb_enable", "1", "Enable / Disable fast team balancing", _, true, 0.0, true, 1.0); 
    if(GetEngineVersion() == Engine_CSGO) 
        HookEvent("round_prestart", Event_PreRoundStart); 
    else 
        HookEvent("round_end", Event_PreRoundStart); 
} 

public Action Event_PreRoundStart(Handle event, const char[] name, bool dontBroadcast) 
{ 
    int T_Count = GetTeamClientCount(CS_TEAM_T); 
    int CT_Count = GetTeamClientCount(CS_TEAM_CT); 
     
    if(!GetConVarBool(h_bEnable) || T_Count == CT_Count || T_Count + 1 == CT_Count || CT_Count + 1 == T_Count) 
        return Plugin_Continue; 
         
    while(T_Count > CT_Count && T_Count != CT_Count + 1) 
    { 
        int client = GetRandomPlayer(CS_TEAM_T);
        int oldmoney = Client_GetMoney(client);
        CS_SwitchTeam(client, CS_TEAM_CT);
        int newmoney = Client_GetMoney(client);
        T_Count--; 
        CT_Count++; 
        if(newmoney != oldmoney)
        {
            Client_SetMoney(client, oldmoney);
        }
    } 
    while(T_Count < CT_Count && CT_Count != T_Count + 1) 
    { 
        int client = GetRandomPlayer(CS_TEAM_CT); 
        int oldmoney = Client_GetMoney(client);
        CS_SwitchTeam(client, CS_TEAM_T);
        int newmoney = Client_GetMoney(client);        
        CT_Count--; 
        T_Count++; 
        if(newmoney != oldmoney)
        {
            Client_SetMoney(client, oldmoney);
        }
    } 
    return Plugin_Continue; 
} 

stock int GetRandomPlayer(int team)  
{  
    int[] clients = new int[MaxClients];  
    int clientCount;  
    for (int i = 1; i <= MaxClients; i++)  
    {  
        if (IsClientInGame(i) && GetClientTeam(i) == team) 
        {  
            clients[clientCount++] = i;  
        }  
    }  
    return (clientCount == 0) ? -1 : clients[GetRandomInt(0, clientCount - 1)];  
}