[MihailoZ]

Hi,

I would like to know if it's possible to make a task that will run at 18:10:45 using this plugin https://forums.alliedmods.net/showthread.php?t=1263 ?

[Bugsy]

Try:

amx_task "18:10:45" "command" tr

Edit: Looking at how that plugin is coded, I am doubtful, it is much less complicated than I was expecting.

[JocAnis]

if it cant affect seconds (dont have time now to look at the code)...make it to 18:10 to call pre_your_func1 so

pre_your_func1 would have set_task of 45 sec for your_func1..no?

[Bugsy]

That plugin works but has a few things wrong. With very few changes it can handle seconds. It was so simple to make possible, I'm not sure why the coder didn't do this to begin with. Literally as simple as changing get_time("%H:%M",curtime,charsmax(curtime)) to get_time("%H:%M:%S",curtime,charsmax(curtime) ) and expanding the string size that holds the time value to accommodate seconds and changing the set_task() interval to 1.0 second.

Tested and works with this (without the extra spaces in the time): amx_task "15 : 37 : 00" "changelevel de_dust" t

Spoiler

PHP Code:

#include <amxmodx>

new task_cmds[32][108]
new task_times[32][16]
new numtasks = 0

public load_task()
{
    if (read_argc() < 4) {
        server_print("[AMX] Usage:  amx_task < time > ^"command^" < flags >")
        return PLUGIN_HANDLED
    }

    new args[128]
    read_args(args,128)
    new clock[9], cmd[108], flags[5]

    parse(args,clock,charsmax(clock),cmd,108,flags,5)
    new Float:time_f = floatstr(clock)

    new flag[2] = ""
    if (contain(flags,"r") != -1)
        flag="b"
        
    if (contain(flags,"m") != -1)
        time_f = time_f * 60

    if (contain(flags,"t") != -1)
    {
        copy(task_cmds[numtasks],108,cmd)
        copy(task_times[numtasks],charsmax( clock ) ,clock)
        numtasks++
        return PLUGIN_HANDLED
    }

    set_task(time_f,"run_task",0,cmd,108,flag)

    return PLUGIN_CONTINUE
}

public run_task(cmd[])
{
    server_cmd(cmd)
    return PLUGIN_HANDLED
}

public check_time()
{
    new curtime[9]
    get_time("%H:%M:%S",curtime,charsmax(curtime))

    for(new i=0; i<numtasks; i++)
    {
        if(equal(curtime,task_times[i]))
            server_cmd(task_cmds[i])
    }

    return PLUGIN_CONTINUE
}

public plugin_init()
{
    register_plugin("Task Scheduler","0.2","JustinHoMi")
    register_srvcmd("amx_task","load_task")
    set_task(1.0,"check_time",1,"",0,"b")
    return PLUGIN_CONTINUE
}