[backwards]

The following error occurs when running the same code on a linux system that works on a windows system.

PHP Code:

ERROR: Tried to SetParentAttachmentMaintainOffset for entity prop_dynamic (prop_dynamic), but it has no attachment named baseorigin. 


The model I've created only has a single bone and that bone is used as an attachment point with no offset.



The QC file to compile the model is really simple.



Both the windows and linux server are running the same base sourcemod install plugins.

Looking at the function in the SDK the LookupAttachment function is failing.

This should obviously only fail if the entity's model doesn't have any attachments with the lookup name.

This is how the code is structured

PHP Code:

new ent = CreateEntityByName("prop_dynamic_override");
....
TeleportEntity(ent, or, ang, NULL_VECTOR); 
    
SetVariantString("!activator");
AcceptEntityInput(ent, "SetParent", client, ent, 0);
    
SetVariantString("baseorigin");
AcceptEntityInput(ent, "SetParentAttachmentMaintainOffset", ent, ent, 0); 


I check the model before setting it like so to validate it's the correct one.

PHP Code:

decl String:m_ModelName[PLATFORM_MAX_PATH];
GetEntPropString(client, Prop_Data, "m_ModelName", m_ModelName, sizeof(m_ModelName));

if (strcmp(m_ModelName, "models/player/Placeholder_Model/placeholder_model.mdl") != 0)
{
    PrintToChat(client, "%s", m_ModelName);
    Format(m_OrginalModelName[client], PLATFORM_MAX_PATH, "%s", m_ModelName);
    SetEntityModel(client, "models/player/Placeholder_Model/placeholder_model.mdl");
} 


Using delays in timers after setting the model or using BoneMerge doesn't seem to fix the issue either.

PHP Code:

public void Bonemerge(int ent)
{
    int m_iEntEffects = GetEntProp(ent, Prop_Send, "m_fEffects"); 
    m_iEntEffects &= ~32;
    m_iEntEffects |= 1;
    m_iEntEffects |= 128;
    SetEntProp(ent, Prop_Send, "m_fEffects", m_iEntEffects); 
} 


I'm curious if anyone knows the reason for this as i haven't seen a single topic about this issue. Is there some dumb rule that isn't mentioned on the Developer.Valve website like "root bones can not be attachments and must have a child bone"? (which i know isn't right since it works on windows)

[Mitchell]

The attachment must exist on the player's model not the model you created. Try setting the attachment point to "forward"

[backwards]

Originally Posted by Mitchell The attachment must exist on the player's model not the model you created. Try setting the attachment point to "forward"

Sorry for not being clear about this part but this is a secondary model I've created which i turn into the players model so that i can utilize pos (0 0 0) since the default models have no attachment at this position. This player model is turned invisible and is only used for this attachment point so that i can utilize the "m_flPoseParameter" netprop on the prop_dynamic_override. If I just assign the model to the player and attempt to use those they appear to be overwritten by game code constantly, even if i add 23 bogus pose parameters and attempt to set the 24th one it still seems to be overwritten. The thing is i don't believe anything is wrong with the setup as the attachment point works just fine on my windows system srcds but on the two linux srcds they just throw out this error and prevent the attachment.

Here's a quick video i made describing the issue.
https://www.youtube.com/watch?v=p_SwyaDHQ3w

Edit: I've made a work around after debugging the process and realizing it's not populating the array of data for studiohdr_t related information after using SetEntityModel. The loop exits before comparing the string for the input attachment point name here at GetNumAttachments(). So after looking deeper into the code I decided to try calling the main function with my own identifier of the attachment point which should be 1 in this case. Using SDKTools here's the config file with signatures to call the function in cstrike.

PHP Code:

"Games"
{
    "cstrike"
    {
        "Signatures"
        {
            "SetParent"
            {
                "library"    "server"
                "linux"        "@_ZN11CBaseEntity9SetParentEPS_i"
                "windows"    "\x55\x8B\xEC\x81\xEC\x2A\x2A\x2A\x2A\x83\x7D\x0C\xFF"
            }
        }
    }
} 


And to call the function inside sourcemod.

PHP Code:

#include <sdktools>
new Handle:g_hSetParent = INVALID_HANDLE;
...

public OnPluginStart()
{
    new Handle:m_hGameConf = LoadGameConfigFile("mario_wheelchair.gamedata");
    StartPrepSDKCall(SDKCall_Entity);
    PrepSDKCall_SetFromConf(m_hGameConf, SDKConf_Signature, "SetParent");
    PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);
    g_hSetParent = EndPrepSDKCall();
    CloseHandle(m_hGameConf);
        
    if(!g_hSetParent)
    {
        LogError("SetParent signature is out of date or not supported in this game.");
        return;
    }
}
...
public SetParent(client, ent, iAttachment)
{
    if(g_hSetParent==INVALID_HANDLE)
        return;
    if(!client || !IsClientInGame(client))
        return;
        
    SDKCall(g_hSetParent, ent, client, iAttachment);
}
...

    TeleportEntity(ent, or, ang, NULL_VECTOR); 
    
    SetVariantString("!activator");
    AcceptEntityInput(ent, "SetParent", client, ent, 0);
    
    SetParent(client, ent, 1); 


Topic can be changed to resolved.