[brian201049]

How about UTIL_ScreenShake

[ConnorMcLeod]

Originally Posted by brian201049 How about UTIL_ScreenShake

Spoiler

PHP Code:

// Shake the screen of all clients within radius
// radius == 0, shake all clients
// UNDONE: Allow caller to shake clients not ONGROUND?
// UNDONE: Fix falloff model (disabled)?
// UNDONE: Affect user controls?
stock UTIL_ScreenShake( const Float:center[3], Float:amplitude, Float:frequency, Float:duration, Float:radius, bool:bMustBeOnGround = true )
{
    new    Float localAmplitude

    new iDuration = FixedUnsigned16( duration, 1<<12 );        // 4.12 fixed
    new iFrequency = FixedUnsigned16( frequency, 1<<8 );    // 8.8 fixed
    new iAmplitude

    new iPlayers[32], Float:fVecPlayerOrigin[3]
    get_players(iPlayer, iNum, "a")
    for(new i, id; i<iNum; i++)
    {
        id = iPlayers[i]
        if( bMustBeOnGround && ~pev(id, pev_flags) & FL_ONGROUND ) // Don't shake if not onground
        {
            continue
        }
        localAmplitude = 0.0
        if ( radius <= 0.0 )
        {
            localAmplitude = amplitude;
        }
        else
        {
            pev(id, pev_origin, fVecPlayerOrigin)

            // Had to get rid of this falloff - it didn't work well
            if ( get_distance_f(center, fVecPlayerOrigin) < radius )
                localAmplitude = amplitude;//radius - distance;
        }
        if ( localAmplitude )
        {
            iAmplitude = FixedUnsigned16( localAmplitude, 1<<12 );        // 4.12 fixed
            static msgShake
            if( !msgShake )
            {
                msgShake = get_user_msgid("ScreenShake")
            }
            message_begin( MSG_ONE, msgShake, .player = id );        // use the magic #1 for "one client"
            {
                write_short( iAmplitude );                // shake amount
                write_short( iDuration );                // shake lasts this long
                write_short( iFrequency );                // shake noise frequency
            }
            message_end();
        }
    }
}

stock UTIL_ScreenShakeAll( const Float:center[], Float:amplitude, Float:frequency, Float:duration, bool:bMustBeOnGround = true )
{
    UTIL_ScreenShake( center, amplitude, frequency, duration, 0.0, bMustBeOnGround );
}

stock FixedUnsigned16(Float:flValue, iScale)
{
    new iOutput;

    iOutput = floatround(flValue * iScale);

    if ( iOutput < 0 )
        iOutput = 0;

    if ( iOutput > 0xFFFF )
        iOutput = 0xFFFF;

    return iOutput;
} 


[Arkshine]

Well, one thing 'UNDONE' fixed + moved message check out of loop.

Spoiler

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <xs>

// Shake the screen of all clients within radius
// radius == 0, shake all clients
// UNDONE: Fix falloff model (disabled)?
// UNDONE: Affect user controls?
UTIL_ScreenShake( const Float:center[3], const Float:amplitude, const Float:frequency, const Float:duration, const Float:radius )
{
    static msgIndexScreenShake; msgIndexScreenShake || ( msgIndexScreenShake = get_user_msgid( "ScreenShake" ) );

    new shakeAmplitude;
    new shakeDuration  = UTIL_FixedUnsigned16( duration , 1 << 12 );
    new shakeFrequency = UTIL_FixedUnsigned16( frequency, 1 << 8  );

    new Float:origin[3];
    new Float:localAmplitude;

    new playersList[32];
    new playersCount;
    new player;

    get_players( playersList, playersCount, "a" );

    for( new i = 0; i < playersCount; i++ )
    {
        player = playersList[ i ];

        localAmplitude = 0.0;

        if( radius <= 0.0 )
        {
            localAmplitude = amplitude;
        }
        else
        {
            pev( player, pev_origin, origin );
            xs_vec_sub( center, origin, origin );

            if( xs_vec_len( origin ) < radius )
            {
                localAmplitude = amplitude;
            }
        }

        if( localAmplitude )
        {
            if( ~pev( player, pev_flags ) & FL_ONGROUND )
            {
                localAmplitude *= 0.5;
            }

            shakeAmplitude = UTIL_FixedUnsigned16( localAmplitude, 1 << 12 );

            message_begin( MSG_ONE_UNRELIABLE, msgIndexScreenShake, .player = player );
            {
                write_short( shakeAmplitude );  // --| Shake amount.
                write_short( shakeDuration );   // --| Shake lasts this long.
                write_short( shakeFrequency );  // --| Shake noise frequency.
            }
            message_end();
        }
    }
}

UTIL_ScreenShakeAll( const Float:center[3], const Float:amplitude, const Float:frequency, const Float:duration )
{
    UTIL_ScreenShake( center, amplitude, frequency, duration, 0 );
}

UTIL_FixedUnsigned16 ( const Float:value, const scale )
{
    return clamp( floatround( value * scale ), 0, 0xFFFF );
} 


[ConnorMcLeod]

Rage version :

Three stocks :

// Main util
UTIL_ScreenFade(id, Float:color[3]={0.0,0.0,0.0},Float:fadeTime=0.0,Float:fadeHold=0.0,alpha=0,flags=FFADE_IN)


// Utils from main util

UTIL_FadeToBlack(id,Float:fadeTime=3.0)


UTIL_Flash(id, Float:fadeTime, Float:holdTime, bool:bFullFlashed)

Details :

• fadeTime and fadeHold in seconds.
• color, type : { 0.0-255.0 , 0.0-255.0 , 0.0-255.0 }
• alpha, type : 0-255
• flags : see .inc

[bogdyuttzu]

What about ScreenShake with rage?

[yokomo]

Sorry, how can i set screen shake for 1 person only?

UTIL_ScreenShake( const Float:center[3], const Float:amplitude, const Float:frequency, const Float:duration, const Float:radius )

I don't see any param for player index.

[Arkshine]

That's not mean to be used for one player. This function calculates the amplitude depending the radius and distance for each player. It doesn't really make sense to send the message only for one player. If you still want to do that, simply redo the function yourself, you have the code in HLSDK, and if I remember conversion to amxx somewhere on the forum.

[ConnorMcLeod]

Originally Posted by bogdyuttzu What about ScreenShake with rage?

Waiting arkshine have time to compile handler for linux and will post it there.

Stocks for use with attachements if you want :

PHP Code:

stock UTIL_ScreenShake( Float:center[3], Float:amplitude, Float:frequency, Float:duration, Float:radius )
{
    static RageFunc:__FuncUTIL_ScreenShake;
    if( !__FuncUTIL_ScreenShake ) __FuncUTIL_ScreenShake = RageGetFunction("UTIL_ScreenShake");
    RageCall(__FuncUTIL_ScreenShake, center, amplitude, frequency, duration, radius);
}

stock UTIL_ScreenShakeAll( Float:center[3], Float:amplitude, Float:frequency, Float:duration )
{
    UTIL_ScreenShake( center, amplitude, frequency, duration, 0.0 );
} 


[Arkshine]

Here.

[bazhenov93]

BUG?

PHP Code:

set_pev(id, pev_origin, lj_position[lalin-220])
client_cmd (id, "spk sound/goto_tp.mp3")
UTIL_ScreenFade(id, get_cvar_color1(goto_Red, goto_Green, goto_Blue), 0.55, 0.45, 60)
ColorChat(id, RED, "{^4Server Name^3} ^1Moved to LJ Block: ^4%i", lalin) 


te result;



without the screenfade_util.inc

{Server Name} Moved to CJ Block: ^4% ( has I need )