[VEN]

Is there a way to use this function for removing a defusekit from a player?

No, because this method is used to clear item(s) in player's item slots but defkit/nvgs is only indicated in player's pvPrivateData.

[ConnorMcLeod]

Here is my strip version :

Pass the CSW_xxx id instead of weapon name.
Pass the weapon slot if you know it.

Needed offsets are here : http://forums.alliedmods.net/showpos...01#post1712101

PHP Code:

stock ham_strip_user_weapon(id, iCswId, iSlot = 0, bool:bSwitchIfActive = true)
{
    new iWeapon;
    if( !iSlot )
    {
        static const iWeaponsSlots[] = {
            -1,
            2, //CSW_P228
            -1,
            1, //CSW_SCOUT
            4, //CSW_HEGRENADE
            1, //CSW_XM1014
            5, //CSW_C4
            1, //CSW_MAC10
            1, //CSW_AUG
            4, //CSW_SMOKEGRENADE
            2, //CSW_ELITE
            2, //CSW_FIVESEVEN
            1, //CSW_UMP45
            1, //CSW_SG550
            1, //CSW_GALIL
            1, //CSW_FAMAS
            2, //CSW_USP
            2, //CSW_GLOCK18
            1, //CSW_AWP
            1, //CSW_MP5NAVY
            1, //CSW_M249
            1, //CSW_M3
            1, //CSW_M4A1
            1, //CSW_TMP
            1, //CSW_G3SG1
            4, //CSW_FLASHBANG
            2, //CSW_DEAGLE
            1, //CSW_SG552
            1, //CSW_AK47
            3, //CSW_KNIFE
            1 //CSW_P90
        }
        iSlot = iWeaponsSlots[iCswId];
    }

    iWeapon = get_pdata_cbase(id, m_rgpPlayerItems_CBasePlayer[iSlot]);

    while( iWeapon > 0 )
    {
        if( get_pdata_int(iWeapon, m_iId, XO_CBASEPLAYERITEM) == iCswId )
        {
            break;
        }
        iWeapon = get_pdata_cbase(iWeapon, m_pNext, XO_CBASEPLAYERITEM);
    }

    if( iWeapon > 0 )
    {
        if( bSwitchIfActive && get_pdata_cbase(id, m_pActiveItem) == iWeapon )
        {
            ExecuteHamB(Ham_Weapon_RetireWeapon, iWeapon);
        }

        if( ExecuteHamB(Ham_RemovePlayerItem, id, iWeapon) )
        {
            user_has_weapon(id, iCswId, 0);
            ExecuteHamB(Ham_Item_Kill, iWeapon);
            return 1;
        }
    }

    return 0;
} 


[Arkshine]

You should explain what is the difference.

[ConnorMcLeod]

You pass weapon type instead of weapon name.
It checks directly in player slots instead of check all weapons and check owner.
The owner check in avanlanche stock is made module side so it shouldn't be a big difference between the 2 ways, and also, such a native shouldn't be often called.
Also, as on cs, player have only 1 weapon per slot (except with specific plugins), the method should be efficient.
Last difference is the use of user_has_weapon instead of pev_weapons that is more efficient, but again, this is trivial.

[FiFiX]

Have some trouble here.

L 06/19/2011 - 18:04:23: [AMXX] Run time error 3: stack error 
L 06/19/2011 - 18:04:23: [AMXX]    [0] bajery.inc::ham_strip_weapon (line 32)
L 06/19/2011 - 18:04:23: [AMXX]    [1] RR_Classic.sma::current_weapon (line 71)

This is CurWeapon:

public current_weapon(id)
{
    if(r_counter>2) 
        return PLUGIN_HANDLED;
        
    new weapon = get_user_weapon(id)
        
    if (weapon == CSW_HEGRENADE || weapon == CSW_SMOKEGRENADE || weapon == CSW_FLASHBANG )
        client_cmd(id, "lastinv");
        
    if (weapon == CSW_C4)
    {
        new gmsgStatusIcon = get_user_msgid("StatusIcon");
        
        ham_strip_weapon(id,"weapon_c4");
        message_begin(MSG_ONE,gmsgStatusIcon,_,id);
        write_byte(0);
        write_string("c4");
        message_end();
    }
    
    return PLUGIN_CONTINUE;
}

And line bajery.inc is a file which contains only functions from 1st post and line 32 is:

if(get_user_weapon(id) == wId) ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);

Any ideas why?

[MeRcyLeZZ]

Originally Posted by FiFiX Have some trouble here. L 06/19/2011 - 18:04:23: [AMXX] Run time error 3: stack error L 06/19/2011 - 18:04:23: [AMXX] [0] bajery.inc::ham_strip_weapon (line 32) L 06/19/2011 - 18:04:23: [AMXX] [1] RR_Classic.sma::current_weapon (line 71) This is CurWeapon: public current_weapon(id) {     (...)     if (weapon == CSW_C4)     {         new gmsgStatusIcon = get_user_msgid("StatusIcon");                 ham_strip_weapon(id,"weapon_c4");                 (...)     }         return PLUGIN_CONTINUE; } Any ideas why?

Yeah, ham_strip_weapon(id,"weapon_c4") triggers an engine message. However, if a message gets sent during AMXX's message forward, it causes re-entrancy/recursion issues like that. (https://bugs.alliedmods.net/show_bug.cgi?id=3664)

[FiFiX]

So if I'll make something like:

if(!g_bombremove)
{
       ham_strip_weapon(id,"weapon_c4");
       g_bombremove = true;
}

it will slove that problem? Anyway is there another way to remove c4 ?

[MeRcyLeZZ]

Originally Posted by FiFiX So if I'll make something like: if(!g_bombremove) { ham_strip_weapon(id,"weapon_c4"); g_bombremove = true; } it will slove that problem? Anyway is there another way to remove c4 ?

You can still use CurWeapon event, just set a task to call ham_strip_weapon, like

    /* CurWeapon event */
    set_task(0.1, "remove_c4", id)

public remove_c4(id)
{
    if (!is_user_alive(id)) return;
    ham_strip_weapon(id, "weapon_c4")
}

I know it's not pretty, but it shold get rid of "Run time error 3: stack error".

[Exolent[jNr]]

If you want to not let player have a C4, you can do a few things:
1. Hook Ham_Item_Deploy and remove there.
2. Hook Ham_AddPlayerItem and remove entity (?) and supercede the forward.

[FiFiX]

For Ham_Item_Deploy hook would be:
RegisterHam(Ham_Item_Deploy, "weapon_c4", "weapon_c4", 1)
And how to remove it then?