[Psyk0tik]

I need help with this:

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdkhooks>
#define PLUGIN_VERSION "1.0"

public Plugin:myinfo =
{
    name = "[L4D & L4D2] No Friendly Fire",
    author = "Psykotik",
    description = "Disables friendly fire.",
    version = PLUGIN_VERSION,
    url = "www.sourcemod.net"
}

new Handle:pFF;
new Handle:pFFF;

public OnPluginStart()
{
    CreateConVar("l4d_friendlyfire_version", PLUGIN_VERSION, "Plugin version");
    pFF = CreateConVar("l4d_friendlyfire", "0", "Enable friendly fire? 0 = Off, 1 = On");
    pFFF = CreateConVar("l4d_friendlyfire_from_fire", "0", "Enable friendly fire from fire sources? 0 = Off, 1 = On");
    AutoExecConfig(true, "l4d_nofriendlyfire");
}

public OnClientPostAdminCheck(client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public OnClientDisconnect(client)
{
    if (client > 0 && IsClientInGame(client)) SDKUnhook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action:OnTakeDamage(victim, &attacker, &inflictor, &Float:damage, &damagetype)
{
    if (victim > 0 && attacker > 0 && GetClientTeam(attacker) == 2 && GetClientTeam(victim) == 2)
    {
        if (GetConVarInt(pFF) == 0 || GetConVarInt(pFFF) == 0 && (damagetype == 8 || damagetype == 2056 || damagetype == 268435464))
        {
            damage = 0.0;
            return Plugin_Changed;
        }
    }

    return Plugin_Continue;
} 


It functions as intended but I get these errors in my logs whenever I throw a molotov on the ground around the survivor bots:

Spoiler

L 10/07/2017 - 06:27:50: SourceMod error session started
L 10/07/2017 - 06:27:50: Info (map "l4d_hospital01_apartment") (file "errors_20171007.log")
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 221 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 389 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 420 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 420 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 221 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 389 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 435 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 389 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 420 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage
L 10/07/2017 - 06:27:50: [SM] Exception reported: Client index 221 is invalid
L 10/07/2017 - 06:27:50: [SM] Blaming: l4d_nofriendlyfire.smx
L 10/07/2017 - 06:27:50: [SM] Call stack trace:
L 10/07/2017 - 06:27:50: [SM]   [0] GetClientTeam
L 10/07/2017 - 06:27:50: [SM]   [1] Line 38, C:\Program Files (x86)\Steam\steamapps\common\left 4 dead\left4dead\addons\sourcemod\scripting\l4d_nofriendlyfire.sp::OnTakeDamage

I don't know if I would get the same errors if I throw a molotov at other human players though.

[xerox8521]

You need to check if the attacker is valid. You can use this function:

PHP Code:

stock bool IsValidClient(int client)
{
    return (1 <= client <= MaxClients && IsClientInGame(client));
} 


[Psyk0tik]

Originally Posted by xerox8521 You need to check if the attacker is valid. You can use this function: PHP Code: stock bool IsValidClient(int client) {     return (1 <= client <= MaxClients && IsClientInGame(client)); }

Thank you.

And would I need to add anything else to the code? You said to check if the attacker is valid, so would I need to add something else besides the function you provided?

EDIT: I tried this but I still get errors.

PHP Code:

#pragma semicolon 1 
#include <sourcemod> 
#include <sdkhooks> 
#define PLUGIN_VERSION "1.0" 

public Plugin:myinfo = 
{ 
    name = "[L4D & L4D2] No Friendly Fire", 
    author = "Psykotik", 
    description = "Disables friendly fire.", 
    version = PLUGIN_VERSION, 
    url = "www.sourcemod.net" 
} 

new Handle:pFF; 
new Handle:pFFF; 

public OnPluginStart() 
{ 
    CreateConVar("l4d_friendlyfire_version", PLUGIN_VERSION, "Plugin version"); 
    pFF = CreateConVar("l4d_friendlyfire", "0", "Enable friendly fire? 0 = Off, 1 = On"); 
    pFFF = CreateConVar("l4d_friendlyfire_from_fire", "0", "Enable friendly fire from fire sources? 0 = Off, 1 = On"); 
    AutoExecConfig(true, "l4d_nofriendlyfire"); 
} 

public OnClientPostAdminCheck(client) 
{ 
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
} 

public OnClientDisconnect(client) 
{ 
    if (client > 0 && IsClientInGame(client)) SDKUnhook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
} 

stock bool IsValidClient(int client) 
{ 
    return (1 <= client <= MaxClients && IsClientInGame(client)); 
}

public Action:OnTakeDamage(victim, &attacker, &inflictor, &Float:damage, &damagetype) 
{ 
    if (IsValidClient(attacker) && IsValidClient(victim) && victim > 0 && attacker > 0 && GetClientTeam(attacker) == 2 && GetClientTeam(victim) == 2) 
    { 
        if (GetConVarInt(pFF) == 0 || GetConVarInt(pFFF) == 0 && (damagetype == 8 || damagetype == 2056 || damagetype == 268435464)) 
        { 
            damage = 0.0; 
            return Plugin_Changed; 
        } 
    } 

    return Plugin_Continue; 
} 


[cravenge]

Edit: Fixed the lines producing the compilation errors.

PHP Code:

#pragma semicolon 1 
#include <sourcemod> 
#include <sdkhooks> 

#define PLUGIN_VERSION "1.0" 

public Plugin myinfo = 
{ 
    name = "[L4D & L4D2] No Friendly Fire", 
    author = "Psykotik", 
    description = "Disables friendly fire.", 
    version = PLUGIN_VERSION, 
    url = "www.sourcemod.net" 
};

ConVar pFF, pFFF;

public void OnPluginStart()
{
    CreateConVar("l4d_friendlyfire_version", PLUGIN_VERSION, "Version of the plugin.");
    pFF = CreateConVar("l4d_friendlyfire", "0", "Friendly Fire status: 0 = Disabled, 1 = Enabled");
    pFFF = CreateConVar("l4d_friendlyfire_from_fire", "0", "Friendly Fire status from fire sources: 0 = Disabled, 1 = Enabled");
    
    AutoExecConfig(true, "l4d_nofriendlyfire");
}

public void OnClientPostAdminCheck(int client) 
{ 
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
} 

public void OnClientDisconnect(int client) 
{ 
    SDKUnhook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3]) 
{ 
    if (!IsSurvivor(victim) || !IsSurvivor(attacker))
    {
        return Plugin_Continue;
    }
    
    if (!pFF.BoolValue || (!pFFF.BoolValue && (damagetype == 8 || damagetype == 2056 || damagetype == 268435464)))
    {
        damage = 0.0;
        return Plugin_Changed;
    }
    
    return Plugin_Continue;
}

stock bool IsSurvivor(int client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2);
} 


[Psyk0tik]

Originally Posted by cravenge Okay, I've fixed it and applied the new syntax. PHP Code: #pragma semicolon 1  #include <sourcemod>  #include <sdkhooks>  #define PLUGIN_VERSION "1.0"  public Plugin myinfo =  {      name = "[L4D & L4D2] No Friendly Fire",      author = "Psykotik",      description = "Disables friendly fire.",      version = PLUGIN_VERSION,      url = "www.sourcemod.net"  }; ConVar pFF, pFFF; public void OnPluginStart() {     CreateConVar("l4d_friendlyfire_version", PLUGIN_VERSION, "Version of the plugin.");     pFF = CreateConVar("l4d_friendlyfire", "0", "Friendly Fire status: 0 = Disabled, 1 = Enabled");     pFFF = CreateConVar("l4d_friendlyfire_from_fire", "0", "Friendly Fire status from fire sources: 0 = Disabled, 1 = Enabled");          AutoExecConfig(true, "l4d_nofriendlyfire"); } public void OnClientPostAdminCheck(int client)  {      SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);  }  public void OnClientDisconnect(int client)  {      SDKUnhook(client, SDKHook_OnTakeDamage, OnTakeDamage);  } public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, float damageForce[3], float damagePosition[3])  {      if (!IsSurvivor(victim) || !IsSurvivor(attacker))     {         return Plugin_Continue;     }          if (!pFF.BoolValue || (!pFFF.BoolValue && (damagetype == 8 || damagetype == 2056 || damagetype == 268435464)))     {         damage = 0.0;         return Plugin_Changed;     }          return Plugin_Continue; } stock bool IsSurvivor(int client) {     return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2); }

I tried your fix and now it's failing to compile. The compiler is saying that there's an "error 100: function prototypes do not match" on lines 29 and 34.

[cravenge]

No worries, check my post again. I've changed it.

[Psyk0tik]

Originally Posted by cravenge No worries, check my post again. I've changed it.

Thank you so much cravenge! No more errors whatsoever!

+