[Joce93]

Hello guys

I need a plugin who allows me to push the other players (by doing a shockwave in a radius). Just as admin pls.

This is what I want:

https://www.youtube.com/watch?v=q1byP3ewPog#t=0m12s

However, maybe a little less powerful. Editing the shockwave sound would be nice too.

Thanks

[Joce93]

Anyone ?

[Joce93]

Please

[addons_zz]

The only thing I mostly see is just this:

[Joce93]

Hmm strange me too, i could see it days ago, well.

I need something that allow me to push other players by doing a "shockwave" in a radius as I said in the first post.

Can someone make it ?

[HamletEagle]

The most basic approach:

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <xs>

public plugin_init()
{
    register_clcmd("shockwave", "ClientCommand_ShockWave")
}

public ClientCommand_ShockWave(id)
{
    new PlayersInRadius[33], PlayersNum, index
    PlayersNum = find_sphere_class(id, "player", 250.0, PlayersInRadius, sizeof PlayersInRadius)
    
    new Float:velocity[3]
    for(new i; i < PlayersNum; i++)
    {
        index = PlayersInRadius[i]
        if(id == index)
        {
            continue
        }
    
        velocity_by_aim(index, 999, velocity)
        xs_vec_neg(velocity, velocity)
        
        set_pev(index, pev_velocity, velocity)
    }
} 


Radius is 250.0, power is 999. Alter them as you like.

[Joce93]

Thanks, works fine.

[Haunted Dino]

whats the command for this shockwave?

[iceeedr]

Originally Posted by Haunted Dino whats the command for this shockwave?

shockwave on console

[EFFx]

Try that:

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#define PLUGIN                     "Unknown yet"
#define VERSION                 "1.0"
#define AUTHOR                     "EFFEX"

#define IMMUNITY_FLAG                    ADMIN_IMMUNITY


#define calculateRadiusDamage(%1,%2)        floatclamp((%1 - (%2 * %1 / g_fPushRadius)), 0.0, %1)
#define fixedUnsigned16(%1,%2)             clamp(floatround(%1 * %2), 0, 0xFFFF)
#define message_begin_fl(%1,%2,%3,%4)        engfunc(EngFunc_MessageBegin, %1, %2, %3, %4)
#define write_coord_fl(%1)                engfunc(EngFunc_WriteCoord, %1)

new g_iExplosionSprite
new g_mMessageScreenShake

new const g_szExplosionSound[] =            "weapons/explode3.wav"

const Float:g_fPushRadius =                250.0
const Float:g_fImpulseMultiplier =             4.5
const Float:g_fMaxDamage =            10.0

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    g_mMessageScreenShake = get_user_msgid("ScreenShake")
    
    register_clcmd("shockwave", "pushPlayers")
}

public plugin_precache()
{
    precache_sound(g_szExplosionSound)
    g_iExplosionSprite =     precache_model("sprites/shockwave.spr")
}

public pushPlayers(id)
{
    static Float:fEntityVelocity[3], Float:fVictimOrigin[3], Float:fTemp[3]
    static Float:fPusherOrigin[3]
    pev(id, pev_origin, fPusherOrigin)
    
    message_begin_fl(MSG_PVS, SVC_TEMPENTITY, fPusherOrigin, 0)
    write_byte(TE_BEAMCYLINDER)
    write_coord_fl(fPusherOrigin[0])
    write_coord_fl(fPusherOrigin[1])
    write_coord_fl(fPusherOrigin[2])
    write_coord_fl(fPusherOrigin[0])
    write_coord_fl(fPusherOrigin[1])
    write_coord_fl(fPusherOrigin[2] + g_fPushRadius)
    write_short(g_iExplosionSprite)
    write_byte(0)
    write_byte(3)
    write_byte(10)
    write_byte(80)
    write_byte(0)
    write_byte(255)
    write_byte(255)
    write_byte(255)
    write_byte(200)
    write_byte(0)
    message_end()
    
    emit_sound(id, CHAN_ITEM, g_szExplosionSound, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
    
    new iVictim = -1
    while((iVictim = engfunc(EngFunc_FindEntityInSphere, iVictim, fPusherOrigin, g_fPushRadius)) != 0)
    {
        if(is_user_alive(iVictim) && (iVictim != id) && ~get_user_flags(iVictim) & IMMUNITY_FLAG)
        {
            message_begin(MSG_ONE, g_mMessageScreenShake, .player = iVictim)
            write_short(fixedUnsigned16(20.0, (1 << 12)))
            write_short(fixedUnsigned16(3.0, (1 << 12)))
            write_short(fixedUnsigned16(5.7, (1 << 8)))
            message_end()
    
            ExecuteHamB(Ham_TakeDamage, id, id, iVictim, calculateRadiusDamage(g_fMaxDamage, get_distance_f(fPusherOrigin, fVictimOrigin)), DMG_BLAST)
            
            pev(iVictim, pev_velocity, fEntityVelocity)
            pev(iVictim, pev_origin, fVictimOrigin)
            
            xs_vec_sub(fVictimOrigin, fPusherOrigin, fTemp)
            xs_vec_normalize(fTemp, fTemp)
            xs_vec_mul_scalar(fTemp, g_fPushRadius, fTemp)
            xs_vec_mul_scalar(fTemp, g_fImpulseMultiplier, fTemp)
            xs_vec_add(fEntityVelocity, fTemp, fEntityVelocity)
            set_pev(iVictim, pev_velocity, fEntityVelocity)
        }
    }
}