[noahspaghetti]

For example, I want an MP7 to have a layout of 30:0 instead of 30:120.


30 = Clip Size

0 = Reserves

Or... if possible is there a way to prevent others from completely reloading at all? I have looked around for other plugins, and Ammo Manager is outdated.

Edit: Solved.

[Bacardi]

csgo ?

"sv_infinite_ammo" = "0"
FCVAR_GAMEDLL FCVAR_REPLICATED FCVAR_RELEASE 
- Player's active weapon will never run out of ammo. If set to 2 then player has infinite total ammo but still has to reload the magazine.

*edit
or
https://www.sourcemod.net/plugins.ph...tion=&search=1

[noahspaghetti]

Or... if possible is there a way to prevent others from completely reloading at all? I have looked around for other plugins, and Ammo Manager is outdated.

I'm mainly looking for something like this.

[Ilusion9]

PHP Code:


#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

bool g_IsPluginLoadedLate;

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
    g_IsPluginLoadedLate = late;
}

public void OnPluginStart()
{    
    if (g_IsPluginLoadedLate)
    {
        for (int i = 1; i <= MaxClients; i++)
        {
            if (IsClientInGame(i))
            {
                OnClientPutInServer(i);
            }
        }
    }
}

public void OnEntityCreated(int entity, const char[] classname)
{    
    if (StrEqual(classname, "weapon_mp7", true))
    {
        SDKHook(entity, SDKHook_SpawnPost, SDK_OnWeaponSpawn_Post);
    }
}

public void SDK_OnWeaponSpawn_Post(int weapon)
{
    if (!IsValidEntity(weapon))
    {
        return;
    }
    
    RequestFrame(Frame_SetWeaponAmmo, EntIndexToEntRef(weapon));
}

public void Frame_SetWeaponAmmo(int reference)
{
    int weapon = EntRefToEntIndex(reference);
    if (weapon == INVALID_ENT_REFERENCE)
    {
        return;
    }
    
    switch (GetItemDefinitionIndex(weapon))
    {
        case 33: // mp7
        {
            if (HasOwner(weapon))
            {
                SetEntProp(weapon, Prop_Send, "m_iClip2", 0);
            }
        }
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_WeaponEquipPost, SDK_OnWeaponEquip_Post);
}

public void SDK_OnWeaponEquip_Post(int client, int weapon)
{
    if (!IsValidEntity(weapon))
    {
        return;
    }
    
    switch (GetItemDefinitionIndex(weapon))
    {
        case 33: // mp7
        {
            if (!HasPrevOwner(weapon))
            {
                SetEntProp(weapon, Prop_Send, "m_iClip2", 0);
            }
        }
    }
}

int GetItemDefinitionIndex(int item)
{
    return GetEntProp(item, Prop_Send, "m_iItemDefinitionIndex");
}

bool HasOwner(int entity)
{
    return GetEntPropEnt(entity, Prop_Data, "m_hOwnerEntity") != -1;
}

bool HasPrevOwner(int entity)
{
    return GetEntPropEnt(entity, Prop_Send, "m_hPrevOwner") != -1;
} 


You can add more weapons.