[ecca]

Good evening.

So basically i'm trying todo a simple check if a players name contains other chars then what i want to , i tried doing as i'm doing in PHP but it seems like it doesnt work.

PHP Code:

new Handle:regeex = INVALID_HANDLE;

public OnPluginStart()
{
    RegConsoleCmd("say", Command_SayChat);
    RegConsoleCmd("say_team", Command_SayChat);
    
    regeex = CompileRegex("/^[a-zA-Z0-9]+$/");
}

public Action:Command_SayChat(client, args)
{    
        decl String:text[192];
        GetCmdArgString(text, sizeof(text));
        if (MatchRegex(regeex, text) > 0) {                        
            LogAction(client, -1, "char was blocked");
            return Plugin_Handled;                
        }            
    return Plugin_Continue;    
} 


Edit: The matching text is just for testing purposes to easier try it out , the function will be against names later!

[Bacardi]

Ok, if you are using chat messages to compare with regex, remember you get "quotes" when type message in game chat panel.

some bad tutorial
Try Regex

anyway... try this and don't include slashes

PHP Code:

// Same as = /[^\w -.]/
// Matching any character, expect [A-Za-z0-9_], space, dot, stroce

"[^\\w -.]" 


some test, don't rely 100%

PHP Code:

#include <regex>
new Handle:regex;

public OnPluginStart()
{
    new RegexError:errcode, String:error[256];

    //new String:pattern[] = "^[\\w .-]+$";
    new String:pattern[] = "[^\\w -.]";
    PrintToServer("my regex pattern /%s/", pattern);

    regex = CompileRegex(pattern, 0, error, sizeof(error), errcode);

    if(regex == INVALID_HANDLE || errcode != REGEX_ERROR_NONE)
    {
        PrintToServer("CompileRegex error code %i error %s", errcode, error);
    }
}

myregex(const String:input[])
{
    if(regex == INVALID_HANDLE)
    {
        return;
    }

    PrintToServer("\n%5s myregex input[%s]", "", input);

    new substrings, String:substr[256];
    new skip, RegexError:errcode, tmp;

    do
    {
        substrings = MatchRegex(regex, input[skip], errcode);

        if(errcode != REGEX_ERROR_NONE)
        {
            PrintToServer("MatchRegex ERROR code %i", errcode);
            break;
        }

        if( substrings > 0 && GetRegexSubString(regex, 0, substr, sizeof(substr)) )
        {
            PrintToServer("\n%5s Input text place [%i]", "", skip);

            skip += StrContains(input[skip], substr);

            PrintToServer("%5s Found matching pattern [%s] place [%i]", "", substr, skip);

            tmp = strlen(substr);

            skip += tmp == 0 ? 1:tmp; // There where somekind whitespace ?

            // You get substrings when add () subexpressions, "(\\w+) (\\w+)"
            for(new a = 1; a < substrings; a++)
            {
                if(GetRegexSubString(regex, a, substr, sizeof(substr)))
                {
                    PrintToServer("%5s substring %i/%i , %s", "", a, substrings-1, substr);
                }
            }
        }

    }
    while( substrings > 0 )
    {
        PrintToServer("- the end\n");
    }

}

public Action:OnClientSayCommand(client, const String:command[], const String:sArgs[])
{
    new String:buffer[256];
    strcopy(buffer, sizeof(buffer), sArgs);

    PrintToServer("\nOriginal = %s", buffer);

    // Ok, if we are checking chat messages, remove start/end "quotes" from text. We get most regex patterns work.
    new start = 0;

    if(buffer[start] == '"')
    {
        start = strlen(buffer);
        if(buffer[start - 1] == '"')
        {
            buffer[start - 1] = '\0';
            start = 1;
        }
        else
        {
            start = 0;
        }
    }

    myregex(buffer[start]);
    //myregex("0Zero0\n15avigil - 1 Vote\n447u\n~sound~wave~ - 1 Vote\nA\n\"AirFusion\"\nAmazingHuh\naranamor\natomic7732\nAwesomus Maximus\nB\nBillybobjoepants\nBioShock_Rules\nBlanzer\nBob-Omb - 1 Vote\nbosky2102\nBrendan170\nbroswen\nBtrpo\nbubbyboytoo\nC\nCandyRaid - 3 Votes\nCarmelpoptart\nc@tlover2011\ncejj99\n\nChan14551\nChowderBowl\n");
}