[Celena Luna]

Is there a better way to optimize this?

PHP Code:

new WeaponList_Pistol_CT[][] = { "weapon_deagle", "weapon_fiveseven", "weapon_fiveseven", "weapon_fiveseven" }
new WeaponList_SMG_SG_CT[][] = { "weapon_tmp", "weapon_ump45", "weapon_m3"}
new WeaponList_SMG_SG2_CT[][] = { "weapon_mp5navy", "weapon_p90", "weapon_xm1014"}
new WeaponList_Rfile_CT[][] = { "weapon_famas", "weapon_scout", "weapon_famas", "weapon_famas"}
new WeaponList_Rifle2_CT[][] = { "weapon_m4a1", "weapon_aug", "weapon_famas"}
new WeaponList_Random_CT[][] = { "weapon_m4a1", "weapon_aug", "weapon_famas", "weapon_mp5navy", "weapon_p90"}

new WeaponList_Pistol_TS[][] = { "weapon_deagle", "weapon_elite", "weapon_elite", "weapon_elite" }
new WeaponList_SMG_SG_TS[][] = { "weapon_mac10", "weapon_ump45", "weapon_m3"}
new WeaponList_SMG_SG2_TS[][] = { "weapon_mp5navy", "weapon_p90", "weapon_xm1014"}
new WeaponList_Rfile_TS[][] = { "weapon_galil", "weapon_scout"}
new WeaponList_Rifle2_TS[][] = { "weapon_ak47", "weapon_sg552", "weapon_galil"}
new WeaponList_Random_TS[][] = { "weapon_ak47", "weapon_sg552", "weapon_mp5navy", "weapon_p90", "weapon_galil"} 


[fysiks]

Optimize it in what sense? Context matters (i.e. it matters on how you're using it). It's likely good enough. I think there are enumerations for weapons which you could use instead, that would use less memory. Then you can look up the string only when needed as a string. But again, it depends on how you are using these arrays.

[Celena Luna]

I plan on randomizing weapon in the array and give it depend on round.
I just questioning if is there any way to do it look "cleaner"

I tried as

PHP Code:

new WeaponListCT[][] = {
    { "weapon_deagle", "weapon_fiveseven" },
    { "weapon_mp5navy", "weapon_p90", "weapon_xm1014"}
} 


but it keep getting error

[+ARUKARI-]

PHP Code:

enum _:WEAPON_LISTS
{
    PISTOLS,
    SMG_SG_1,
    SMG_SG_2,
    RIFLE_1,
    RIFLE_2,
    RANDOM,
};
WeaponListCT[WEAPON_LISTS][][] =
{
    { "weapon_deagle", "weapon_fiveseven", "" },                // PISTOLS
    { "weapon_mp5navy", "weapon_p90", "weapon_xm1014"},        // SMG_SG_1
    //...
}; 


It is a 3-dimensional array and the number of items must match or an error will occur.

[Celena Luna]

That was what I tried to used but then I got

error 052: multi-dimensional arrays must be fully initialized

so I have to split it into smaller array.
When randomize with sizeof, it will also random into the blank one

[Napoleon_be]

I made this a while ago, it might be helpful for you.

PHP Code:

/* Credits to
    ConnorMcLeod:
        - I got the Free For All code from his plugin: https://forums.alliedmods.net/showthread.php?t=80208
    Bugsy:
        - Helping me figure out how to set model to the player if the weapon can be bought by both teams.
        - I still need to work on blocking weapon pickup to avoid bugs.
*/

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fun>

#pragma semicolon 1

#define PLUGIN "FFA: WeaponBased PlayerModels"
#define VERSION "1.0.0"
#define AUTHOR "NapoleoN#"

enum _:ModelsInfo
{
    szModelName[32],
    iWeaponID,
    CsTeams:csTeams
}

new const szWeapons[][ModelsInfo] =
{
    { "wbknife", CSW_KNIFE , CS_TEAM_UNASSIGNED },             // Knife
    { "wbawp", CSW_AWP , CS_TEAM_UNASSIGNED },            // AWP
    { "wbfamas", CSW_FAMAS, CS_TEAM_CT },                 // Famas
    { "wbm4a1", CSW_M4A1, CS_TEAM_CT },                    // M4A1
    { "wbak47", CSW_AK47, CS_TEAM_T },                     // AK47
    { "wbgalil", CSW_GALIL, CS_TEAM_T },                     // Galil
    { "wbtmp", CSW_TMP, CS_TEAM_CT },                     // TMP
    { "wbump45", CSW_UMP45 , CS_TEAM_UNASSIGNED},             // Ump45
    { "wbscout", CSW_SCOUT , CS_TEAM_UNASSIGNED},             // Scout
    { "wbxm1014", CSW_XM1014 , CS_TEAM_UNASSIGNED},            // XM1014
    { "wbaug", CSW_AUG, CS_TEAM_CT },                    // AUG
    { "wbsg550", CSW_SG550, CS_TEAM_CT },                // SG550
    { "wbmp5navy", CSW_MP5NAVY , CS_TEAM_UNASSIGNED},            // MP5 Navy
    { "wbm249", CSW_M249 , CS_TEAM_UNASSIGNED},                 // M249
    { "wbm3", CSW_M3 , CS_TEAM_UNASSIGNED},                // M3
    { "wbg3sg1", CSW_G3SG1, CS_TEAM_T },                    // G3SG1
    { "wbsg552", CSW_SG552, CS_TEAM_T }                     // SG552
};

new iMsgRadar;
new iMaxPlayers;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);

    register_event("CurWeapon", "CheckWeapons", "be", "1=1");

    RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage");
    RegisterHam(Ham_TraceAttack, "player", "TraceAttack");

    iMsgRadar = get_user_msgid("Radar");
    register_message(iMsgRadar, "RadarMessage");

    server_cmd("mp_friendlyfire 1");

    iMaxPlayers = get_maxplayers();
}

precache_player_model(szModel[])
{
    static szFile[128];
    formatex(szFile, charsmax(szFile), "models/player/%s/%s.mdl", szModel, szModel);
    precache_model(szFile);
    replace(szFile, charsmax(szFile), ".mdl", "T.mdl");

    if(file_exists(szFile))
    {
        precache_model(szFile);
    }
}

public plugin_precache()
{
    for(new i; i < sizeof(szWeapons); i++)
    {
        precache_player_model(szWeapons[i][szModelName]);
    }
}

public client_putinserver(id)
{
    client_cmd(id, "hideradar");
}

public RadarMessage(iMsgID, MsgDest, id)
{
    return PLUGIN_HANDLED;
}

public CheckWeapons(id)
{
    new iUserWeapon = get_user_weapon(id);
    new CsTeams:csTeam = cs_get_user_team(id);

    for (new i; i < sizeof(szWeapons) ; i++)
    {
        if (iUserWeapon == szWeapons[i][iWeaponID])
        {
            if((szWeapons[i][csTeams] == CS_TEAM_UNASSIGNED) || (csTeam == szWeapons[i][csTeams]))
            {
                cs_set_user_model(id , szWeapons[i][szModelName]);
            }
            else
            {
                cs_reset_user_model(id);
            }

            break;
        }
    }
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, DamageBits)
{
    if(iVictim != iAttacker && (1 <= iAttacker <= iMaxPlayers))
    {
        new CsTeams:csVictimTeam = cs_get_user_team(iVictim);
        if(csVictimTeam == cs_get_user_team(iAttacker))
        {
            cs_set_user_team(iVictim, csVictimTeam == CS_TEAM_T ? CS_TEAM_CT : CS_TEAM_T);
            ExecuteHamB(Ham_TakeDamage, iVictim, iInflictor, iAttacker, fDamage, DamageBits);
            cs_set_user_team(iVictim, csVictimTeam);
            return HAM_SUPERCEDE;
        }
    }
    return HAM_IGNORED;
}

public TraceAttack(iVictim, iAttacker, Float:fDamage, Float:fDirection[3], TraceHandle, DamageBits)
{
    if( iVictim != iAttacker && (1 <= iAttacker <= iMaxPlayers))
    {
        new CsTeams:csVictimTeam = cs_get_user_team(iVictim);
        if(csVictimTeam == cs_get_user_team(iAttacker))
        {
            cs_set_user_team(iVictim, csVictimTeam == CS_TEAM_T ? CS_TEAM_CT : CS_TEAM_T);
            ExecuteHamB(Ham_TraceAttack, iVictim, iAttacker, fDamage, fDirection, TraceHandle, DamageBits);
            cs_set_user_team(iVictim, csVictimTeam);
            return HAM_SUPERCEDE;
        }
    }
    return HAM_IGNORED;
} 


[Natsheh]

add const to the array when initializing.

for example

PHP Code:

static const array[][] = { "Hello this will never change", ":)" } 


this is slightly better but if you're using alot of plugins which have alot of constant arrays it will make a difference.

and use static for file scope only.


also if you want just to save weapons you can use the weapon id rather than using its name, and use get_weaponname to get the weapon name if needed.

[Bugsy]

I think Napoleon_be's approach would be the cleanest if this works. How do you need to reference this data for each weapon within your code? We can most likely make it work by building a small function/macro to make it work either way.

[Napoleon_be]

I might aswell just share the entire code. Previous post has been updated.

Take in mind this is just to show you an example of how i did something simular to what you need. The free for all part hasn't been tested and the code still needs a "weapon pickup blocker".

Also the free for all part needs a better integration as i could use my array instead of creating a new variable localy.

[Celena Luna]

Originally Posted by Natsheh add const to the array when initializing. for example PHP Code: static const array[][] = { "Hello this will never change", ":)" }  this is slightly better but if you're using alot of plugins which have alot of constant arrays it will make a difference. and use static for file scope only. also if you want just to save weapons you can use the weapon id rather than using its name, and use get_weaponname to get the weapon name if needed.

I actually forgot about get_weaponname can be use here. If only 2-dimension array then it might better.

Originally Posted by Napoleon_be I might aswell just share the entire code. Previous post has been updated. Take in mind this is just to show you an example of how i did something simular to what you need. The free for all part hasn't been tested and the code still needs a "weapon pickup blocker". Also the free for all part needs a better integration as i could use my array instead of creating a new variable localy.

Originally Posted by Bugsy I think Napoleon_be's approach would be the cleanest if this works. How do you need to reference this data for each weapon within your code? We can most likely make it work by building a small function/macro to make it work either way.

My base ideas is just make a multi-dimensional array for a set of weapon for each team each round but because number of weapon each round is different so some round will have "blank" weapon.
I can just fill it with random previous weapon in that set but it look kind of a mess.

@Napoleon_be thanks, I will try it