[NooTy]

When Any Admin access kill he Got +80hp and 80ap and 8k$ Why ??

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>

static const
    PLUGIN[] = "Beneficii Playeri",
    VERSION[] = "1.1",
    AUTHOR[] = "NooTy";
    
public plugin_init(){
    register_plugin(PLUGIN,VERSION,AUTHOR);
    register_event("DeathMsg","ev_death_msg","a")
}
public ev_death_msg( ) {
    new id = read_data(1)
    new victim = read_data(2)

    if(!is_user_alive(id) || id == victim) return
    
    if(get_user_flags(id) & read_flags("abcdefghijklmnopqrsux")) {
        cs_set_user_money(id,cs_get_user_money(id) + 8000)
        set_user_health(id,get_user_health(id) + 80)
        set_user_armor(id,get_user_armor(id) + 80)
    }
     else if(get_user_flags(id) & read_flags("abcdefghijklmnopqrsu")) {
        cs_set_user_money(id,cs_get_user_money(id) + 7000)
        set_user_health(id,get_user_health(id) + 70)
        set_user_armor(id,get_user_armor(id) + 70)
    }
     else if(get_user_flags(id) & read_flags("bcdefimnjo")) {
        cs_set_user_money(id,cs_get_user_money(id) + 6000)
        set_user_health(id,get_user_health(id) + 60)
        set_user_armor(id,get_user_armor(id) + 60)
    }
    else if(get_user_flags(id) & read_flags("bcdefimnjp")) {
        cs_set_user_money(id,cs_get_user_money(id) + 5000)
        set_user_health(id,get_user_health(id) + 50)
        set_user_armor(id,get_user_armor(id) + 50)
    }
     else if(get_user_flags(id) & read_flags("bcdefimnjs")) {
        cs_set_user_money(id,cs_get_user_money(id) + 3500)
        set_user_health(id,get_user_health(id) + 35)
        set_user_armor(id,get_user_armor(id) + 35)
    }
    else  if(get_user_flags(id) & read_flags("bcdefimnjt")) {
        cs_set_user_money(id,cs_get_user_money(id) + 2000)
        set_user_health(id,get_user_health(id) + 20)
        set_user_armor(id,get_user_armor(id) + 20)
    }
    
    else if(get_user_flags(id) & read_flags("z")) {
        set_user_health(id,get_user_health(id) + 10)
        set_user_armor(id,get_user_armor(id) + 5)
    }
} 


[OciXCrom]

Because "get_user_flags & flag" checks if the user has AT LEAST ONE of the specified admin flags.
Check the "has_all_flags" function from "amxmisc".

[4ever16]

Because.

PHP Code:

if(get_user_flags(id) & read_flags("abcdefghijklmnopqrsux")) 


Change all

PHP Code:

if(get_user_flags(id) & read_flags 


To

PHP Code:

    else if(get_user_flags(id) & read_flags("z")) {
        set_user_health(id,get_user_health(id) + 10)
        set_user_armor(id,get_user_armor(id) + 5)
    } 


[Bugsy]

Originally Posted by 4ever16 Because. PHP Code: if(get_user_flags(id) & read_flags("abcdefghijklmnopqrsux"))  Change all PHP Code: if(get_user_flags(id) & read_flags  To PHP Code:     else if(get_user_flags(id) & read_flags("z")) {         set_user_health(id,get_user_health(id) + 10)         set_user_armor(id,get_user_armor(id) + 5)     }

That makes no sense..OciXCrom correctly identified his problem. The & operator will result in all bits that match, but the if () condition only checks for non-zero so if any single flags exists, the condition will return true. OP wants the player to have all flags.

@OP, I reduced/organized your code and fixed your issue. My code does the same as has_all_flags(), just manually to avoid the native call. Though it's a lightweight native so there really is no issue using it.

PHP Code:


#include <amxmodx>
#include <fun>
#include <cstrike>

static const
    PLUGIN[] = "Beneficii Playeri",
    VERSION[] = "1.1",
    AUTHOR[] = "NooTy";

enum BenefitsLevels
{
    Level1 ,
    Level2 ,
    Level3 ,
    Level4 ,
    Level5 ,
    Level6 ,
    Level7
}

enum Benefits
{
    Flags[ 26 ] ,
    FlagBits , 
    Money ,
    Health ,
    Armor
}

new BenefitsData[ BenefitsLevels ][ Benefits ] = 
{
    { "abcdefghijklmnopqrsux" , 0 , 8000 , 80 , 80 },
    { "abcdefghijklmnopqrsu" , 7000 , 70 , 70 },
    { "bcdefimnjo" , 0 , 6000 , 60 , 60 },
    { "bcdefimnjp" , 0 , 5000 , 50 , 50 },
    { "bcdefimnjs" , 0 , 3500 , 35 , 35 },
    { "bcdefimnjt" , 0 , 2000 , 20 , 20 },
    { "z" , 0 , 0 , 10 , 5 }
};

public plugin_init()
{
    register_plugin(PLUGIN,VERSION,AUTHOR);
    register_event("DeathMsg","ev_death_msg","a")
    
    for ( new BenefitsLevels:blIndex = Level1 ; blIndex < BenefitsLevels ; blIndex++ )
    {
        BenefitsData[ blIndex ][ FlagBits ] = read_flags( BenefitsData[ blIndex ][ Flags ] );
    }
}

public ev_death_msg( ) 
{
    new id = read_data(1)
    new victim = read_data(2)
    new iFlags;
    
    if(!is_user_alive(id) || id == victim) 
        return
    
    iFlags = get_user_flags( id );
    
    for ( new BenefitsLevels:blIndex = Level1 ; blIndex < BenefitsLevels ; blIndex++ )
    {
        if ( ( iFlags & BenefitsData[ blIndex ][ FlagBits ] ) == BenefitsData[ blIndex ][ FlagBits ] ) 
        {
            if ( BenefitsData[ blIndex ][ Money ] )
                cs_set_user_money( id , cs_get_user_money( id ) + BenefitsData[ blIndex ][ Money ] )
                
            if ( BenefitsData[ blIndex ][ Health ] )    
                set_user_health( id , get_user_health( id ) + BenefitsData[ blIndex ][ Health ] )
                
            if ( BenefitsData[ blIndex ][ Armor ] )    
                set_user_armor( id , get_user_armor( id ) + BenefitsData[ blIndex ][ Armor ] )
                
            break;
        }
    }    
} 


[NooTy]

Originally Posted by OciXCrom Because "get_user_flags & flag" checks if the user has AT LEAST ONE of the specified admin flags. Check the "has_all_flags" function from "amxmisc".

like this : if(has_all_flags((Attacker) , "abcdefghijklmnopqrsux")) ??

Thank You All For Help

[Bugsy]

Yes .. use this to lookup anything: http://www.amxmodx.org/api/

I recommend using the new code I wrote.

[NooTy]

Thank You bro

[NooTy]

You joined in 2005 ? I borned in 2005 xD