[fatal_nl]

For now I'm not even sure if this can be done with a cvar by default or if amxmodx is even needed for this. But what I want is making a daily .log file containing all chats that took place in the server.

I know there are dozens plugins published on this website, but they're all too advanced, like including admins chats, adding IP's/Steam ID's, formatting in HTML and even feeding it to a SQL database. Which is all unnecessary for my purpose.

[Relaxing]

log text: if $dead$ $team$ $steamid$ $name$ : $message$
Editing a few lines you can get rid of steamid.

Spoiler

#include <amxmodx>
#include <amxmisc>

new szTeams[][] = {
    "(UNASSIGNED)",
    "(Terrorist)",
    "(Counter-Terrorist)",
    "*SPEC*"
}

public plugin_init(){
    register_clcmd("say", "log_chat")
    register_clcmd("say_team", "log_chat")
}

public log_chat(id) {
    if(is_user_bot(id)){
        return PLUGIN_HANDLED;
    }
    
    new arg[192], name[32], steamid[24];
    
    get_user_name(id, name, charsmax(name))
    get_user_authid(id, steamid, charsmax(steamid))  
    
    read_args(arg, charsmax(arg)); 
    remove_quotes(arg);
    
    if (!arg[0]) {
        return PLUGIN_HANDLED;
    }
    
    new Team = get_user_team(id);

    new message[256];
    
    if (!is_user_alive(id) && 1 <= Team <= 2){
        formatex(message, charsmax(message), "*DEAD* %s (%s) %s :  %s", szTeams[Team], steamid, name, arg);
    } else {
        formatex(message, charsmax(message), "%s (%s) %s :  %s", szTeams[Team], steamid, name, arg);
    }
    
    Log("chat_database/chat", message);
    
    return PLUGIN_CONTINUE;
}

//credits Tirant
stock Log(const log_filename[], const message_fmt[], any:...){
    static message[256];
    vformat(message, sizeof(message) - 1, message_fmt, 3);
    
    static filename[96];
    static dir[64];
    if(!dir[0]){
        get_basedir(dir, sizeof(dir) - 1);
        add(dir, sizeof(dir) - 1, "/logs");
    }
    
    format_time(filename, sizeof(filename) - 1, "%m-%d-%Y");
    format(filename, sizeof(filename) - 1, "%s/%s_%s.log", dir, log_filename, filename);
    log_to_file(filename, "%s", message);
}