[Floody]

Hey there,
is there anyone out there who has a code which blocks a player who used a command. For example: xy use !test and cannot pick up any weapon for 30 seconds.

Honestly, I have no clue how I could do this. I thought about SDKHooks, but I have no idea how I should write this code.

I would be pleased if you would give me an ex

Thanks in advance!
Greetz

[ecca]

Should block weapon pickup , can be wrong try it out.

PHP Code:

#include <sdkhooks>

new bool:IsBlocked[MAXPLAYERS+1] = false;

public OnPluginStart()
{
    RegConsoleCmd("sm_test", BlockPickupCommand);
}

public Action:BlockPickupCommand(client, args)
{
    IsBlocked[client] = true;
    CreateTimer(30.0, UnblockClient, _, client);
}

public Action:UnblockClient(Handle:timer, any:client)
{
    if(IsClientInGame(client))
        IsBlocked[client] = false;
}

public OnClientPutInServer(client)  
{  
    SDKHook(client, SDKHook_WeaponCanUse, OnWeaponThingy);
}

public OnClientDisconnect(client)  
{  
    if(IsClientInGame(client))  
    {  
        SDKUnhook(client, SDKHook_WeaponCanUse, OnWeaponThingy);
        IsBlocked[client] = false;
    }
}  

public Action:OnWeaponThingy(client, weapon)  
{
    if(IsBlocked[client])
        return Plugin_Handled;  
    
    return Plugin_Continue;
} 


[Floody]

Nice! It blocks the weapon perfectly, but the timer won't stop. I added this ex to my code, but my timer just won't stop. You have an idea why?

[floube]

Just add return Plugin_Stop in the timer callback.

PHP Code:

public Action:UnblockClient(Handle:timer, any:client)
{
    if(IsClientInGame(client))
        IsBlocked[client] = false;

    return Plugin_Stop;
} 


[TnTSCS]

You are creating the timer incorrectly... the any:data goes in the third argument (native Handle:CreateTimer(Float:interval, Timer:func, any:data=INVALID_HANDLE, flags=0);), not the fourth... And, when passing client data in timers, use userId or serial... Also, return plugin_handled in command callback, otherwise you get unknown command in player's console

fixed example

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdkhooks>

public OnPluginStart()
{
    RegConsoleCmd("sm_test", BlockPickupCommand);
}

public Action:BlockPickupCommand(client, args)
{
    SDKHook(client, SDKHook_WeaponCanUse, OnWeaponThingy);
    CreateTimer(30.0, UnblockClient, GetClientSerial(client));
    
    return Plugin_Handled;
}

public Action:UnblockClient(Handle:timer, any:serial)
{
    new client = GetClientFromSerial(serial);
    
    if (client != 0)
    {
        SDKUnhook(client, SDKHook_WeaponCanUse, OnWeaponThingy);
    }
}

public OnClientDisconnect(client)  
{  
    if (IsClientInGame(client))  
    {  
        SDKUnhook(client, SDKHook_WeaponCanUse, OnWeaponThingy);
    }
}  

public Action:OnWeaponThingy(client, weapon)  
{
    return Plugin_Handled;
} 


[Floody]

TnTSCS, your ex works like a charm! Thank you!