[Solved] XP TOP10

abdobiskra · **Author**

Hi, I found this plugin in the forum
But it only shows the current players and not the data top players ?

PHP Code:


			
/* Plugin generated by AMXX-Studio */



#include <amxmodx>

#include <nvault>



#define PLUGIN "New Plugin"

#define VERSION "1.0"

#define AUTHOR "Author"



#define MAXSLOTS    32

new g_XP[MAXSLOTS+1];



public plugin_init() {

    register_plugin(PLUGIN, VERSION, AUTHOR);

    register_clcmd("say /xptop10","show_top");

}

public client_disconnect(id){

    SaveXP(id)

}

public client_putinserver(id){

    LoadXP(id)

}

//Save xp when a player disconnect

public SaveXP(id){

    new Vault = nvault_open("player_XP");

    new Key[64],Value[64],Name[32];

    get_user_name(id,Name,sizeof Name - 1);

    formatex(Key,sizeof Key - 1, "%s - XP:", Name);

    formatex(Value,sizeof Value - 1, "%d", g_XP[id]);

    

    nvault_set(Vault,Key,Value);

    nvault_close(Vault);

}

//Load xp when a player enters on the server

public LoadXP(id){

    new Vault = nvault_open("player_XP");

    new Key[64],Value[64],Name[32];

    get_user_name(id,Name,sizeof Name - 1);

    

    formatex(Key,sizeof Key - 1, "%s - XP:", Name);

    nvault_get(Vault,Key,Value,sizeof Value - 1);

    nvault_close(Vault);

    

    g_XP[id] = str_to_num(Value)

}

//Show top10

public show_top(id){

    static Sort[33][2];

    new players[32],num,count,index;

    get_players(players,num);

    

    for(new i = 0; i < num; i++){

        index = players[i];

        Sort[count][0] = index;

        Sort[count][1] = g_XP[index];

        count++;

    }

    

    SortCustom2D(Sort,count,"compare_xp");

    new motd[1501],iLen;

    iLen = format(motd, sizeof motd - 1,"<body bgcolor=#000000><font color=#98f5ff><pre>");

    iLen += format(motd[iLen], (sizeof motd - 1) - iLen,"%s %-22.22s %3s^n", "#", "Name", "XP Top10");

    

    new y = clamp(count,0,10);

    new name[32],kindex;

    

    for(new x = 0; x < y; x++){

        kindex = Sort[x][0];

        get_user_name(kindex,name,sizeof name - 1);

        iLen += format(motd[iLen], (sizeof motd - 1) - iLen,"%d %-22.22s %d^n", x + 1, name, Sort[x][1]);

    }

    iLen += format(motd[iLen], (sizeof motd - 1) - iLen,"</body></font></pre>");

    show_motd(id,motd, "XP Top 10");

}

public compare_xp(elem1[], elem2[])

{

    if(elem1[1] > elem2[1])

        return -1;

    else if(elem1[1] < elem2[1])

        return 1;

    

    return 0;

}

The question is how to call the ranking in the data for the players ?

JocAnis · 04-11-2018 , 15:41 Re: XP TOP10

load xp is loaded on player connect...=> only connected players in top15...
load xp should be loaded in plugin_init (or with set_task) but dunno how exactly to do, hopefully someone will write it, i will also need this

abdobiskra · 04-21-2018 , 09:35 Re: XP TOP10

bump

**Bugsy** · 04-21-2018 , 11:02 Re: XP TOP10

You will need to use nVault Utility to iterate through all data in the vault to load it into an array and then do your sort etc. This is not ideal, you can make improvements for how XP is saved to make this more efficient but I made it work with the current XP framework. Would be best to use SQL. This will only support a vault with up to 2000 players.

PHP Code:


			
public show_top_all(id)
{
    static Sort[2000][2];
    new count;
    
    //Open vault for nvault utility usage
    new iVault = nvault_util_open( "player_XP" );
    
    //Get count of total number of entries in the vault
    new num = nvault_util_count( iVault );
    new iOffset, iTS , szKey[ 45 ] , szVal[ 12 ];
    
    //Loop through all entries in the vault
    for( count = 0; count < num ; count++)
    {
        //Read entry in vault
        iOffset = nvault_util_read( iVault , iOffset , szKey , charsmax( szKey ) , szVal , charsmax( szVal ) , iTS );
    
        //Set [0] to the byte offset for this players data within the vault so it can be referenced later to get his name if he is within the top 10.
        Sort[count][0] = ( count == 0 ) ? 0 : iOffset;
        
        //Set [1] to his XP value
        Sort[count][1] = str_to_num( szVal );
    }
    
    //Sort the array
    SortCustom2D(Sort,count,"compare_xp");
    
    new motd[1501],iLen;
    iLen = formatex(motd, sizeof motd - 1,"<body bgcolor=#000000><font color=#98f5ff><pre>");
    iLen += formatex(motd[iLen], (sizeof motd - 1) - iLen,"%s %-22.22s %3s^n", "#", "Name", "XP Top10");
    new y = min( num , 10 );
    
    //Build the top 10. y is set to the smaller of 10 or the total records in the vault.
    for(new x = 0; x < y ; x++)
    {
        //Above we set [0] to the players data offset within the vault file.
        iOffset = Sort[x][0];
        
        //Read data at the players offset so we can get his name. Since he may not be online we can not use get_user_name().
        nvault_util_read( iVault , iOffset , szKey , charsmax( szKey ) , szVal , charsmax( szVal ) , iTS );
        
        //Trim off the ' - XP:' part of their name.
        szKey[ strfind( szKey , " - XP:" ) ] = EOS;
        
        iLen += formatex(motd[iLen], (sizeof motd - 1) - iLen,"%d %-22.22s %d^n", x + 1, szKey, Sort[x][1] );
    }
    
    //Close nvault utility file.
    nvault_util_close( iVault );
    
    iLen += formatex(motd[iLen], (sizeof motd - 1) - iLen,"</body></font></pre>");
    show_motd(id,motd, "XP Top 10");
}

abdobiskra · 05-10-2018 , 10:58 Re: XP TOP10

Thank you for reply Bugsy but your code did not work for me ? (Nothing happens when i calle for it)
I found here who explains how https://amx-x.ru/viewtopic.php?f=9&t=29910 .. but it depends on the storage of data through the name.
And when I wanted to store it with SteamID .. the top 15 show SteamID only? Where is the problem ?
i need to show it with name ?
what i try to solve it :

PHP Code:


			
/* Plugin generated by AMXX-Studio */



#include <amxmodx>

#include <amxmisc>

#include <nvault> 

#include <nvault_util> 





#define PLUGIN  "[TUT]StatsNvault(amx-x)"

#define VERSION         "1.0"

#define AUTHOR  "BaJIeHoK"



new g_Vault

new iPlayerNum[33][3]







//new Trie:g_Name 

//new Array:g_SteamID 



public plugin_init()

{

    register_plugin(PLUGIN, VERSION, AUTHOR)



    register_clcmd("say /set_num", "SetPlayerNum") //??????? ??? ?????????? ?????

    register_clcmd("say /rank", "ShowRank") //??????? ??? ?????? ?????

    register_clcmd("say", "handle_say") //??????? ??? ?????? ????

    

    

    //g_SteamID = ArrayCreate(32, 1)

    //g_Name = TrieCreate()



    

}



public SetPlayerNum(id){

    

    new iPlayers[32] //???? ??????? ??? id ???????

    new iPlayer, iNum //? ????? ????? ??????? ?????????? ?????? ? ???? ???????

    

    get_players(iPlayers, iNum) //???????? ???????

    

    for(new i; i < iNum; i++) //????????? ????? ????    

    {

        iPlayer = iPlayers[i] //??? ????????? ?????????? ?????? ????????

        

        iPlayerNum[iPlayer][1] += random_num(1, 5) //??????????? 1 ?????

        iPlayerNum[iPlayer][2] += random_num(1, 5) //??????????? 2 ?????

    }

}



public client_putinserver(id){

    

    g_Vault = nvault_open("level_xp_rank") //????????? ????

    

    if(g_Vault == INVALID_HANDLE) //???? ??????

    {

        set_fail_state("level_xp_rank") //?????? ?????, ????? ? ????????? ????

    }

    

    new szData[32] //??? ???????? ?????? ?? ????

    new szName[32] //???? ??????? ???

    

    

    //get_user_name(id, szName, charsmax( szName )) //???????? ???

    get_user_authid(id, szName, charsmax(szName))

    

    nvault_get(g_Vault, szName, szData, charsmax( szData )) //???????? ??????

    

    nvault_close( g_Vault ) //????????? ????

    

    replace_all(szData, charsmax( szData ), "#", " ") //???????? # ?? ??????(# - ????? ???????????? ??????)

    new szParse[3][32] //????? ??????? ?????????? ?????

    

    parse(szData, szParse[1], 31, szParse[2], 31)



    iPlayerNum[id][1] = str_to_num( szParse[1] ) //??????????? 1 ????? ??????

    iPlayerNum[id][2] = str_to_num( szParse[2] ) //??????????? 2 ????? ??????

    

}





public client_disconnect(id){

    

    g_Vault = nvault_open("level_xp_rank") 

    

    if(g_Vault == INVALID_HANDLE)     

    {

        

        set_fail_state("NVault Error")

    }

    

    new szData[32] 

    new szName[32] 

    

    //get_user_name(id, szName, charsmax( szName )) 

    get_user_authid(id, szName, charsmax(szName))

    



    formatex(szData, charsmax( szData ), "%i#%i", iPlayerNum[id][1], iPlayerNum[id][2])

    

    nvault_set(g_Vault, szName, szData)

    

    nvault_close( g_Vault ) 

    

}





public ShowRank(id){

    

    new iPlayers[32]

    new iPlayer, iNum 

    

    get_players(iPlayers, iNum) 

    

    for(new i; i < iNum; i++) 

    {

        

        iPlayer = iPlayers[i] 

        

        client_disconnect(iPlayer) 

    }

    

    

    new Array:aNames  = ArrayCreate(32) 

    new Array:aNums = ArrayCreate(1)

    

    new iPos, iCount, iTime 

    

    g_Vault = nvault_util_open("level_xp_rank")

    iCount = nvault_util_count( g_Vault ) 

    

    for(new i; i < iCount; i++) 

    {

        

        new szName[32], szData[10] 

        

        iPos = nvault_util_read(g_Vault, iPos, szName, charsmax( szName ), szData, charsmax( szData ), iTime)

        

        ArrayPushString(aNames, szName) 

        

        ArrayPushCell(aNums, str_to_num( szData )) 

        

    }

    

    nvault_util_close( g_Vault ) 

    

    new iCheckNum 

    

    for(new i,  j; i < ( iCount - 1 ); i++) 

    {

        

        iCheckNum = ArrayGetCell(aNums, i) 

        

        for( j = i + 1; j < iCount; j++ ) 

        {

            

            if(iCheckNum < ArrayGetCell(aNums, j))      

            {

                

                ArraySwap(aNames, i,  j) 

                

                ArraySwap(aNums, i,  j) 

                

                

                

                i-- 

                

                break 

                

            }

            

        }

        

    }

    

    new szName[32], szParseName[32]

    

    get_user_name(id, szName, charsmax( szName ))

    

    for(new i; i < iCount; i++) 

    {

        

        ArrayGetString(aNames, i, szParseName, charsmax( szParseName )) 

        

        

        

        if(equal(szParseName, szName)) 

        {

            

            client_print(id, print_chat, "you rank %d  %d", (i + 1), iCount)

            

            break

            

        }

        

    }

    

    ArrayDestroy(aNames) 

    ArrayDestroy(aNums) 

    

    return PLUGIN_HANDLED

    

}



public handle_say(id) 

{

    static args[32]

    read_args(args, charsmax(args))

    remove_quotes(args)

    trim(args)

    

    if(args[0] != '/')

        return PLUGIN_CONTINUE

    

    if(contain(args, "/top") != -1) 

    {

        replace(args, charsmax(args), "/top", " ")

        

        return handle_top(id, str_to_num(args))

    }

    return PLUGIN_CONTINUE

}

handle_top(id, topnum = 15)

{    

    

    new buffer[2048], buf[64]

    topnum = ShowTop(id, buffer, topnum)

    

    formatex(buf, charsmax(buf), "Zobmbie Infection - Top %d", topnum)

    show_motd(id, buffer, buf)

    

    return PLUGIN_CONTINUE

}



ShowTop(id, szMotd[2048], topnum){

    

    new iPlayers[32]

    new iPlayer, iNum 

    

    get_players(iPlayers, iNum) 

    

    for(new i; i < iNum; i++) 

    {

        iPlayer = iPlayers[i] 

    

        client_disconnect(iPlayer)

    }

    

    new Array:g_SteamID = ArrayCreate(32, 1)

    new Trie: g_Name = TrieCreate()

    //new Array:aNames  = ArrayCreate(32) 

    new Array:aNum1 = ArrayCreate(1) 

    new Array:aNum2 = ArrayCreate(1) 

    

    new iPos, iCount, iTime 

    

    g_Vault = nvault_util_open("level_xp_rank") 

    iCount = nvault_util_count( g_Vault ) 

    

    for(new i; i < iCount; i++) 

    {

        

        new szName[32], szData[10] 

        

        iPos = nvault_util_read(g_Vault, iPos, szName, charsmax( szName ), szData, charsmax( szData ), iTime)

        

        replace_all(szData, charsmax( szData ), "#", " ")

        

        new szParseNum1[32], szParseNum2[32]

        

        parse(szData, szParseNum1, charsmax( szParseNum1 ), szParseNum2, charsmax( szParseNum2 ))

        

        ArrayPushString(g_SteamID, szName) 

        ArrayPushCell(aNum1, str_to_num( szParseNum1 ))

        ArrayPushCell(aNum2, str_to_num( szParseNum2 )) 

        

    }

    

    nvault_util_close( g_Vault ) 

    

    new iCheckNum 

    

    for(new i,  j; i < ( iCount - 1 ); i++) 

    {

        

        iCheckNum = ArrayGetCell(aNum1, i) 

        

        

        

        for( j = i + 1; j < iCount; j++ ) 

        {

            

            if(iCheckNum < ArrayGetCell(aNum1, j))

            {

                

                ArraySwap(g_SteamID, i,  j) 

                ArraySwap(aNum1, i,  j)  

                

                ArraySwap(aNum2, i,  j)  

                

                i-- 

                

                break 

            }

            

        }

        

    }

    

    new szName[32], szParseName[32], SteamID[32]

    new iParseNum[3] 

    new iLen, size, Position

    

    iLen += formatex(szMotd[iLen], charsmax( szMotd ) - iLen,"%5s  %30s %25s %25s %25s" , "Rank", "Name", "XP", "Level", "Contry");

    

    

    size = min(ArraySize(g_SteamID), topnum)

    

    //for (Position = 0, Size = min(ArraySize(aNames), topnum); Position < Size; Position++)

    //{

    for(Position = size - 15 < 0 ? 0 : size - 15; Position < size && charsmax(szMotd) - iLen > 0; Position++)

    {

        ArrayGetString(g_SteamID , Position, SteamID, charsmax( SteamID )) 

        //ArrayGetString(aNames, Position, szParseName, charsmax( szParseName )) 

        TrieGetString(g_Name, SteamID, szParseName, charsmax(szParseName));

        //get_user_name(id, szParseName, charsmax( szParseName )) //???????? ???

        

        iParseNum[1] = ArrayGetCell(aNum1, Position) 

        iParseNum[2] = ArrayGetCell(aNum2, Position) 

        

        iLen += formatex(szMotd[iLen], charsmax( szMotd ) - iLen, "^n%5d  %25s %6.0d/%d", (Position + 1), szParseName, iParseNum[1], iParseNum[2])

    }

    

    

    return size

    

}

But the result is that the name does not appear

**Bugsy** · 05-10-2018 , 17:52 Re: XP TOP10

I coded it based on your above code. How am I supposed to know you truly wanted to store using steamid? Am I supposed to spend time coding it assuming things for you to then tell me I didn't do what you asked?

Although it is the correct way to go storing data using steam id, I coded based on your first post. It will take some more work and nvault array to do this with name, steam id and value.

**Bugsy** · 05-10-2018 , 20:49 Re: XP TOP10

You need these includes:

Make sure your nVault module is updated as stated in the nVault Array thread (AMX-X dev builds >= 4589 are ok).

Set a players XP using: pdData[ id ][ XP ] = X

Edit: Applied fix to correctly associate XP to player.

Spoiler

PHP Code:


			
#include <amxmodx>
#include <nvault>
#include <nvault_util>
#include <nvault_array>

#pragma dynamic 16384

new const VaultName[] = "Player_XP2";

enum PlayerData
{
    PlayerName[ 32 ],
    XP
}

new pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_AuthID[ MAX_PLAYERS + 1 ][ 34 ];
new g_Vault;

public plugin_init() 
{
    register_clcmd( "say top10" , "show_top_all" );
    
    g_Vault = nvault_open( VaultName );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    get_user_authid( id , g_AuthID[ id ] , charsmax( g_AuthID[] ) );
    nvault_get_array( g_Vault , g_AuthID[ id ] , pdData[ id ][ PlayerData:0 ] , sizeof( pdData[] ) );
}

public client_disconnect( id )
{
    get_user_name( id , pdData[ id ][ PlayerName ] , charsmax( pdData[][ PlayerName ] ) );
    nvault_set_array( g_Vault , g_AuthID[ id ] , pdData[ id ][ PlayerData:0 ] , sizeof( pdData[] ) );
}

public show_top_all( id )
{
    static Sort[2000][2];
    new count;
    
    //Close and re-open vault so the journal writes to the vault so nvault_util gets fresh data
    nvault_close( g_Vault );
    g_Vault = nvault_open( VaultName );
    
    //Open vault for nvault utility usage
    new iVault = nvault_util_open( VaultName );
    
    //Get count of total number of entries in the vault
    new num = nvault_util_count( iVault );
    new iOffset, iTS , szKey[ 45 ] , pdVal[ PlayerData ] , iPrevOffset;
    
    //Loop through all entries in the vault
    for ( count = 0 ; count < num ; count++ )
    {
        //Read entry in vault
        iOffset = nvault_util_read_array( iVault , iOffset , szKey , charsmax( szKey ) , pdVal[ PlayerData:0 ] , sizeof( pdVal ) , iTS );
        
        //Set [0] to the byte offset for this players data within the vault so it can be referenced later to get his name if he is within the top 10.
        Sort[ count ][ 0 ] = iPrevOffset;
        
        //Set [1] to his XP value
        Sort[ count ][ 1 ] = pdVal[ XP ];
        
        iPrevOffset = iOffset;
    }
    
    //Sort the array
    SortCustom2D( Sort , count , "compare_xp" );
    
    new motd[1501],iLen;
    iLen = formatex( motd , charsmax( motd ) , "<body bgcolor=#000000><font color=#98f5ff><pre>" );
    iLen += formatex( motd[ iLen ] , charsmax( motd ) - iLen , "%s %-22.22s %3s^n" , "#" , "Name" , "XP Top10" );
    new y = min( num , 10 );
    
    //Build the top 10. y is set to the smaller of 10 or the total records in the vault.
    for ( new x = 0 ; x < y ; x++ )
    {
        //Above we set [0] to the players data offset within the vault file.
        iOffset = Sort[ x ][ 0 ];
        
        //Read data at the players offset so we can get his name. Since he may not be online we can not use get_user_name().
        nvault_util_read_array( iVault , iOffset , szKey , charsmax( szKey ) , pdVal[ PlayerData:0 ] , sizeof( pdVal ) , iTS );
        
        iLen += formatex( motd[ iLen ] , charsmax( motd ) - iLen ,"%d %-22.22s %d^n", ( x + 1 ) , pdVal[ PlayerName ] , pdVal[ XP ] );
    }
    
    //Close nvault utility file.
    nvault_util_close( iVault );
    
    iLen += formatex( motd[ iLen ], charsmax( motd ) - iLen , "</body></font></pre>" );
    show_motd( id , motd , "XP Top 10" );
}

public compare_xp( elem1[] , elem2[] ) 
{ 
    if(elem1[1] > elem2[1]) 
        return -1; 
    else if(elem1[1] < elem2[1]) 
        return 1; 
    
    return 0; 
}

abdobiskra · 05-11-2018 , 05:12 Re: XP TOP10

Quote:

Originally Posted by Bugsy

I coded it based on your above code. How am I supposed to know you truly wanted to store using steamid? Am I supposed to spend time coding it assuming things for you to then tell me I didn't do what you asked?

Although it is the correct way to go storing data using steam id, I coded based on your first post. It will take some more work and nvault array to do this with name, steam id and value.

No I do not blame your code just I'm the one who wanted to do it to try just because I consider it the best way
Sorry, maybe I was in a hurry. I appreciate your effort and the time you give me for help

Thank you very much again have been resolved

**Bugsy** · 05-13-2018 , 13:07 Re: XP TOP10

abdobiskra, please use the updated code in my previous post. The original plugin was not correctly associating XP to a player.

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode