It was a private plugin only for us. I give it to you.
PHP Code:
// vim: set ts=4 sw=4 tw=99 noet:
//
// AMX Mod X, based on AMX Mod by Aleksander Naszko ("OLO").
// Copyright (C) The AMX Mod X Development Team.
//
// This software is licensed under the GNU General Public License, version 3 or higher.
// Additional exceptions apply. For full license details, see LICENSE.txt or visit:
// https://alliedmods.net/amxmodx-license
//
// Nextmap Chooser Plugin
//
#include <amxmodx>
#include <amxmisc>
#define SELECTMAPS 5
new Array:DefaultMapsList;
new Array:MinPlayersMapsList;
new Array:MaxPlayersMapsList;
new Array:CurrentMapsList;
new Float:ResetTime;
new Float:NextForcedVotemap;
new VotemapDirectCount = 1;
new g_nextName[SELECTMAPS]
new g_voteCount[SELECTMAPS + 2]
new g_mapVoteNum
new g_teamScore[2]
new g_lastMap[32]
new g_coloredMenus
new bool:VotemapRunning;
new bool:VotemapDirectRunning;
new bool:IsDeDust2;
new CvarMinPlayersDirect;
new CvarMinPlayersDirectCooldown;
new CvarMinPlayersDirectMaxCount;
new CvarMinPlayers;
new CvarMinPlayersMapCycle[PLATFORM_MAX_PATH];
new CvarMaxPlayers;
new CvarMaxPlayersMapCycle[PLATFORM_MAX_PATH];
new CvarVoteCountBot;
new CurrentMap[32];
public plugin_init()
{
register_plugin("Nextmap Chooser", AMXX_VERSION_STR, "1.2")
register_dictionary("mapchooser.txt")
register_dictionary("nextmap.txt")
register_dictionary("common.txt")
new MenuName[64]
format(MenuName, charsmax(MenuName), "%L", "en", "CHOOSE_NEXTM")
register_menucmd(register_menuid(MenuName), (-1^(-1<<(SELECTMAPS+2))), "countVote")
register_cvar("amx_extendmap_max", "90")
register_cvar("amx_extendmap_step", "15")
bind_pcvar_num(register_cvar("amx_vote_countbot", "0"), CvarVoteCountBot);
bind_pcvar_num(register_cvar("amx_vote_minplayers_direct", "1"), CvarMinPlayersDirect);
bind_pcvar_num(register_cvar("amx_vote_minplayers_direct_cooldown", "120"), CvarMinPlayersDirectCooldown);
bind_pcvar_num(register_cvar("amx_vote_minplayers_direct_maxcount", "2"), CvarMinPlayersDirectMaxCount);
bind_pcvar_num(register_cvar("amx_vote_minplayers", "10"), CvarMinPlayers);
bind_pcvar_string(register_cvar("amx_vote_minplayers_mapcycle", "maps_minplayers.ini"), CvarMinPlayersMapCycle, charsmax(CvarMinPlayersMapCycle));
bind_pcvar_num(register_cvar("amx_vote_maxplayers", "25"), CvarMaxPlayers);
bind_pcvar_string(register_cvar("amx_vote_maxnplayers_mapcycle", "maps_maxplayers.ini"), CvarMaxPlayersMapCycle, charsmax(CvarMaxPlayersMapCycle));
register_event("TeamScore", "team_score", "a");
register_logevent("@OnGameCommencing", 2, "1&Game_Commencing", "1&Restart_Round");
get_localinfo("lastMap", g_lastMap, charsmax(g_lastMap))
set_localinfo("lastMap", "")
g_coloredMenus = colored_menus()
get_mapname(CurrentMap, charsmax(CurrentMap));
IsDeDust2 = bool:equali(CurrentMap, "de_dust2");
NextForcedVotemap = get_gametime() + 4 * 60;
}
@OnGameCommencing()
{
ResetTime = get_gametime() + 0.1;
}
public OnConfigsExecuted()
{
new filepath[PLATFORM_MAX_PATH];
new configsDir[PLATFORM_MAX_PATH];
get_configsdir(configsDir, charsmax(configsDir));
formatex(filepath, charsmax(filepath), "%s/maps.ini", configsDir);
if (!file_exists(filepath))
{
new mapcycle[32];
get_cvar_string("mapcyclefile", mapcycle, charsmax(mapcycle));
formatex(filepath, charsmax(filepath), "%s/%s", configsDir, mapcycle);
}
if (loadSettings(filepath, DefaultMapsList))
{
set_task(15.0, "voteNextmap", 987456, "", 0, "b");
if (CvarMinPlayers > 0 && CvarMinPlayersMapCycle[0] != EOS)
{
formatex(filepath, charsmax(filepath), "%s/%s", configsDir, CvarMinPlayersMapCycle);
loadSettings(filepath, MinPlayersMapsList);
}
if (CvarMaxPlayers > 0 && CvarMaxPlayersMapCycle[0] != EOS)
{
formatex(filepath, charsmax(filepath), "%s/%s", configsDir, CvarMaxPlayersMapCycle);
loadSettings(filepath, MaxPlayersMapsList);
}
}
else
{
set_fail_state("Maps non trouvés dans %s (incluant la map actuelle et la derniere jouee)", filepath);
}
}
public client_disconnected(client)
{
if (!!!CvarMinPlayersDirect || VotemapRunning || VotemapDirectRunning)
{
return;
}
new Float:currentTime = get_gametime();
if (NextForcedVotemap < currentTime)
{
if (getTotalActivePlayers(.ignoreMe = client) <= CvarMinPlayers && !IsDeDust2 && VotemapDirectCount <= CvarMinPlayersDirectMaxCount)
{
VotemapDirectRunning = true;
VotemapDirectCount++;
displayVoteMap(MinPlayersMapsList);
}
}
}
public checkVotes()
{
new b = 0
for (new a = 0; a < g_mapVoteNum; ++a)
if (g_voteCount[b] < g_voteCount[a])
b = a
if (!VotemapDirectRunning
&& g_voteCount[SELECTMAPS] > g_voteCount[b]
&& g_voteCount[SELECTMAPS] > g_voteCount[SELECTMAPS+1])
{
new Float:steptime = get_cvar_float("amx_extendmap_step")
set_cvar_float("mp_timelimit", get_cvar_float("mp_timelimit") + steptime)
client_print(0, print_chat, "%L", LANG_PLAYER, "CHO_FIN_EXT", steptime)
log_amx("Vote: Voting for the nextmap finished. Map %s will be extended to next %.0f minutes", CurrentMap, steptime)
return
}
new smap[32]
if (g_voteCount[b] && g_voteCount[SELECTMAPS + 1] <= g_voteCount[b])
{
ArrayGetString(CurrentMapsList, g_nextName[b], smap, charsmax(smap));
set_cvar_string("amx_nextmap", smap);
if (VotemapDirectRunning)
{
set_cvar_float("mp_timelimit", ((get_gametime() - ResetTime) + 5.0) / 60.0);
set_hudmessage(20, 200, 100, -1.0, 0.55, 0, 0.5, 4.5, 0.25, 2.0, -1);
show_hudmessage(0, "Changement de map dans quelques secondes...");
}
}
else if (VotemapDirectRunning)
{
client_print(0, print_chat, "%L", LANG_PLAYER, "VOTE_FAILED");
log_amx("Vote: Voting for the nextmap finished. Vote failed.");
VotemapDirectRunning = false;
return;
}
get_cvar_string("amx_nextmap", smap, charsmax(smap))
client_print(0, print_chat, "%L", LANG_PLAYER, "CHO_FIN_NEXT", smap)
log_amx("Vote: Voting for the nextmap finished. The nextmap will be %s", smap)
}
public countVote(id, key)
{
if (get_cvar_float("amx_vote_answers"))
{
new name[MAX_NAME_LENGTH]
get_user_name(id, name, charsmax(name))
if (key == SELECTMAPS)
client_print(0, print_chat, "%L", LANG_PLAYER, "CHOSE_EXT", name)
else if (key < SELECTMAPS)
{
new map[32];
ArrayGetString(CurrentMapsList, g_nextName[key], map, charsmax(map));
client_print(0, print_chat, "%L", LANG_PLAYER, "X_CHOSE_X", name, map);
}
}
++g_voteCount[key]
return PLUGIN_HANDLED
}
bool:isInMenu(id)
{
for (new a = 0; a < g_mapVoteNum; ++a)
if (id == g_nextName[a])
return true
return false
}
bool:checkWinsRounds()
{
new winlimit = get_cvar_num("mp_winlimit")
new maxrounds = get_cvar_num("mp_maxrounds")
if (winlimit)
{
new c = winlimit - 2
if ((c > g_teamScore[0]) && (c > g_teamScore[1]))
{
return false;
}
}
else if (maxrounds)
{
if ((maxrounds - 2) > (g_teamScore[0] + g_teamScore[1]))
{
return false;
}
}
return true;
}
bool:checkTimeLeft()
{
new timeleft = get_timeleft()
if (timeleft < 1 || timeleft > 129)
{
return false;
}
return true;
}
getTotalActivePlayers(ignoreMe = 0)
{
new playersList[MAX_PLAYERS], playersCount, totalplayers;
get_players(playersList, playersCount, !!CvarVoteCountBot ? "ih" : "ich");
for (new i = 0, player = 0; i < playersCount; ++i)
{
player = playersList[i];
if ((!ignoreMe || player != ignoreMe) && 1 <= get_user_team(player) <= 2)
{
++totalplayers;
}
}
return totalplayers;
}
public voteNextmap()
{
if (!checkWinsRounds() || !checkTimeLeft())
{
VotemapRunning = false;
return;
}
if (VotemapRunning || VotemapDirectRunning)
{
return;
}
VotemapRunning = true;
new totalplayers = getTotalActivePlayers();
new Array:mapsList = Invalid_Array;
if (CvarMinPlayers > 0 && totalplayers <= CvarMinPlayers)
{
if (IsDeDust2)
{
client_print_color(0, print_team_red, "* Il y a moins de ^3%d^1 joueurs sur la map ^4de_dust2^4, ^3votemap est désactivé^1", CvarMinPlayers + 1);
return;
}
mapsList = MinPlayersMapsList;
}
else if (CvarMaxPlayers > 0 && totalplayers >= CvarMaxPlayers)
{
mapsList = MaxPlayersMapsList;
}
displayVoteMap(mapsList);
}
displayVoteMap(Array:mapsList)
{
if (mapsList == Invalid_Array)
{
mapsList = DefaultMapsList;
}
CurrentMapsList = mapsList;
NextForcedVotemap = get_gametime() + float(CvarMinPlayersDirectCooldown);
new const mapsCount = ArraySize(mapsList);
new menu[512], a, mkeys = (1<<SELECTMAPS + 1)
new pos = format(menu, charsmax(menu), g_coloredMenus ? "\y%L:\w^n^n" : "%L:^n^n", LANG_SERVER, "CHOOSE_NEXTM")
new dmax = (mapsCount > SELECTMAPS) ? SELECTMAPS : mapsCount
for (g_mapVoteNum = 0; g_mapVoteNum < dmax; ++g_mapVoteNum)
{
a = random_num(0, mapsCount - 1)
while (isInMenu(a))
if (++a >= mapsCount) a = 0
g_nextName[g_mapVoteNum] = a
pos += format(menu[pos], charsmax(menu) - pos, "%d. %a^n", g_mapVoteNum + 1, ArrayGetStringHandle(mapsList, a));
mkeys |= (1<<g_mapVoteNum)
g_voteCount[g_mapVoteNum] = 0
}
menu[pos++] = '^n'
g_voteCount[SELECTMAPS] = 0
g_voteCount[SELECTMAPS + 1] = 0
if (!VotemapDirectRunning && (get_cvar_num("mp_winlimit") + get_cvar_num("mp_maxrounds")) == 0 && (get_cvar_float("mp_timelimit") < get_cvar_float("amx_extendmap_max")))
{
pos += format(menu[pos], charsmax(menu) - pos, "%d. %L^n", SELECTMAPS + 1, LANG_SERVER, "EXTED_MAP", CurrentMap)
mkeys |= (1<<SELECTMAPS)
}
format(menu[pos], charsmax(menu), "%d. %L", SELECTMAPS+2, LANG_SERVER, "NONE")
new MenuName[64]
format(MenuName, charsmax(MenuName), "%L", "en", "CHOOSE_NEXTM")
show_menu(0, mkeys, menu, 15, MenuName)
set_task(15.0, "checkVotes")
client_print(0, print_chat, "%L", LANG_SERVER, "TIME_CHOOSE")
client_cmd(0, "spk Gman/Gman_Choose2")
log_amx("Vote: Voting for the nextmap started")
}
stock bool:ValidMap(mapname[])
{
if ( is_map_valid(mapname) )
{
return true;
}
// If the is_map_valid check failed, check the end of the string
new len = strlen(mapname) - 4;
// The mapname was too short to possibly house the .bsp extension
if (len < 0)
{
return false;
}
if ( equali(mapname[len], ".bsp") )
{
// If the ending was .bsp, then cut it off.
// the string is byref'ed, so this copies back to the loaded text.
mapname[len] = '^0';
// recheck
if ( is_map_valid(mapname) )
{
return true;
}
}
return false;
}
loadSettings(filename[], &Array:mapsList)
{
if (!file_exists(filename))
return 0
server_print("Chargement du fichier: %s", filename);
new szText[32]
new currentMap[32]
new buff[256];
get_mapname(currentMap, charsmax(currentMap))
new fp=fopen(filename,"r");
if (mapsList == Invalid_Array)
{
mapsList = ArrayCreate(32);
}
while (!feof(fp))
{
buff[0]='^0';
szText[0]='^0';
fgets(fp, buff, charsmax(buff));
parse(buff, szText, charsmax(szText));
if (szText[0] == ';' || !ValidMap(szText))
{
continue;
}
if (equali(currentMap, "de_dust2") || !equali(szText, currentMap))
{
ArrayPushString(mapsList, szText);
}
}
fclose(fp);
if (!ArraySize(mapsList))
{
ArrayDestroy(mapsList);
return 0;
}
return 1;
}
public team_score()
{
new team[2]
read_data(1, team, charsmax(team))
g_teamScore[(team[0]=='C') ? 0 : 1] = read_data(2)
}
public plugin_end()
{
new current_map[32]
get_mapname(current_map, charsmax(current_map))
set_localinfo("lastMap", current_map)
ArrayDestroy(DefaultMapsList);
ArrayDestroy(MinPlayersMapsList);
ArrayDestroy(MaxPlayersMapsList);
}