[yokomo]

Originally Posted by Doc-Holiday Ive had issues with mass plugins using this forward... it would continue running and not register the bots... i have been using this method from rage without issue and same load of plugin http://forums.alliedmods.net/showpos...7&postcount=41

Hurmm strange, but for me it work fine. The 1st code that Connor attached is error, but this 1 no error.

Test result:

[Ham Test] Bot [13] killed.
[Ham Test] Bot [1] spawned.
[Ham Test] Bot [2] spawned.
[Ham Test] Bot [3] spawned.
[Ham Test] Bot [4] spawned.
[Ham Test] Bot [5] spawned.
[Ham Test] Bot [6] spawned.
[Ham Test] Bot [7] spawned.
[Ham Test] Bot [8] spawned.
[Ham Test] Bot [9] spawned.
[Ham Test] Bot [10] spawned.
[Ham Test] Bot [17] hitted by [15.0] damage.
[Ham Test] Bot [17] hitted by [15.0] damage.
[Ham Test] Bot [17] hitted by [65.0] damage.
[Ham Test] Bot [15] hitted by [195.0] damage.
[Ham Test] Bot [17] hitted by [65.0] damage.
[Ham Test] Bot [17] hitted by [260.0] damage.
[Ham Test] Bot [17] hitted by [114.7] damage.
[Ham Test] Bot [17] hitted by [95.0]

Test plugin:

PHP Code:

#include <amxmodx>
#include <hamsandwich>

public plugin_init()
{
    register_plugin("Test CZ bot Ham", "0.0.1", "wbyokomo")
    
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawnPost", 1)
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled")
    RegisterHam(Ham_TakeDamage, "player", "OnPlayerTakeDamage")
}

public cz_bot_ham_registerable(id)
{
    RegisterHamFromEntity(Ham_Spawn, id, "OnPlayerSpawnPost", 1)
    RegisterHamFromEntity(Ham_Killed, id, "OnPlayerKilled")
    RegisterHamFromEntity(Ham_TakeDamage, id, "OnPlayerTakeDamage")
}

public OnPlayerSpawnPost(id)
{
    if(!is_user_alive(id)) return;
    client_print(0, print_chat, "[Ham Test] Bot [%i] spawned.", id)
}

public OnPlayerKilled(id)
{
    client_print(0, print_chat, "[Ham Test] Bot [%i] killed.", id)
}

public OnPlayerTakeDamage(victim, inflictor, attacker, Float:damage, damagetype)
{
    if(!is_user_connected(attacker)) return HAM_IGNORED;
    client_print(attacker, print_chat, "[Ham Test] Bot [%i] hitted by [%.1f] damage.", victim, damage)
    
    return HAM_IGNORED;
} 


[Doc-Holiday]

I dont get an error it just seems like if i have to many plugins running with this it would stop working so i removed the forward and plugin and used the rage one and it all worked fine. But if i ran one or two plugins using his forward it wouldnt work. Tried even addig forward blah like he said.

Also tried to move it arohnd in the plugins ini. But same results everywhere

[yokomo]

Originally Posted by ConnorMcLeod That version with fakemeta should also works fine, if someone has some trouble with other one. Spoiler PHP Code: #include <amxmodx> #include <fakemeta> #define VERSION "2.0.0" new g_iFwdSetClientKeyValue public plugin_init() {     register_plugin("Ham Register Cz Bots", VERSION, "ConnorMcLeod")     g_iFwdSetClientKeyValue = register_forward(FM_SetClientKeyValue, "SetClientKeyValue") } public SetClientKeyValue(id, infobuffer[], key[], value[]) {     if( equal(key, "*bot") && value[0] == '1' )     {         unregister_forward(FM_SetClientKeyValue, g_iFwdSetClientKeyValue)         new iForward = CreateMultiForward("cz_bot_ham_registerable", ET_IGNORE, FP_CELL)         new iRet         ExecuteForward(iForward, iRet, id)         DestroyForward(iForward)     } }

Waa this 1 is simple coded. Gonna try this version, thanks for share.

[ConnorMcLeod]

Little update, should filter cz bots from other bots :

Spoiler

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "2.1.3"

new g_iFwdSetClientKeyValue

public plugin_init()
{
    register_plugin("Ham Register Cz Bots", VERSION, "ConnorMcLeod")
}

public client_putinserver( id )
{
    if( !g_iFwdSetClientKeyValue && is_user_bot(id) )
    {
        g_iFwdSetClientKeyValue = register_forward(FM_SetClientKeyValue, "SetClientKeyValue")
    }
}

public SetClientKeyValue(id, infobuffer[], key[], value[])
{
    if( value[0] == '1' && equal(key, "*bot") )
    {
        unregister_forward(FM_SetClientKeyValue, g_iFwdSetClientKeyValue)
        if( IsCzBot( id ) )
        {
            new iRet, iForward = CreateMultiForward("cz_bot_ham_registerable", ET_IGNORE, FP_CELL)
            ExecuteForward(iForward, iRet, id)
            DestroyForward(iForward)
            pause("ac")
        }
        else
        {
            g_iFwdSetClientKeyValue = 0
        }
    }
}

IsCzBot( id )
{
#if defined Ham_CS_Player_IsBot
    static valid = -1
    if( valid == -1 )
    {
        valid = IsHamValid( Ham_CS_Player_IsBot )
    }
    if( valid )
    {
        return ExecuteHam(Ham_CS_Player_IsBot, id)
    }
    return ExecuteHam(Ham_Weapon_ExtractClipAmmo, id, 0)
#else
    return ExecuteHam(Ham_Weapon_ExtractClipAmmo, id, 0)
#endif
} 


[PRoSToTeM@]

My version:

Spoiler

PHP Code:

#include <amxmodx>
#include <fakemeta>

new g_iFakeClientByGameDll;

new g_fwdCreateFakeClient_Post;
new g_fwdGetInfoKeyBuffer;

public plugin_init() {
    g_fwdCreateFakeClient_Post = register_forward(FM_CreateFakeClient, "CreateFakeClient_Post", true);
    g_fwdGetInfoKeyBuffer = register_forward(FM_GetInfoKeyBuffer, "GetInfoKeyBuffer");
}

public CreateFakeClient_Post() {
    new iEntity = get_orig_retval();
    
    if (!pev_valid(iEntity)) {
        return;
    }
    
    g_iFakeClientByGameDll = iEntity;
}

public GetInfoKeyBuffer(const iEntity) {
    if (!g_iFakeClientByGameDll) {
        return;
    }
    
    g_iFakeClientByGameDll = 0;
    
    unregister_forward(FM_CreateFakeClient, g_fwdCreateFakeClient_Post, true);
    unregister_forward(FM_GetInfoKeyBuffer, g_fwdGetInfoKeyBuffer);
    
    new iRet;
    new fwd = CreateMultiForward("CSBot_Init", ET_IGNORE, FP_CELL);
    ExecuteForward(fwd, iRet, iEntity);
    DestroyForward(fwd);
} 


Example plugin:

Spoiler

PHP Code:

#include <amxmodx>
#include <hamsandwich>

public plugin_init() {
    RegisterHam(Ham_Spawn, "player", "PlayerSpawnPost", 1);
}

public CSBot_Init(const iEntity) {
    RegisterHamFromEntity(Ham_Spawn, iEntity, "PlayerSpawnPost", 1);
}

public PlayerSpawnPost(const iEntity) {
    new szName[32];
    get_user_name(iEntity, szName, charsmax(szName));
    
    server_print("Player spawned %s", szName);
} 


P.S. sorry for up topic