[deprale]

PHP Code:

/* Sublime AMXX Editor v2.2 */

#include <amxmodx>

#define PLUGIN  "LICENSE PLUGIN FIXED"
#define VERSION "1.0"
#define AUTHOR  "deprale"

new hostname[ 64 ]
new hostip[ 20 ]
new bool:Licensed

enum _:ServerInfo
{
    ServerName[ 64 ],
    ServerIP[ 64 ]
}

new const g_ServerList[][ ServerInfo ] = 
{
    { "PUB.ALLSTAR.RU", "127.0.0.1" },
    { "PUB2.ALLSTAR.RU", "localhost" }
};

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    CheckLicense()
}

public CheckLicense()
{
    get_cvar_string("hostname", hostname, 63)
    get_cvar_string("ip", hostip, 19)

    for(new i = 0; i < sizeof( g_ServerList ); i++)
    {
        if( !equali( hostname, g_ServerList[ i ][ ServerName ]) || !equali( hostip, g_ServerList[ i ][ ServerIP ]))
            Licensed = false

        else {
        Licensed = true
        break;
        }
    }

    switch(Licensed) {
        case 0:
        {
            set_fail_state("[HOST-IP LICENSE] SOMETHING WENT WRONG!")
        }
        case 1:
        {
            server_print("[HOST-IP LICENSE] NAME (%s), IP (%s) - LICENSE SUCCESSFULLY VERIFIED!", hostname, hostip)
        }
    }

    return PLUGIN_HANDLED;
} 


before anyone jumps to conclusions, YES I DO KNOW this is "useless" if someone really wants to crack it.

[CrazY.]

Get server IP with get_user_ip(0, ...), not by cvars.

[deprale]

Thanks, done!

[Natsheh]

Add a break after lincesed = falsee

Use equal instead of equali

CheckING ip + port is much better than ip ,+;servername


CheckLicense function is no need to be a public and remove the returning in the function it's useless


Switch can also take boolean values

[OciXCrom]

This type of plugin is against the rules. I assume you plan to hand out only the .amxx file after you're done, correct?

[HamletEagle]

The best optimization is deleting it entirely, it's useless and what is the purpose of developing useless code? People can just open the source file and remove your license check.

But the real question is what OciXCrom said. Are you going to provide the sma file?
If yes, you are free to add licensing, people will just delete the code and recompile.
If no, then you are breaking the license and this is not acceptable.

[Bugsy]

Originally Posted by Natsheh //Add a break after lincesed = falsee The loop would then exit after checking the first server in g_ServerList[] if there was no match. The 'Licensed=false' code can be removed all together. //Use equal instead of equali He should only use equal on the IP, equali() is needed on the hostname. //CheckING ip + port is much better than ip ,+;servername //CheckLicense function is no need to be a public and remove the returning in the function it's useless //Switch can also take boolean values An if/else statement is more relevant for a bool

@deprale, I'm not sure if you want to require the hostname and IP match in the same row of g_ServerList[]. The below will require both hostname and IP match.

PHP Code:

CheckLicense()
{
    new szHost[ 64 ] , szIP[ 16 ] , bool:bLicensed;
    
    get_cvar_string( "hostname" , szHost , charsmax( szHost ) );
    get_cvar_string( "ip" , szIP , charsmax( szIP ) );
    
    for ( new i = 0 ; i < sizeof( g_ServerList ) ; i++ )
    {
        if ( equali( szHost , g_ServerList[ i ][ ServerName ] ) && equal( szIP , g_ServerList[ i ][ ServerIP ] ) ) 
        {
            bLicensed = true;
            break;
        }
    }

    if ( !bLicensed )
    {
        set_fail_state( "[HOST-IP LICENSE] SOMETHING WENT WRONG!" );
    }
    else
    {
        server_print("[HOST-IP LICENSE] NAME (%s), IP (%s) - LICENSE SUCCESSFULLY VERIFIED!" , szHost , szIP );
    }
} 


[Bugsy]

I agree with HamletEagle and Oxi. If this plugin is going to be distributed on these boards then the code is useless.

[deprale]

Nah, this is a custom request by one of my friends Chill out guys, I already said it's useless in the original post, he didn't want any of his friends to steal the plugin from the FTP Server so they could move out on with their own community, as they have an agreement to never share the plugin with someone else so one of them suggested this.

Only the ORIGINAL owner will have the .sma, the rest won't have access to it, but they will have access to the FTP server and it's just the ORIGINAL owner's concern that someone might steal it!

I read the ToS of AmxModX and I'm fully aware it's not legal to "sell" plugins without the .sma itself!

EDIT: thanks everyone for the suggestions! learning something new everyday

[Mordekay]

As said this protection is not really secure. If your server is running on linux you should better move the .amxx into another directory and only put a symlink into the plugins folder. This way all they could steal is the symlink