[Dragokas]

L 03/18/2018 - 187:14: [SM] Native "GetEntProp" reported: Property "m_humanSpectatorUserID" not found (entity 3/player) L 03/18/2018 - 187:14: [SM] Displaying call stack trace for plugin "MuLS.smx": L 03/18/2018 - 187:14: [SM] [0] Line 823, plugin.sp::IsClientIdle() L 03/18/2018 - 187:14: [SM] [1] Line 205, plugin.sp::evtPlayerActivate()

public bool HasIdlePlayer(int bot)
{
	if(!IsFakeClient(bot))
		return false
	
	if(IsClientConnected(bot) && IsClientInGame(bot))
	{
		if((GetClientTeam(bot) == TEAM_SURVIVORS) && IsAlive(bot))
		{
			if(IsFakeClient(bot))
			{
				int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID"))			
				if(client)
				{
					if(!IsFakeClient(client) && (GetClientTeam(client) == TEAM_SPECTATORS))
						return true
				}
			}
		}
	}
	return false
}

Why he is thinking client entity has no such property after all validations are passed?

Thanks.

[Indarello]

Like music dont have property color
This entity dont have this property

[Silvers]

PHP Code:

stock bool:HasSpectator(client)
{
    decl String:sNetClass[12];
    GetEntityNetClass(client, sNetClass, sizeof(sNetClass));

    if( strcmp(sNetClass, "SurvivorBot") == 0 )
    {
        if( !GetEntProp(client, Prop_Send, "m_humanSpectatorUserID") )
            return false;
    }
    return true;
} 


SurvivorBot - survivor_bot
The only entity with: m_humanSpectatorUserID

https://wiki.alliedmods.net/Entity_p...ceMod_Commands
"sm_dump_netprops netprops.txt"
"sm_dump_datamaps datamaps.txt"

[Dragokas]

Indarello, understood.

Silvers, thank you for example of property class determination.
I'll certainly examine the list of properties.

[Psyk0tik]

This is what I have, maybe you can find it useful for something:

PHP Code:

bool bHasIdlePlayer(int client)
{
    int iIdler = GetClientOfUserId(GetEntData(client, FindSendPropInfo("SurvivorBot", "m_humanSpectatorUserID")));
    if (iIdler)
    {
        if (IsClientInGame(iIdler) && !IsFakeClient(iIdler) && (GetClientTeam(iIdler) != 2))
        {
            return true;
        }
    }

    return false;
}

bool bIsPlayerIdle(int client)
{
    for (int iPlayer = 1; iPlayer <= MaxClients; iPlayer++)
    {
        if (!IsClientConnected(iPlayer) || !IsClientInGame(iPlayer) || GetClientTeam(iPlayer) != 2 || !IsFakeClient(iPlayer) || !bHasIdlePlayer(iPlayer))
        {
            continue;
        }

        int iIdler = GetClientOfUserId(GetEntData(iPlayer, FindSendPropInfo("SurvivorBot", "m_humanSpectatorUserID")));
        if (iIdler == client)
        {
            return true;
        }
    }

    return false;
}

bool bIsHumanSurvivor(int client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2 && IsPlayerAlive(client) && !IsClientInKickQueue(client) && !IsFakeClient(client) && !bHasIdlePlayer(client) && !bIsPlayerIdle(client));
} 


[MasterMind420]

Originally Posted by Dragokas public bool HasIdlePlayer(int bot) { if(!IsFakeClient(bot)) return false if(IsClientConnected(bot) && IsClientInGame(bot)) { if((GetClientTeam(bot) == TEAM_SURVIVORS) && IsAlive(bot)) { if(IsFakeClient(bot)) { int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID")) if(client) { if(!IsFakeClient(client) && (GetClientTeam(client) == TEAM_SPECTATORS)) return true } } } } return false } Why he is thinking client entity has no such property after all validations are passed? Thanks.

This should suffice...however it will only get actual afk players, not spectators...use crashers for idle and spectate.

public bool HasIdlePlayer(int bot)
{
	if(bot > 0 && bot <= MaxClients && IsClientInGame(bot) && GetClientTeam(bot) == 2)
	{
		if (HasEntProp(bot, Prop_Send, "m_humanSpectatorUserID")) //Seeings how survivor bots are the only ones with this netprop, clients will fail this check
		{
			int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID"));

			if(client > 0 && client <= MaxClients && IsClientInGame(client) && IsClientObserver(client))
			{
				//PrintToChatAll("%N HasIdlePlayer", bot);
				return true;
			}

			//PrintToChatAll("%N !HasIdlePlayer", bot);
		}
	}

	return false;
}