[finishlast]

Hi there,

I have a script that should check player positions on 2 maps to fix some bypasses.

Actually it should play a sound, slay the player bc I am mean and make a whitty quote.

It prevents jumping down from the DA Crane level on common heads at car alarm for example.

If you jump down, it slays you.

All working as expected. Except the cpu load seems to slow down chat messages.

I guess it is bc I used OnGameFrame() and then several if statements.

Is there any other way with less cpu load to check the playerpostions?

Thx in advance.

[Silvers]

For starters you should cache the map name in OnMapStart() and set a value to an int and check that instead of constantly retrieving the map and checking the string. You could use an enum

PHP Code:

enum
{
    MAP_DA_1 = 1,
    MAP_DA_2,
    MAP_DA_3
    etc
} 


You could also switch to a 0.1 or 0.2 timer, it doesn't need to be so precise as OnGameFrame, just increase the Distance variable to 100 more.

It might be better to use "EmitSoundToAll()" instead of looping clients and running "ClientCommand playgamesound".

Also change the if statements, currently it's checking all even if killing that person, use if else statements.

You also have a mistake in the client loop. It should be "Client <= MaxClients" not "Client < MaxClients"

You don't need to do "#include <sdktools_sound>" this is covered by "#include <sdktools>" which is the only one you should include, not any "sdktools_other_file_names", otherwise if you don't have "#include <sdktools>" and nothing else is using sdktools the extension will not load.

[Dragokas]

You can decrease CPU loading down to 0% by using triggers and hooking touch outputs, e.g., see: [Any] Dev Zones

Try never use OnGameFrame() at all unless a real reason.

[finishlast]

Thanks for the input!

I will try with a timer next and take a look into this dev zones thing too.

Thanks again!

****
Tried a timer with 0.2 and a bit bigger distance.
That seems to work, doing the suggested enum and if else next.

The lag is already gone.

Going to check out the dev zone thing too.

[Dragokas]

My example:

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <devzones>

#pragma newdecls required

public Plugin myinfo =
{
    name = "Zones Teleporter",
    author = "Dragokas",
    description = "",
    version = "1.0",
    url = ""
};

bool g_bActivated;

public void OnMapStart()
{
    static char sMap[64];
    GetCurrentMap(sMap, sizeof sMap);
    
    g_bActivated = false;
    
    if (strcmp(sMap, "l4d_airport02_offices") == 0)
    {
        g_bActivated = true;
    }
}

public int Zone_OnClientEntry(int client, char[] zone)
{
    if (!g_bActivated)
        return;

    float pos[3];
    if (strcmp(zone, "Zone 1") == 0)
    {
        GetClientAbsOrigin(client, pos);
        pos[0] -= 100.0;
        TeleportEntity(client, pos, NULL_VECTOR, NULL_VECTOR);
    }
    else if (strcmp(zone, "Zone 2") == 0)
    {
        GetClientAbsOrigin(client, pos);
        pos[0] += 100.0;
        TeleportEntity(client, pos, NULL_VECTOR, NULL_VECTOR);
    }
} 


configs/dev_zones/l4d_airport02_offices.zones.txt

"Zones"
{
	"0"
	{
		"Name"		"Zone 1"
		"cordinate_a"		"4426.947266 834.294373 16.031248"
		"cordinate_b"		"4438.528809 1663.458740 250.000000"
		"vis"		"0"
		"team"		"0"
	}
	"1"
	{
		"Name"		"Zone 2"
		"cordinate_a"		"4402.264160 880.324707 16.031252"
		"cordinate_b"		"4384.531250 1606.159668 250.000000"
		"vis"		"0"
		"team"		"0"
	}
}

See description in Dev Zones topic to get zones creation commands.

[finishlast]

Oh, thank you Dragokas for the example.

That seems to be very helpfull for a lot of different stuff! Very nice.