[noxman]

Hello,

i have this plugin: http://forums.alliedmods.net/showthread.php?p=1257852

i want include a point resetter. If a player change the team during the game, the points should be resettet (but only for this player, not whole Team). At the moment, the points will be reset at round_start and round_end only.

I coded something (myself):

Spoiler

PHP Code:

public Action:Event_REnd(Handle:event, String:event_name[], bool:dontBroadcast)
{
    if(IsAllowedReset())
    {
        for (new i=1; i<=MaxClients; i++)
        {
            points[i] = GetConVarInt(StartPoints);
            hurtcount[i] = 0;
            protectcount[i] = 0;
            headshotcount[i] = 0;
            killcount[i] = 0;
            wassmoker[i] = 0;
        }    
    }
    tanksspawned = 0;
    witchsspawned = 0;
    PrintToChat("[PS]The Points are been reset to 200.");
}

public Action:Event_TeamChange(Handle:event, String:event_name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    new teamnew = GetEventInt(event, "team");
    new teamold = GetEventInt(event, "oldteam");
    
    if (teamold != teamnew, client){
    
    if(IsAllowedReset(), client)
    {
        for (new i=1; i<=MaxClients; i++)
        {
            points[i] = GetConVarInt(StartPoints);
            hurtcount[i] = 0;
            protectcount[i] = 0;
            headshotcount[i] = 0;
            killcount[i] = 0;
            wassmoker[i] = 0;
        }    
    }
    tanksspawned = 0;
    witchsspawned = 0;
    PrintToChat("[PS]The Points are been reset to 200.");
    }
}    

public Action:Event_RStart(Handle:event, String:event_name[], bool:dontBroadcast)
{
    if (!IsModelPrecached("models/w_models/weapons/w_m60.mdl")) PrecacheModel("models/w_models/weapons/w_m60.mdl");
    if (!IsModelPrecached("models/v_models/v_m60.mdl")) PrecacheModel("models/v_models/v_m60.mdl");
    if(IsAllowedReset())
    {
        for (new i=1; i<=MaxClients; i++)
        {
            points[i] = GetConVarInt(StartPoints);
            hurtcount[i] = 0;
            protectcount[i] = 0;
            headshotcount[i] = 0;
            killcount[i] = 0;
            wassmoker[i] = 0;
        }    
    }
    tanksspawned = 0;
    witchsspawned = 0;
    PrintToChat("[PS]The Points are been reset to 200.");
} 


But a hard bugg: The points are reset always (without teamchange too). What is wrong? Sry for my english.

[xf117]

That does not make any sense

PHP Code:

if (teamold != teamnew, client) 


And you are clearing the whole array, that is why it points are being reset for each player.
Something like that will do

PHP Code:

public Action:Event_TeamChange(Handle:event, String:event_name[], bool:dontBroadcast) {

    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    new teamnew = GetEventInt(event, "team");
    new teamold = GetEventInt(event, "oldteam");

    if (teamold != teamnew && IsAllowedReset()) {
        points[client] = GetConVarInt(StartPoints);
        hurtcount[client] = 0;
        protectcount[client] = 0;
        headshotcount[client] = 0;
        killcount[client] = 0;
        wassmoker[client] = 0;
    }
    
    tanksspawned = 0;
    witchsspawned = 0;
    PrintToChat(client, "[PS]The Points are been reset to 200.");
} 


[noxman]

Thank you. It works

[noxman]

It works, but it spams my console with a error:

PHP Code:

L 10/31/2013 - 19:15:32: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:32: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:32: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange()
L 10/31/2013 - 19:15:32: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:32: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:32: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange()
L 10/31/2013 - 19:15:32: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:32: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:32: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange()
L 10/31/2013 - 19:15:32: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:32: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:32: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange()
L 10/31/2013 - 19:15:32: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:32: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:32: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange()
L 10/31/2013 - 19:15:36: [SM] Native "PrintToChat" reported: Client index 0 is invalid
L 10/31/2013 - 19:15:36: [SM] Displaying call stack trace for plugin "point_system_167_fix_reset_beta.smx":
L 10/31/2013 - 19:15:36: [SM]   [0]  Line 702, point_system_167_fix_reset_beta.sp::Event_TeamChange() 


[sdz]

PHP Code:

public Action:Event_TeamChange(Handle:event, String:event_name[], bool:dontBroadcast) {

    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    new teamnew = GetEventInt(event, "team");
    new teamold = GetEventInt(event, "oldteam");

    if (teamold != teamnew && IsAllowedReset()) {
        points[client] = GetConVarInt(StartPoints);
        hurtcount[client] = 0;
        protectcount[client] = 0;
        headshotcount[client] = 0;
        killcount[client] = 0;
        wassmoker[client] = 0;
    }
    
    tanksspawned = 0;
    witchsspawned = 0;
    if(IsClientInGame(client))
        PrintToChat(client, "[PS]The Points are been reset to 200.");
} 


Always want to check if the client is in game.
if(IsClientInGame(client))

[xf117]

This will probably also yield an error, because 0 is not a valid client.
I'm not sure, how and why this event gets fired with client 0, but workaround is:

PHP Code:

public Action:Event_TeamChange(Handle:event, String:event_name[], bool:dontBroadcast) {

    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    if (client == 0) {
        return Plugin_Continue;
    }
    // The rest of the code is the same 


And with this is safe to add @EasSidezz's check for IsClientInGame.

[noxman]

Originally Posted by xf117 This will probably also yield an error, because 0 is not a valid client. I'm not sure, how and why this event gets fired with client 0, but workaround is: PHP Code: public Action:Event_TeamChange(Handle:event, String:event_name[], bool:dontBroadcast) {     new client = GetClientOfUserId(GetEventInt(event, "userid"));     if (client == 0) {         return Plugin_Continue;     }     // The rest of the code is the same  And with this is safe to add @EasSidezz's check for IsClientInGame.

Thanks for that, but i get a warning:

[GsiX]

Originally Posted by noxman Thanks for that, but i get a warning:

PHP Code:

if ( client == 0 ) return; 


[noxman]

Wow, thanks

[xf117]

It doesn't really matter what to return - the hook is in Post mode. I assumed you have

PHP Code:

 return Plugin_Continue; 


in the end of the callback. Didn't check that.