[Obyboby]

Okay so correct me if there's something easier than this.
Since mp_spawnprotectiontime doesn't seem to work for me, I need a plugin to help stop players that kill their team mates at spawn.
I installed eylonap_multicommands which gave me the option to !respawn a player, so that if an admin is in game, and notices a teamkill, he is able to at least respawn the player using that command.
What I was thinking is:
How about a plugin that shows a popup to any admin in game, after a teamkill occurs, showing the option to respawn the player? And perhaps add the ability to restore the health points and equipment they had at the time of the teamkill?
"Player X was teamkilled by player Y, respawn?" "Yes" "No"
After that, another menu with the available punishment for the teamkiller <---- Either for the victim or the admin, I don't know.. perhaps a kick/ban (with ban duration options) for admins, and a "standard" tkmenu for players with slap/slay etc.

Well the most important part I'd need is the respawn menu, i believe there should be a tkmenu plugin already..not sure whether it works on CSGO but I'm pretty sure I've seen it somewhere.
Thanks!

[WatchDogs]

Why don't you use this ? It has round start protection too.

https://forums.alliedmods.net/showthread.php?p=714326

Or this for menu

https://forums.alliedmods.net/showthread.php?p=1841274

[Obyboby]

Originally Posted by WatchDogs Why don't you use this ? It has round start protection too. https://forums.alliedmods.net/showthread.php?p=714326 Or this for menu https://forums.alliedmods.net/showthread.php?p=1841274

First one doesn't work in csgo, according to the latest replies to the thread.
Second one, could be something, but I'd love to have the menu popup for the admins to take immediate action.
Also what can I use to insta-kick whoever teamkills at the beginning of the round?

[WatchDogs]

OK. Wait i'm editing tk menu plugin. It takes some time

[WatchDogs]

Not tested.I added Round Protection & edited plugin to show menu to admins with 4 items:

Just Respawn Victim
Give 25% Cash of Killer to Victim - Respawn Victim
Slay Killer - Respawn Victim
Kick Killer - Respawn Victim

Also this cvars:

tk_round_protect_enable "1" - Enable / Disable round protection
tk_round_protect_time "10" - Round protection time in seconds

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <cstrike>

new Handle:h_iProtectTime;
new Handle:h_bProtectEnable;
new String:KillerList[MAXPLAYERS+1][MAX_NAME_LENGTH+1];
new String:VictimList[MAXPLAYERS+1][MAX_NAME_LENGTH+1];
new KilledBy[MAXPLAYERS+1];
new ACCOUNT_OFFSET;

#define PLUGIN_VERSION "1.2"

public Plugin:myinfo =
{
    name = "Simple CS:GO TK Menu + Round Start Protection",
    author = "Sheepdude",
    description = "Displays a TK Menu that lets TK victims steal cash",
    version = PLUGIN_VERSION,
    url = "http://www.clan-psycho.com"
};

public OnPluginStart()
{
    h_bProtectEnable = CreateConVar("tk_round_protect_enable", "1", "Enable / Disable round protection", _, true, 0.0, true, 1.0);
    h_iProtectTime = CreateConVar("tk_round_protect_time", "10", "Round protection time in seconds", _, true, 1.0);
    
    ACCOUNT_OFFSET = FindSendPropOffs("CCSPlayer", "m_iAccount");
    HookEventEx("player_death", PlayerDeathEvent);
    HookEvent("round_start", OnRoundStart);
}

public Action:OnRoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    if(!GetConVarBool(h_bProtectEnable))
        return Plugin_Continue;
        
    for (new i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i))
        {
            SetEntProp(i, Prop_Data, "m_takedamage", 0, 1);
        }
    }
    CreateTimer(GetConVarFloat(h_iProtectTime), RemoveProtection, _, TIMER_FLAG_NO_MAPCHANGE);
    return Plugin_Continue;
}

public PlayerDeathEvent(Handle:event, const String:name[], bool:dontBroadcast)
{
    new victim = GetClientOfUserId(GetEventInt(event,"userid"));
    new killer = GetClientOfUserId(GetEventInt(event,"attacker"));
    GetClientName(killer, KillerList[victim], sizeof(KillerList[]));
    GetClientName(victim, VictimList[victim], sizeof(VictimList[]));
    KilledBy[victim] = killer;
    if(victim > 0 && victim <= MaxClients && killer > 0 && killer <= MaxClients && GetClientTeam(victim) == GetClientTeam(killer) && victim != killer && !IsFakeClient(victim))
    {
        for (new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i) && !IsFakeClient(i) && GetUserAdmin(i) != INVALID_ADMIN_ID)
            {
                doTKMenu(i, victim);
            }
        }
    }
}

public doTKMenu(client, victim)
{
    decl String:menuTitle[64], String:sVictim[8];
    Format(menuTitle, sizeof(menuTitle), "Team Killer! %s were killed by %s, choose an action:", VictimList[victim], KillerList[victim]);
    IntToString(victim, sVictim, sizeof(sVictim));
    
    new Handle:menu = CreateMenu(handleTKVoteMenu);
    SetMenuTitle(menu, menuTitle);
    AddMenuItem(menu, sVictim, "Just Respawn Victim");
    AddMenuItem(menu, sVictim, "Give 25\% Cash of Killer to Victim - Respawn Victim");
    AddMenuItem(menu, sVictim, "Slay Killer - Respawn Victim");
    AddMenuItem(menu, sVictim, "Kick Killer - Respawn Victim");
    DisplayMenu(menu, client, MENU_TIME_FOREVER);
}

public handleTKVoteMenu(Handle:menu, MenuAction:action, param1, param2) 
{
    if (action == MenuAction_End) 
    {
        CloseHandle(menu);
    }
    else if (action == MenuAction_Select)
    {
        decl String:sItem[8];
        GetMenuItem(menu, param2, sItem, sizeof(sItem));
        new victim = StringToInt(sItem);
        if(param2 == 0)
        {
            PrintToChatAll("\x01\x0B\x04[TKMenu]\x01 %s was respawned by admin", VictimList[victim]);
            CS_RespawnPlayer(victim);
        }
        else if(param2 == 1 && IsClientInGame(victim) && IsClientInGame(KilledBy[victim]))
        {
            new KillerMoney = GetEntData(KilledBy[victim], ACCOUNT_OFFSET, 4);
            new VictimMoney = GetEntData(victim, ACCOUNT_OFFSET, 4);
            new difference = RoundToFloor(KillerMoney * 0.25);
            SetEntData(KilledBy[victim], ACCOUNT_OFFSET, KillerMoney - difference, 4, true);
            if(VictimMoney + difference > 16000)
                SetEntData(victim, ACCOUNT_OFFSET, 16000, 4, true);
            else
                SetEntData(victim, ACCOUNT_OFFSET, VictimMoney + difference, 4, true);
            PrintToChatAll("\x01\x0B\x04[TKMenu]\x01 %s stole \x05$%d\x01 from %s for team killing.", VictimList[victim], difference, KillerList[victim]);
            CS_RespawnPlayer(victim);
        }
        else if(param2 == 2 && IsClientInGame(KilledBy[victim]))
        {
            CreateTimer(0.0, Slay, KilledBy[victim], TIMER_FLAG_NO_MAPCHANGE);
            PrintToChatAll("\x01\x0B\x04[TKMenu]\x01 %s was slain for team killing %s.", KillerList[victim], VictimList[victim]);
            CS_RespawnPlayer(victim);
        }
        else if(param2 == 3 && IsClientInGame(KilledBy[victim]))
        {
            KickClient(KilledBy[victim], "Kicked By Admin. Reason: Team Killing");
            PrintToChatAll("\x01\x0B\x04[TKMenu]\x01 %s was kicked for team killing %s.", KillerList[victim], VictimList[victim]);
            CS_RespawnPlayer(victim);
        }
    }
}

public Action:Slay(Handle:timer, any:client)
{
    ForcePlayerSuicide(client);
}

public Action:RemoveProtection(Handle:timer)
{
    for (new i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i))
        {
            SetEntProp(i, Prop_Data, "m_takedamage", 2, 1);
        }
    }
} 


EDIT: Updated to 1.2 | Fixed a bug

[Obyboby]

Thanks, I installed it and will test!
Question: so the MODERATORS get the menu and not the victim right?
What if there are multiple mods on the server? And ideally two mods choose two differnent options at the same time?
Like mod A clicks steal cash, mod B clicks slay (example), I guess the plugin just takes the first command?

[WatchDogs]

Yes menu is only for admins.

You can choose one option only. If you want I can add more options.

[Obyboby]

Originally Posted by WatchDogs Yes menu is only for admins. You can choose one option only. If you want I can add more options.

"Ban player" that opens another menu with "10 minutes - 1 hour - 1 day - permanent" is this possible?

[WatchDogs]

Here you are. Sorry for late.