[danonix]

Hello, I would like to add something like "GOAAAAL sprite" to soccerjam mod, while goal.

Is it right?

stock Create_TE_PLAYERATTACHMENT(id, entity, vOffset, iSprite, life)
{
	message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY, _, id);
	write_byte(TE_PLAYERATTACHMENT);
	write_byte(entity);	   	
	write_coord(vOffset);	
	write_short(iSprite);		
	write_short(life);		  
	message_end();

}

[milutinke]

I wrote this via my mobile phone.
It compiles on amxmodx.org/webcompiler.cgi
It should work
Now you can show sprite.
NOTE: Is uses engine

Here is code:

stock ShowSprite( const szEntityName[ ] , const szSprite[ ], Float: fOrigin[ 3 ], Float: fFrame ) {
	new iEntity = create_entity( "info_target" );
	
	entity_set_model( iEntity, szSprite );
	entity_set_string( iEntity, EV_SZ_classname, szEntityName );
	entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_NOCLIP ); 
	entity_set_float( iEntity, EV_FL_gravity, 0.0001 );
	entity_set_int( iEntity, EV_INT_solid, SOLID_TRIGGER );
	entity_set_int( iEntity, EV_INT_rendermode, kRenderTransAdd );
	entity_set_float( iEntity, EV_FL_renderamt, 250.0 );
	entity_set_vector( iEntity, EV_VEC_origin, fOrigin );
	entity_set_float( iEntity, EV_FL_scale, 0.4 );
	entity_set_float( iEntity, EV_FL_framerate, 0.0 );
	entity_set_float( iEntity, EV_FL_frame, fFrame );
	
	return iEntity;
}

Edit: I have wrote this before you edited your post
I refreshed page later and saw your new code

[danonix]

Thanks, what should I enter in parameter szEntityName?

[HamletEagle]

Originally Posted by danonix Thanks, what should I enter in parameter szEntityName?

Whatever you want, this is the entity classname.

[danonix]

What I am doing wrong?

Nothing shows:

ShowSprite("goal", "sprites/gol_bramka.spr", netOrig2, 10);

[Bos93]

Float: fFrame

[danonix]

Well, still doesn't work.

I have got this code, it works, but I have got one question
How I can make it dissapear after X seconds? Remove_entity?

PHP Code:

   new Float:fOrigin[3]
   new ent = create_entity("env_sprite")

   IVecFVec(iOrigin, fOrigin)

   entity_set_string(ent, EV_SZ_classname, "gol")
   entity_set_model(ent, "sprites/gol_bramka.spr")
   entity_set_int(ent, EV_INT_spawnflags, SF_SPRITE_STARTON)
   entity_set_float(ent, EV_FL_framerate, 30.0)

   DispatchSpawn(ent)

   entity_set_origin(ent, fOrigin)
   entity_set_size(ent, Float:{-25.0, -25.0, -25.0}, Float:{2000.0, 2000.0, 2000.0})
   entity_set_int(ent, EV_INT_solid, SOLID_TRIGGER)
   entity_set_int(ent, EV_INT_movetype, MOVETYPE_FLY)
   entity_set_int(ent, EV_INT_rendermode, kRenderTransAdd)
   entity_set_float(ent, EV_FL_renderamt, 255.0)
   entity_set_float(ent, EV_FL_scale, 1.0) 


[Freezo Begin]

Yes you have do a create_entity so you can remove it by remove_entity . you can just do it with a set_task you know ...

[milutinke]

It is working, i have tested it.
Sprite link: https://www.dropbox.com/s/2062rqqq7z...ill_1.spr?dl=0
Resoult: http://i.imgur.com/WSoO3ga.png

Example code:

PHP Code:

#include < amxmodx >
#include < engine >

new const g_szSprite[ ] = "sprites/kill_1.spr";

public plugin_init( ) {
    register_plugin( "Show Sprite Test", "1.0", "Milutinke (ByM)" );
    
    register_clcmd( "say /spr", "CreateSprite" );
}

public plugin_precache( )
    precache_model( g_szSprite );

public CreateSprite( id ) {
    if( !is_user_connected( id ) || !is_user_alive( id ) )
        return;
        
    static Float: g_fMyOrigin[ 3 ];
    entity_get_vector( id, EV_VEC_origin, g_fMyOrigin );
    g_fMyOrigin[ 0 ] += 10;
    
    ShowSprite( "Example", g_szSprite, g_fMyOrigin, 2.0 );
}

stock ShowSprite( const szEntityName[ ] , const szSprite[ ], Float: fOrigin[ 3 ], Float: fFrame ) {
    new iEntity = create_entity( "info_target" );
    
    entity_set_model( iEntity, szSprite );
    entity_set_string( iEntity, EV_SZ_classname, szEntityName );
    entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_NOCLIP ); 
    entity_set_float( iEntity, EV_FL_gravity, 0.0001 );
    entity_set_int( iEntity, EV_INT_solid, SOLID_TRIGGER );
    entity_set_int( iEntity, EV_INT_rendermode, kRenderTransAdd );
    entity_set_float( iEntity, EV_FL_renderamt, 250.0 );
    entity_set_vector( iEntity, EV_VEC_origin, fOrigin );
    entity_set_float( iEntity, EV_FL_scale, 0.4 );
    entity_set_float( iEntity, EV_FL_framerate, 0.0 );
    entity_set_float( iEntity, EV_FL_frame, fFrame );
    
    return iEntity;
} 


[danonix]

Well, maybe I have done something wrong :p
Thanks for help anyway!
Have a nice day guys