[Krtola]

You can not avoid C4.
The only thing you can do is block players to set C4.

[HamletEagle]

Originally Posted by Krtola You can not avoid C4. The only thing you can do is block players to set C4.

Don't spread wrong information please. You can block c4 from being given to players.

[Krtola]

Then why do not you show how?

[HamletEagle]

The best way is to hook with orpheu CHalfLifeMultiplay::GiveC4 and supercede it.

[wickedd]

You can also just remove the bombsites, then no one will be give the bomb. That's what I did and it WORKS, but the op must have tested it alone.

[Krtola]

Any way..
Enjoy:

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>
#include <fun>

const XO_WEAPON = 4

const m_pPlayer = 41
const m_flNextPrimaryAttack = 46

new bool:g_bCanPlantC4

public plugin_init()
{
    register_plugin("C4 block", "0.1", "cs 1.6")
    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn", true)
    
    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_c4", "CC4_PrimaryAttack")
}

public CC4_PrimaryAttack(iC4)
{
    if( !g_bCanPlantC4 )
    {
        new id = get_pdata_cbase(iC4, m_pPlayer, XO_WEAPON)
        client_print(id, print_chat, "C4 is actually disabled !!")
        set_pdata_float(iC4, m_flNextPrimaryAttack, 1.0, XO_WEAPON)
        return HAM_SUPERCEDE
    }
    return HAM_IGNORED
}

public CBasePlayer_Spawn(id)
{
    if(is_user_alive(id))
    {
        strip_user_weapons( id )
        give_item(id, "weapon_knife")
        
        if(!user_has_weapon(id, CSW_HEGRENADE))
        {
            give_item(id, "weapon_hegrenade")
        }
    }
} 


PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>
#include <fun>

public plugin_init()
{
    register_plugin("c4 block", "0.1", "cs 1.6")
    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn", true)
    register_event("StatusIcon", "GotBomb", "be", "1=1", "1=2", "2=c4")
}

public GotBomb(id) 
{
    fm_strip_user_gun(id, CSW_C4)
}

public CBasePlayer_Spawn(id)
{
    if(is_user_alive(id))
    {
        strip_user_weapons( id )
        give_item(id, "weapon_knife")
        
        if(!user_has_weapon(id, CSW_HEGRENADE))
        {
            give_item(id, "weapon_hegrenade")
        }
    }
} 


[Hartmann]

Try...

- remove c4 from map
- remove buy
- equipment knife and hegrenade

PHP Code:

#include <amxmodx>
#include <engine>

public plugin_precache()
{
    new iEnt
    iEnt = create_entity("game_player_equip")
    DispatchKeyValue(iEnt, "weapon_knife", "1")
    DispatchKeyValue(iEnt, "weapon_hegrenade", "1")
    DispatchSpawn(iEnt)

    iEnt = create_entity("info_map_parameters")
    DispatchKeyValue(iEnt, "buying", "3")
    DispatchSpawn(iEnt)
}

public pfn_keyvalue( iEnt ) 
{
    new szClassName[32], szKeyName[32], szValue[32]
    copy_keyvalue(szClassName, charsmax(szClassName), szKeyName, charsmax(szKeyName), szValue, charsmax(szValue)) 
    if(    equal(szClassName, "game_player_equip")
    ||    equal(szClassName, "info_map_parameters")
    ||    equal(szClassName, "func_bomb_target")
    ||    equal(szClassName, "info_bomb_target")    )
    {
        remove_entity(iEnt)
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public plugin_cfg()
{
    server_cmd("sv_restart 1")
}