[safetymoose]

Hey guys, any help would be appreciated

I'm trying to read coordinates from a file, then use those coordinates as origins. I've hit an obstacle..

PHP Code:

New Float:origins[ ][ 3 ] = {
    { x1, y1. z1 },
    { x2, y2, z2 },
    { x3, y3, z3 }
};

Plugin_init() {

    LoadValues()

}

public LoadValues() {
    new file[200]
    new map[50]

    //directory folder
    get_configsdir(file, 199)
    format(file, 199, "%s/origins", file)
    
    // Extension for files
    get_mapname(map, 49)
    format(file, 199, "%s/%s.ini", file, map)
    
    if (!file_exists(file))
    {
        log_amx("File not found")
        return
    }
    
    new input[1000], line = 0, len
    
    while( (line = read_file(file , line , input , 127 , len) ) != 0 ) 
    {
        if (!strlen(input)  || (input[0] == ';')) continue;

        new data[20]
        
        //Coordinates
        strbreak(input, data, 20, input, 999);    origin_first[0] = str_to_float(data);
        strbreak(input, data, 20, input, 999);    origin_first[1] = str_to_float(data);
        strbreak(input, data, 20, input, 999);    origin_first[2] = str_to_float(data);

      //etc...
     }

    origins[ ][ 3 ] = {
        { origin_first[0], origin_first[1]. origin_first[2] },
        { origin_second[0], origin_second[1], origin_second[2] },
        { origin_third[0], origin_third[1], origin_third[2] }
    };
} 


I am getting errors on the last part, where i want to set origins[][3] with the data from the file. It says "Assumed zero". How can i set them properly?

[HamletEagle]

Your code is crap, lol. Use new file natives and learn how to properly work with strings. Secondly, are you sure that origins din exists ?

PHP Code:

New Float:origins[ ][ 3 ] = {
    { x1, y1. z1 },
    { x2, y2, z2 },
    { x3, y3, z3 }
}; 


Here you have a typo, it should be "," and "new", not "New"

PHP Code:

 origins[ ][ 3 ] = {
        { origin_first[0], origin_first[1]. origin_first[2] },
        { origin_second[0], origin_second[1], origin_second[2] },
        { origin_third[0], origin_third[1], origin_third[2] }
    }; 


What ?

I did something like that before, hope this could help you. I need to know what you will do with this origins later, how you would use them ?

PHP Code:

#include <amxmodx>
#include <amxmisc>

public plugin_init()
{
    LoadValues()
}

LoadValues()
{
    new const FolderName[] = "origins"
    
    new HandleConfigsDir[160]
    get_configsdir(HandleConfigsDir, charsmax(HandleConfigsDir))
    format(HandleConfigsDir, charsmax(HandleConfigsDir), "%s/%s", HandleConfigsDir, FolderName)
    
    if(!dir_exists(HandleConfigsDir))
    {
        mkdir(HandleConfigsDir)
    }
    
    new MapName[32]
    get_mapname(MapName, charsmax(MapName))
    format(HandleConfigsDir, charsmax(HandleConfigsDir), "%s/%s.ini", HandleConfigsDir, MapName)
    
    new FilePointer = fopen(HandleConfigsDir, "rt")
    if(FilePointer)
    {
            
        new FileData[100], XOrigin[10], YOrigin[10], ZOrigin[10], Float: FloatOrigin[10]
        while(!feof(FilePointer))
        {
            fgets(FilePointer, FileData, charsmax(FileData))
            trim(FileData)
    
            if(!FileData[0] || FileData[0] == ';' || FileData[0] == '#' || FileData[0] == '/')
            {
                continue
            }
            parse
            (
                FileData,
                XOrigin, charsmax(XOrigin), 
                YOrigin, charsmax(YOrigin), 
                ZOrigin, charsmax(ZOrigin)
            )
    
            FloatOrigin[0] = str_to_float(XOrigin)
            FloatOrigin[1] = str_to_float(YOrigin)
            FloatOrigin[2] = str_to_float(ZOrigin)
            
            server_print("Debug: %f %f %f", FloatOrigin[0], FloatOrigin[1], FloatOrigin[2])
        }
        fclose(FilePointer)
    }
} 


In my file:

1.0 2.0 3.0
4.0 5.0 6.0

Get when running it:

Debug: 1.000000 2.000000 3.000000
Debug: 4.000000 5.000000 6.000000

Folder is created automatically, you have to create the file manually.

You see that it is working correctly, so, answer the question above if you want more help.

[safetymoose]

I want to read map coordinates from a file, and use some as teleport origins, some as mins, maxs. So my question is how to properly store these values once they are read from the file, because i will need to compare them later on...

[HamletEagle]

Dynamic array. This seems to be the best way considering the short information you provided.

[Bugsy]

Edit: Added delete command to delete origins from the file. Also now uses configs/map_coords folder. There is a separate coord file used for each map. Added random command to teleport player to random origin from file.

Commands:
save -player says this in game to save his current location to the current map coord file.
random -player says this in game to teleport to random origin saved in the current map coord file.
read - display in server console all saved origins for current map.
delete # - delete specified coord index (as printed from read command) from current map coord file.

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <fun>

new const szFileName[] = "coords";
new const OriginSize = 3 * BLOCK_INT;

new szFile[ 64 ];

public plugin_init() 
{
    register_plugin( "Save Origins" , "0.3" , "bugsy" );
    
    register_clcmd( "say save" , "SaveOrigin" );
    register_clcmd( "say random" , "TeleportRandom" );
    
    register_concmd( "read" , "ReadOrigins" );
    register_concmd( "delete" , "DeleteOrigin" );
}

public plugin_cfg()
{
    new szMap[ 32 ] , iPos;

    get_mapname( szMap , charsmax( szMap ) );
    iPos = formatex( szFile[ get_configsdir( szFile , charsmax( szFile ) ) ] , charsmax( szFile ) , "/map_coords" ) + sizeof( szFileName ) + 15;
    
    if ( !dir_exists( szFile ) )
        mkdir( szFile );
        
    formatex( szFile[ iPos ] , charsmax( szFile ) - iPos , "/%s_%s" , szMap , szFileName );
}

public SaveOrigin( id )
{
    new iFile , iOrigin[ 3 ];
    
    if ( ( iFile = fopen( szFile , "ab" ) ) )
    {
        get_user_origin( id , iOrigin );
        
        fwrite_raw( iFile , iOrigin , sizeof( iOrigin ) , BLOCK_INT );
        fclose( iFile );
        
        client_print( id , print_chat , "Origin saved: [ %d , %d , %d ]" , iOrigin[ 0 ] , iOrigin[ 1 ] , iOrigin[ 2 ] );
    }
}

public TeleportRandom( id )
{
    new iOrigin[ 3 ];
    
    GetRandomOrigin( iOrigin );
    set_user_origin( id , iOrigin );
}

public ReadOrigins()
{
    new iFile , iOrigin[ 3 ] , iCount;
    
    if ( ( iFile = fopen( szFile , "rb" ) ) )
    {
        iCount = file_size( szFile , 0 ) / OriginSize;
        
        server_print( "%d origins exist" , iCount );
        
        for ( new i = 1 ; i <= iCount ; i++ )
        {
            fread_raw( iFile , iOrigin , sizeof( iOrigin ) , BLOCK_INT );
            server_print( "%d - [ %d , %d , %d ]" , i ,  iOrigin[ 0 ] , iOrigin[ 1 ] , iOrigin[ 2 ] );
        }
    
        fclose( iFile );
    }
}

public DeleteOrigin()
{
    new iFile , iNewFile , iOrigin[ 3 ] , iCount , szArg[ 4 ] , iDeleteIndex , szTmpFile[ 64 ];
    
    if ( !read_argv( 1 , szArg , charsmax( szArg ) ) )
    {
        server_print( "No coord index specified to delete." );
        return;
    }
    
    iDeleteIndex = str_to_num( szArg );
    iCount = file_size( szFile , 0 ) / OriginSize;
        
    if ( !iCount )
    {
        server_print( "No coords exists for this map." );
        return;
    }
    else if ( !( 1 <= iDeleteIndex <= iCount ) ) 
    {
        server_print( "Invalid coord index specified. Must be in range of 1-%d." , iCount );
        return;
    }
        
    formatex( szTmpFile , charsmax( szTmpFile ) , "%s_tmp" , szFile );
    rename_file( szFile , szTmpFile , 1 );
    
    if ( ( iFile = fopen( szTmpFile , "rb" ) ) )
    {
        if ( ( iNewFile = fopen( szFile , "wb" ) ) )
        {
            for ( new i = 1 ; i <= iCount ; i++ )
            {
                fread_raw( iFile , iOrigin , sizeof( iOrigin ) , BLOCK_INT );
                
                if ( i == iDeleteIndex )
                {
                    server_print( "Deleted: %d - [ %d , %d , %d ]" , iDeleteIndex , iOrigin[ 0 ] , iOrigin[ 1 ] , iOrigin[ 2 ] );    
                }
                else
                {
                    fwrite_raw( iNewFile , iOrigin , sizeof( iOrigin ) , BLOCK_INT );
                }
            }
        
            fclose( iNewFile );
        }
        fclose( iFile );
    }

    delete_file( szTmpFile );
}

public GetRandomOrigin( iOrigin[ 3 ] )
{
    new iFile;
    
    if ( ( iFile = fopen( szFile , "rb" ) ) )
    {
        fseek( iFile , ( random( file_size( szFile , 0 ) / OriginSize ) ) * OriginSize , SEEK_SET );
        fread_raw( iFile , iOrigin , sizeof( iOrigin ) , BLOCK_INT );
        
        fclose( iFile );
    }    
}