[CrazY.]

Hello, I want to do a thing for one weapon only. I need to hide weapon clip of hud and when player shoot, decrease one bullet of bpammo.

[Bugsy]

I'm not sure it's possible to hide just the clip ammo. You could possibly make it display 0 or some constant value.

I was thinking HideWeapon message, but this hides other things in addition to ammo.

  1   (1<<0)  -  crosshair, ammo, weapons list
  2   (1<<1)  -  flashlight, +
  4   (1<<2)  -  ALL
  8   (1<<3)  -  radar, health, armor, +
 16   (1<<4)  -  timer, +
 32   (1<<5)  -  money, +
 64   (1<<6)  -  crosshair
128   (1<<7)  -  +

This will show clip as always 0 (or whatever you want it to show as) and subtract from bpammo as shots are fired. It needs a little work but it's something to start with:

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define m_pActiveItem 373

const WeaponType = CSW_GLOCK18; //Weapon that you want this plugin to apply to
const DisplayClip = 0; //Clip ammo that will display regardless of actual contents

enum _:CurWeaponArgs
{
    IsActive = 1,
    WeaponID,
    ClipAmmo
}

public plugin_init() 
{
    register_message( get_user_msgid( "CurWeapon" ) , "CurWeapon" );
}

public CurWeapon( msg_id , msg_dest , msg_entity )
{
    new iClip , iBP , iWeaponEnt;
    
    if ( ( get_msg_arg_int( IsActive ) == 1 ) && ( get_msg_arg_int( WeaponID ) == WeaponType ) )
    {
        get_user_ammo( msg_entity , WeaponType , iClip , iBP );
        iWeaponEnt = get_pdata_cbase( msg_entity , m_pActiveItem );
        
        if ( iBP >= 1 )
        {
            cs_set_user_bpammo( msg_entity , WeaponType , --iBP );
            cs_set_weapon_ammo( iWeaponEnt , 40 );
        }
        else
        {
            cs_set_weapon_ammo( iWeaponEnt , 0 );
        }
        
        set_msg_arg_int( ClipAmmo , 0 , DisplayClip );
    }
} 


[CrazY.]

I will test that bugsy, thank you!

[CrazY.]

Bugsy, the code is subtracting 1 from the Bpammo of the player even if it is not firing. I print the value of IBP, is showing the Bpammo that the player should have, but in the hud shows the current value subtracted by one. So when the player's Bpammo is at 0, I can shoot one more time.

Apart from that problem, the code is OK!

I did some tests and found that if you change the display value to -1, it will only show you the Bpammo.

Edit: If I get user button and check if is IN_ATTACK the code work, but still player can shoot more one time if bpammo are 0

[NiHiLaNTh]

I am pretty sure it is possible - just send 'CurWeapon' message with argument -1 as weapon clip.

[Craxor]

Here's what i've done, is not using bpammo insteand of ammo, but when you no more having bullets is settings directly the bullets as bpamoo and empty the bpammo, test to see by yourself how is working.

You can easily add a hudmessage and remove the clip using the bugsy method (HideWeaponMessage) by yourself and manage how you want.

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <fun>
#include <cstrike>
#include <engine>

public plugin_init()
{
    new szWeaponName[20];
    for( new i = 1; i < 31; i++ )
    {
        get_weaponname( i, szWeaponName, charsmax(szWeaponName) );

        if( szWeaponName[0] != EOS )
        {
            RegisterHam( Ham_Weapon_PrimaryAttack, szWeaponName, "ham_WpPrimaryAttack_PostFunc", true );
        }
    }
}

public ham_WpPrimaryAttack_PostFunc( const Entity )
{
    new OwnerOfWeaponIndex = pev( Entity, pev_owner );
    new Bullets,Ammo;

    new WeaponId = get_user_weapon( OwnerOfWeaponIndex, Bullets, Ammo );

    if( Bullets <= 1 )
    {
        give_user_weapon( OwnerOfWeaponIndex, WeaponId, Ammo--, 0 );
    }
}


give_user_weapon( index , iWeaponTypeID , iClip=0 , iBPAmmo=0 , szWeapon[]="" , maxchars=0 )
{
    if ( !( CSW_P228 <= iWeaponTypeID <= CSW_P90 ) || ( iClip < 0 ) || ( iBPAmmo < 0 ) || !is_user_alive( index ) )
        return -1;
    
    new szWeaponName[ 20 ] , iWeaponEntity , bool:bIsGrenade;
    
    const GrenadeBits = ( ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) );
    
    if ( ( bIsGrenade = bool:!!( GrenadeBits & ( 1 << iWeaponTypeID ) ) ) )
        iClip = clamp( iClip ? iClip : iBPAmmo , 1 );
    
    get_weaponname( iWeaponTypeID , szWeaponName , charsmax( szWeaponName ) );
    
    if ( ( iWeaponEntity = user_has_weapon( index , iWeaponTypeID ) ? find_ent_by_owner( -1 , szWeaponName , index ) : give_item( index , szWeaponName ) ) > 0 )
    {
        if ( iWeaponTypeID != CSW_KNIFE )
        {
            if ( iClip && !bIsGrenade )
                cs_set_weapon_ammo( iWeaponEntity , iClip );
        
            if ( iWeaponTypeID == CSW_C4 ) 
                cs_set_user_plant( index , 1 , 1 );
            else
                cs_set_user_bpammo( index , iWeaponTypeID , bIsGrenade ? iClip : iBPAmmo ); 
        }
        
        if ( maxchars )
            copy( szWeapon , maxchars , szWeaponName[7] );
    }
    
    return iWeaponEntity;
} 


[CrazY.]

Ok, thanks.

[CrazY.]

Bugsy, I tried to do the same with the Bpammo so it looks like the HUD of the knife, but I realized that there is no argument in the Curweapon as Clipammo. Can you help me?

https://wiki.alliedmods.net/Half-lif...ents#CurWeapon

Edit: I will try with ammox.
https://wiki.alliedmods.net/Half-lif...e_events#AmmoX

[Depresie]

What weapon are you trying to create exactly ?
Maybe we can find a work around instead of rewriting a lot of stuff..

[CrazY.]

Well, it's actually I added a power system to the Predators in my mod, so I don't need the clip/Bpammo from the plasma caster.

And the speargun just needs the Bpammo, it's already working.