[maqi]

You can't store weapons info in global variables like that, if a another player dies before the first one respawned, everything is messed up, both would get the number of weapons of the second one but actually weapons of the first one ( while there is enough ).
Also that quote i sent earlier get_user_weapons expects the num variable to be set to 0 beforehand to work properly.

This is how I would do it, it works of course.

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fun>

#pragma semicolon 1

#define MAX_PLAYERS 32

enum WeaponsData
{
    WEAPONS[32],
    NUM
}

new g_eWeapons[ MAX_PLAYERS + 1 ][WeaponsData];

public plugin_init( ) 
{
    register_plugin( "Save Weapons On Death", "1.0a", "maqi" );
    
    RegisterHam( Ham_Killed, "player", "Event_HamKilledPre", 0 );
    RegisterHam( Ham_Spawn, "player", "Event_PlayerSpawnPost", 1 );
}

public client_connect( iIndex )
    g_eWeapons[iIndex][NUM] = 0;

public Event_HamKilledPre( iIndex )
{
    new iWeapons[32];
    
    get_user_weapons( iIndex, iWeapons, g_eWeapons[iIndex][NUM] );
    
    g_eWeapons[iIndex][WEAPONS] = iWeapons;
    
    return HAM_IGNORED;
}

public Event_PlayerSpawnPost( iIndex )
{
    new sWeapon[32];
    
    for( new i = 0; i < g_eWeapons[iIndex][NUM]; i++ )
    {
        get_weaponname( g_eWeapons[iIndex][WEAPONS][i], sWeapon, charsmax(sWeapon) );
        give_item( iIndex, sWeapon );
    }
    
    g_eWeapons[iIndex][NUM] = 0;

    return HAM_IGNORED;
} 


[Natsheh]

You can simply store weapons in a bitsum variable, you dont need a dynamical array.

[maqi]

Why ?

[Natsheh]

Originally Posted by maqi Why ?

Much better and efficient.

[HamletEagle]

Originally Posted by Natsheh Much better and efficient.

I would not say it's "much better and efficient".Yes, it is more efficient but adds unneded complexity. Using a normal array should be enough. In most cases you will not notice the difference between bitsum and an array.

[maqi]

Do you use bitsum instead of get_players ? Because its the exact same thing

[Natsheh]

Originally Posted by maqi Do you use bitsum instead of get_players ? Because its the exact same thing

Nope its not the same, player id is required to execute functions upon him.

Anywho using the bitsum is more simple.

[maqi]

So is weapon id Its pretty much the same thing and get_user_weapons is a lot like get_players, just saying.

[Natsheh]

Originally Posted by maqi So is weapon id Its pretty much the same thing and get_user_weapons is a lot like get_players, just saying.

I'm not sure whats the reference you are trying to get. The only thing is common between weapons id and players id that the ids starts from 1 and ends at 32.

[maqi]

Im just saying that both weapon id and player id are nothing but integers from 1 to 32 and theres no reason to keep them as a bitsum especially when there are nice functions like get_players and get_user_weapons.