[Stefanos]

Oh i get it.. sorry im bad with english, dont get mad.. can you do something that death dont need to happen, bcs what if im in 85 seconds on round, and im alone.. plugin wont work then.. i hope u understand me..

[Bugsy]

Ok hang on

[Bugsy]

Try above code

[Stefanos]

works perfect, add deagle for allowed guns, and thats it

[Bugsy]

Code updated for CT slay

You can make it allow deagle, look at the code for other allowed weapons and figure it out

[Stefanos]

slay for ct does not work, again 2 min passed, last alive 10 dead, nothing happens..

[Bugsy]

Please re-test, it's working fine for me.

[Stefanos]

retested 10times, sometimes WORK sometimes DONT work... dont know reason but i sometime get slayed, sometime no..

[Bugsy]

I added logging. When it doesn't work, I need the logs for that time frame.

PHP Code:


#include <amxmodx>

new const Version[] = "0.61";

new g_pSlayNoBots , g_pSlayWithBots , g_pSlayDelay , g_pPluginStartDelay;
new g_Bots , g_iSeconds , g_iSlayID;
new g_szName[ 33 ] , g_shHUD , g_iRoundStartTime;

public plugin_init() 
{
    register_plugin( "Slay CT" , Version , "bugsy" );

    register_event( "HLTV" , "NewRound" , "a" , "1=0" , "2=0" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );
    
    g_pSlayNoBots = register_cvar( "sct_nobotslay" , "3" );
    g_pSlayWithBots = register_cvar( "sct_botslay" , "5" );
    g_pSlayDelay = register_cvar( "sct_slaydelay" , "5" );
    g_pPluginStartDelay = register_cvar( "sct_rounddelayseconds" , "90" );
    
    g_shHUD = CreateHudSyncObj();
    
    set_task( 1.0 , "SlayCheck" , 139457 , .flags="b" );
    log_to_file( "CTSlay.log" , "Plugin started, starting task" );
}

public client_putinserver( id )
{
    g_Bots |= ( is_user_bot( id ) << ( id & 31 ) );
}

public client_disconnect( id )
{
    g_Bots &= ~( 1 << ( id & 31 ) );
    
    if ( id == g_iSlayID )
    {
        log_to_file( "CTSlay.log" , "Removed HUD on disconnect - g_iSlayID=%d" , g_iSlayID );
        remove_task( g_iSlayID );
        g_iSlayID = 0;
    }
}

public NewRound()
{
    log_to_file( "CTSlay.log" , "New round" );
    g_iRoundStartTime = get_systime();
}

public RoundEnd()
{
    log_to_file( "CTSlay.log" , "Removed HUD on round end - g_iSlayID=%d" , g_iSlayID );
    remove_task( g_iSlayID );
    g_iSlayID = 0;
}

public SlayCheck()
{
    new iPlayers[ 32 ] , iCTNum , iTNum
    
    log_to_file( "CTSlay.log" , "Task Check - g_iSlayID=%d : Slay delay: %d >= %d : Players %d > %d" , g_iSlayID , get_systime() - g_iRoundStartTime , get_pcvar_num( g_pPluginStartDelay ) , get_playersnum() , get_pcvar_num( g_Bots ? g_pSlayWithBots : g_pSlayNoBots ) );
    
    if ( !g_iSlayID && ( get_systime() - g_iRoundStartTime ) >= get_pcvar_num( g_pPluginStartDelay ) && ( get_playersnum() > get_pcvar_num( g_Bots ? g_pSlayWithBots : g_pSlayNoBots ) ) )
    {
        get_players( iPlayers , iTNum , "ae" , "TERRORIST" );
        get_players( iPlayers , iCTNum , "ae" , "CT" );
        
        if ( ( iCTNum == 1 ) && iTNum )
        {
            get_user_name( ( g_iSlayID = iPlayers[ 0 ] ) , g_szName , charsmax( g_szName ) );
            set_task( 1.0 , "DisplayHUD" , g_iSlayID , .flags="a" , .repeat=( g_iSeconds = get_pcvar_num( g_pSlayDelay ) + 1 ) );
            
            log_to_file( "CTSlay.log" , "Created HUD on %d" , g_iSlayID );
        }
    }
}

public DisplayHUD( id )
{
    if ( --g_iSeconds >= 1 ) 
    {
        set_hudmessage( 0 , 170 , 255 , -1.0 , 0.40 , 0 , 0.0 , 1.0 , 0.0 , 0.0 , -1 );
        ShowSyncHudMsg( 0 , g_shHUD , "%s will be slayed in %d second%s!" , g_szName , g_iSeconds , g_iSeconds > 1 ? "s" : "" );
    }
    else
    {
        user_kill( id );
        g_iSlayID = 0;
    }
} 


[instinctpt1]

@Bugsy can i ask you, why arent you checking this on DeathMsg event and get players count accordingly instead of adding a task to be executed every second ?